Grundsatz und Erstellung des Stop-Loss-Modells

Grundsatz und Erstellung des Stop-Loss-Modells

Warum Stop-Loss?

Das Alligatorprinzip

Nehmen wir an, ein Krokodil beißt dich an den Füßen. Wenn du versuchst, deine Füße mit deinen Händen zu befreien, beißt der Krokodil deine Füße und Hände gleichzeitig. Je mehr du kämpfst, desto mehr wirst du gebissen. Also, wenn der Krokodil dich beißt, ist deine einzige Chance, einen Fuß zu opfern.

Auf dem Kapitalmarkt, egal ob es sich um digitale Währungen oder Rohstoff-Futures handelt, lautet das Alligator-Prinzip, wenn Sie feststellen, dass Ihre Transaktion von der Richtung des Marktes abweicht, müssen Sie den Verlust sofort ohne Verzögerung oder Glück stoppen.

Die Erhaltung Ihres Kapitals steht immer an erster Stelle!

Investitionsmagnaten

Ich glaube, das Wichtigste ist immer, das Kapital zu bewahren, das der Grundstein der Investitionsstrategie ist.

Versagte Investoren

Das einzige Anlageziel ist es, viel Geld zu verdienen.

Investitionsmagnaten wissen, dass es einfacher ist, Geld zu vermeiden, als Geld zu verdienen. Wenn Sie 50% Ihres Investitionskapitals verlieren, müssen Sie Ihr Kapital verdoppeln, um zum Ausgangspunkt zurückzukehren.

Geographische Stop-Loss-Methode

Der Schlüssel besteht darin, den Stop-Loss-Preis über oder unter eine bestimmte Benchmark-Position zu setzen, um einen präventiven Ansatz zu erreichen.

Zum Beispiel:

Langer Stop-Loss - Stop-Loss unterhalb der Unterstützungslinie auf Basis der Unterstützungslinie Kurzer Stop-Loss - setzt einen Stop-Loss über die Widerstandslinie auf Basis der Widerstandslinie.

Diese Stop-Loss-Methode gehört zur Preismodellmethode, die gleichbedeutend ist mit der Festlegung der maximalen Grenze des Stop-Loss, um sich zu schützen und die durch emotionale Interferenzen verursachte Katastrophe zu vermeiden. Nachdem wir unsere Position festgelegt haben, werden Sie passiv sein, wenn wir passiv darauf warten, dass der Preis bis zur maximalen Stop-Loss-Linie fällt. Die voreingestellte maximale Stop-Loss-Limit kann nur eine sehr gute Rolle bei der Blockierung spielen, wenn der Markt plötzlich seine Richtung ändert.

Limit- und Stop-Loss-Methode

Stop-Loss-Strategie: Die Stop-Loss-Position wird vor der Eröffnung der Position festgelegt.

Strategiebeispiel: Stop-Loss bei einem festen Preispunkt und Stop-Loss bei 3% oder 5% unter dem Kaufpreis. Sobald der Preis effektiv unter die Stop-Loss-Position fällt, verlassen Sie den Markt sofort.

Befolgen Sie die Trend-Floating Stop-Loss-Methode

Stop-Loss-Strategie: basiert auf dem Gewinn und Verlust zum Zeitpunkt der Festlegung des Stop-Loss, Stop-Loss nach Entnahme von N Preispunkten aus dem maximalen Gewinn und Verlust.

Strategiebeispiel: Wenn Sie einen Long-Order für PTA bei 8946 aufgeben und den Stop-Loss setzen, wenn der Preis auf 10 zurückgeht (8936), wird der Stop-Loss-Preis automatisch bei 8940 neu positioniert, wenn der PTA-Preis auf 8950 steigt.

Einheitliche Wertpapier- und WertpapierverträgeWenn der Preis erst nach dem Kauf steigt und dann nach Erreichen eines relativen Höchstpunkts sinkt, dann können Sie den Rückgangsspielraum vom relativen Höchstpunkt als Stop-Loss-Ziel festlegen, und der spezifische Wert dieses Bereichs wird auch von Ihrer persönlichen Situation bestimmt. Darüber hinaus können wir auch den Faktor der abnehmenden Zeit (d.h. Tage) hinzufügen.

Einführung in moderne Stop-Loss-Methoden

Zeitstop-Loss-Methode

Anwendung: Intraday-Ultra-Short-Handel

Schlüssel: Nachdem die Position etabliert ist, gibt es keine günstige Schwankung auf dem Markt für einen bestimmten Zeitraum, Stop-Loss und verlassen Sie den Markt und suchen Sie nach der Gelegenheit, den Markt wieder zu betreten.

Handelsprinzip: Wenn sich der Preis unter dem Einfluss bestimmter Faktoren wie der Auswirkungen des Außenmarktes, dem Durchbruch und dem falschen Durchbruch des Intraday-Unterstützungsniveaus und des Druckniveaus und der plötzlichen Nachrichten in einem Augenblick stark bewegt, kann der Gewinn durch schnellen Eintritt und Ausstieg in den Trend oder gegen den Trend erzielt werden.

Die Praxis des Zeitstop-Loss ist zukunftsgerichtet und gehört zu anderen Stop-Loss-Methoden. Der Zeitstop-Loss beinhaltet auch die Frage der Öffnungszeit. Zum Beispiel sollten wir uns bemühen, die Position im Moment des Beginns des kritischen Punktes (der qualitativen Veränderungspunkt) zu öffnen und erwarten, dass es einen Wahnsinn gibt, die Gewinner zu kaufen, aber es ist nur eine Erwartung. Wenn dies nicht geschieht, sollten wir die Position schließen und den Markt verlassen und nicht warten, bis die Unterstützung oder der Crossover-Widerstand sinkt, bevor wir den Verlust stoppen.

Typische Stop-Loss-Zeit:

Horizontale Stop-Loss

• Stop-Loss-Strategie: Setzen Sie ein Stop-Loss-Ziel für die Zeit, in der der Preis nach dem Kauf innerhalb eines bestimmten Bereichs überschreitet.

• Strategische Distanz: Stop-Loss, wenn die Erhöhungsrate innerhalb von 5 Tagen nach dem Kauf nicht 5% erreicht.

• Im Allgemeinen erfordert die horizontale Stop-Loss-Methode, dass zur umfassenden Kontrolle des Risikos gleichzeitig die Zeit-Stop-Loss- und die Maximalverlustmethode verwendet werden.

Technische Stop-Loss-Methode

Schlüssel: Die technische Stop-Loss-Methode ist eine komplexere Stop-Loss-Methode. Sie kombiniert die Stop-Loss-Einstellung mit der technischen Analyse. Nachdem die zufälligen Schwankungen des Marktes beseitigt wurden, setzt sie die Stop-Loss-Order auf dem wichtigen technischen Niveau, um eine weitere Ausweitung des Verlustes zu vermeiden.

Anwendung: Die technische Stop-Loss-Methode erfordert, dass Anleger starke technische Analysefähigkeiten und Selbstkontrolle haben. Im Vergleich zur früheren Methode hat die technische Stop-Loss-Methode höhere Anforderungen an Anleger und es ist schwierig, ein festes Modell zu finden. Im Allgemeinen ist die Verwendung der technischen Stop-Loss-Methode nichts anderes als kleine Verluste, um große Gewinne zu erzielen.

Zum Beispiel warten Sie nach dem Kauf abseits der Spur des steigenden Kanals auf das Ende des steigenden Trends, um die Position zu schließen, und setzen Sie die Stop-Loss-Position in der Nähe der relativ zuverlässigen gleitenden Durchschnittslinie ein, so dass Sie die Preisdifferenz erhalten können, indem Sie in eine niedrige Position eintreten und in einer hohen Position aussteigen.

Typischer technischer Stop-Loss:

Der Wert des Vermögenswertes ist der Wert des Vermögenswertes, der für die Vermögenswerte verwendet wird.

Einschließlich der Tangente des Preises, der effektiv unter die Trendlinie fällt; Der Preis bricht effektiv die Gann-Winkellinie 1 × 1 oder 2 × 1-Linie; Der Preis bricht effektiv durch die untere Spur des steigenden Kanals.

Morphologischer Stop-Loss:

Dazu gehörte, dass der Aktienkurs den Ausschnitt von Kopf und Schultern, M-Kopf, rundem Oberteil und anderen Kopfmustern brach; der Preis sprang nach unten, um die Lücke zu überbrücken, usw.

K-Linien-Stop-Loss:

Einschließlich kurzer Aufnahmen mit zwei negativen Linien, die mit einer positiven Linie eingeklemmt sind, und einer negativen Linie, gefolgt von zwei negativen und positiven Linien, oder vollständig abgedeckter Status mit einer negativen Linie, die drei Linien bricht, und das Auftreten der typischen K-Linienkombinationen, wie Twilight Star, die 2. K-Linie, die die 1. K-Linie durchdringt, die Sterne des Schießens, die beiden fliegenden Krähen und die drei Krähen, die auf Baumkronen hängen und so weiter.

Index-Stop-Loss:

Gemäß den technischen Indikatoren, die von den Verkaufsanweisungen ausgegeben werden, als Stop-Loss-Signal, hauptsächlich einschließlich: MACD erschien grüner Balken und bildete ein Down-Kreuz; SAR unten unter dem Wendepunkt und grün geworden, etc... Eine der einfachsten und praktischsten ist der SAR Parabol Turn-Indikator, auch bekannt als das Stop-Loss Point Turn-Betriebssystem.

Statistische Stop-Loss-Methode

Bei der Auswahl von Referenzmaterialien für Stop-Loss können wir verschiedene Referenzstandards auswählen. Neben technischen Indikatoren, K-Linienform, Zeit und Preisraum sind viele statistische Variablen auch wichtige Referenzstandards für die Einstellung von Stop-Loss. Die meisten dieser statistischen Variablen basieren auf Statistiken und mathematischen Prinzipien, daher nennen wir sie temporär statistische Stop-Loss.

Typische statistische Stop-Loss:

Kapitalstop-Loss-Methode:

Dies ist die einfachste Stop-Loss-Methode. Wir kontrollieren das Risiko bei einem festen Anteil des Kapitals in jeder Transaktion. Wenn wir kontinuierlich Geld verdienen, stellt der Anteil dar, dass der Betrag steigen wird, so dass wir mehr Kapital investieren können, um mehr Gewinne zu erzielen. Wenn wir kontinuierlich Geld verlieren, können wir den Verlust im Gegenteil reduzieren.

Methode zur Erstellung des Stop-Loss-Modells

Schreiben Sie mehrere häufige Stop-Loss-Funktionen:

BKPRICE Return to the signal price of the last buying and opening of the data contract.
SKPRICE Return to the signal price of the last selling and opening of the data contract.
BKHIGH Return to the highest price from the last model buy opening position to the current one.
SKLOW Return to the lowest price from the last model sell opening position to the current one.
BARSBK Last buy opening signal position
BARSSK Last sell opening signal position

Grenzpreis für Stop-Loss und Stop-Profit

TMP1:=C<BKPRICE-M;
TMP2:=C>SKPRICE+M;

TMP3:=C>BKPRICE+M;
TMP4:=C<SKPRICE-M;

Nachläufige Stop-Loss

HH:HHV(H,BARSBK); // High point since entering the market
LL:LLV(L,BARSSK); // Low point since entering the market
TMP1:=C<(HH-BKPRICE)*0.5+BKPRICE&&HH>BKPRICE+25; // Long position trailing stop-loss conditions
TMP2:=C>SKPRICE-(SKPRICE-LL)*0.5&&LL<SKPRICE-25; // Short position trailing stop-loss conditions

Beispiele für Stop-Loss-Modelle

Beispiel 1: Doppel SMA-System

Idee: Kaufen oder verkaufen, wenn der 100-Tage-SMA den 350-Tage-SMA überschreitet

MA1:MA(C,100);
MA2:MA(C,350); // Define double SMA
CROSS(MA1,MA2),BPK;
CROSS(MA2,MA1),SPK;
AUTOFILTER;

Denken

• Wenn die Voraussetzungen für das Überschreiten der Schlusspositionen nicht erfüllt sind und der Trend umgekehrt ist, können wir sofort einen Stop-Loss durchführen, um Verluste zu reduzieren?

• Wenn es profitabel ist, kann es den Gewinn maximieren und die Position der Schließposition mit dem Markt steigen lassen?

Umrechnung: Preislimit-Stop-Loss + nachfolgende Stop-Profit

// price limit stop-loss
C<BKPRICE-N,SP;
C>SKPRICE+N,BP;
// trailing stop-profit
C>BKPRICE&&C<BKHIGH-M,SP;
C<SKPRICE&&C>SKLOW+M,BP;
Note: N and M are price differences

Vollständiger Code:

MA1:MA(C,100);
MA2:MA(C,350); // Define double SMA
CROSS(MA1,MA2),BK;
CROSS(MA2,MA1),SK; // Conversion model
CROSS(MA2,MA1)||C<BKPRICE-N||(C>BKPRICE&&C<BKHIGH-M),SP;
CROSS(MA1,MA2)||C>SKPRICE+N||(C<SKPRICE&&C>SKLOW+M),BP;
 // Limit price stop-loss + withdrawal stop-loss
AUTOFILTER; // Realize signal filtering

Beispiel 2: Regressionsmodell der Eröffnungsvolatilität

Idee: Durchbrechen Sie das physische obere Ende der ersten K-Linie am Tag des Minutenzeitraums und gehen Sie lang. Der Preis fällt unter den niedrigsten Preis der ersten K-Linie des Tages oder der Markt ist 10 Minuten vergangen, schließen Sie die Position und gehen Sie aus; Wenn er unter das untere Ende der Entität der ersten K-Linie des Tages des Minutenzeitraums fällt, gehen Sie kurz und der Preis steigt höher als der höchste Preis der ersten K-Linie des Tages oder der Markt ist 10 Minuten vergangen, schließen Sie die Position und gehen Sie aus.

RKO:=VALUEWHEN(TIME=0900,O);// The opening price of the first K-line of the day in the minute period
RKC:=VALUEWHEN(TIME=0900,C);// The closing price of the first K-line of the day in the minute period
RKH:=VALUEWHEN(TIME=0900,H);// The highest price of the first K-line of the day in the minute period
RKL:=VALUEWHEN(TIME=0900,L);// The lowest price of the first K-line of the day in the minute period
CROSS(H,MAX(RKO,RKC))&&TIME<0910&&TIME>0900,BK;
CROSS(MIN(RKO,RKC),L)&&TIME<0910&&TIME>0900,SK;
C>RKH || TIME>=0910,BP;
C<RKL || TIME>=0910,SP;
AUTOFILTER;
// Applicable varieties, influenced by the external market and the opening volatility of the more violent varieties

Beispiel für ein Stop-Loss-Modell - Zeit Stop-Loss:

Beispiel 3: Preisdurchbruch-Kanalmodell

Idee: Verwenden Sie ATR, um die oberen und unteren Spuren des Preiskanals zu berechnen. Nachdem das Rekordhoch und der aktuelle höchste Preis den Schlusskurs der vorherigen K-Linie plus ein bestimmtes Vielfaches von ATR überschreitet, tritt die Long-Position in den Markt, wenn der Preis den unteren Track überschreitet, schließt die Position und geht aus. Nachdem das Rekordtief und der aktuelle niedrigste Preis den Schlusskurs der vorherigen K-Linie minus ein bestimmtes Vielfaches von ATR überschreitet, tritt die Short-Position in den Markt, der Preis überschreitet den oberen Track, schließt die Position und geht aus.

TR:=MAX(MAX((HIGH-LOW),ABS(REF(CLOSE,1)-HIGH)),ABS(REF(CLOSE,1)-LOW));
ATR:=MA(TR,26),COLORYELLOW; // Find the simple moving average of TR over 26 periods
C1:REF(C,1)+REF(ATR,1)*0.79; // Upper track
C2:REF(C,1)-REF(ATR,1)*0.79; // Lower track
HIGH>HHV(REF(HIGH,1),10)&&H>=REF(C,1)+REF(ATR,1)*0.79,BPK;
LOW<LLV(REF(L,1),10)&&L<=REF(C,1)-REF(ATR,1)*0.79,SPK;
CROSS(C2,C),SP; // The price breaks through the lower track, and the long position stop-loss is closed
CROSS(C,C1),BP; // The price breaks through the upper track, and the short position stop-loss is closed
AUTOFILTER;

Preisdurchbruch-Kanalmodell:

Beispiel 4: Morphologisches Stop-Loss-Modell Idee: Die Differenz zwischen aktuellem Preis und MA wird als DRD definiert, die Summe von DRD in N Tagen geteilt durch die Summe des absoluten Werts von DRD. Setzen Sie 5 als Markteintrittsschwelle. Wenn RDV> 5, wird der Markteintritt lang sein, und die K-Linie wird eine Abwärtslücke haben, und der Markenausgang wird geschlossen. Setzen Sie - 5 als Schwelle für den Markteintritt. Wenn RDV <- 5, betreten Sie den Markt und gehen Sie kurz, und die K-Linie hat eine Aufwärtslücke, und schließen Sie die Position und den Markenausgang.

RMA:=MA(CLOSE,15); 
DRD:=CLOSE-RMA; // Define the difference between the current price and MA as DRD                
NDV:=SUM(DRD,15); 
TDV:=SUM(ABS(DRD),15); 
RDV:=VALUEWHEN(TDV>0,100*NDV/TDV); // The sum of 15 days DRD divided by the sum of the absolute value of DRD
RDV>5,BPK;
RDV<-5,SPK;
MAX(C,O)<REF(MIN(C,O),1),SP; // If there is a downward gap in the K-line, stop-loss of the long position
MIN(C,O)>REF(MAX(C,O),1),BP; // If there is an upward gap in the K-line, stop-loss of the short position
AUTOFILTER;

Morphologisches Stop-Loss-Modell:

Beispiel 5: K-Linien-Stop-Loss-Modell

Idee: Wenn die beiden Gruppen von gleitenden Durchschnitten in einer Long-Position angeordnet sind und der aktuelle Preis höher ist als der höchste Preis der vorherigen K-Linie, treten Sie in den Markt, um lang zu gehen, und eine negative Linie fällt unter die vier gleitenden Durchschnitte, um den Verlust der langen Position zu stoppen.

MA3:MA(CLOSE,3);
MA5:MA(CLOSE,5);
MA10:MA(CLOSE,10);
MA20:MA(CLOSE,20); // SMA combinations
MA5>MA20&&MA3>MA10&&HIGH>=REF(HIGH,1),BPK;
MA5<MA20&&MA3<MA10&&LOW<=REF(LOW,1),SPK;
ISDOWN&&O>MAX1(MA3,MA5,MA10,MA20)&&C<MIN1(MA3,MA5,MA10,MA20),SP;
// One negative line falls below the four moving averages to stop the long position loss
ISUP&&C>MAX1(MA3,MA5,MA10,MA20)&&O<MIN1(MA3,MA5,MA10,MA20),BP;
// A positive line crossover four moving averages to stop the short position loss
AUTOFILTER;

K-Linien-Stop-Loss-Modell:

Beispiel 6: Index-Stop-Loss-Modell auf Basis von BOLL und SAR

Idee: Wenn der höchste Preis größer als die oberen Bollinger Bands ist, treten Sie in den Markt ein und gehen lang, der parabolische Steuerungswert überschreitet 0, und stoppen Sie den Long-Positionsverlust.

MID:=MA(CLOSE,26); // Find the average closing price of 26 periods, called the middle track of the Bollinger Bands
TMP2:=STD(CLOSE,26); // Find the standard deviation of the closing price over 26 periods
TOP:=MID+2*TMP2; // Bollinger Bands upper track
BOTTOM:=MID-2*TMP2; // Bollinger Bands lower track
STEP1:=2/100;
MVALUE1:=2/10;
SARLINE:SAR(4,STEP1,MVALUE1),CIRCLEDOT;
// Parabolic steering in 4 periods, step length of STEP1, and limit value of MVALUE1
HIGH>=TOP,BPK;
LOW<=BOTTOM,SPK;
CROSS(SARLINE,0),BP; // Parabolic steering value above 0, long position stop-loss
CROSS(0,SARLINE),SP; // Parabolic steering value below 0, short position stop-loss
AUTOFILTER;

Das obige ist der allgemeine Code-Rahmen für jedes Stop-Loss-Modell. Die Leser können je nach eigenen Bedürfnissen wählen. Der Weg zum Handel besteht darin, verschiedene Strategien und Methoden flexibel zu verwenden. Die Bedeutung des Stop-Loss in einer quantitativen Handelsstrategie ist selbstverständlich. Bei der Verwendung der obigen Modelle sollten die Leser sie nicht mechanisch kopieren. Sie müssen die Anwendbarkeit ihrer Handelsziele und Modelle mehrmals überprüfen und dann mehrere Rücktestungen des Simulationsbots durchführen, sicherstellen, dass das Modell korrekt ist und es dann auf den echten Bot anwenden.

Verwandt

Mehr