En la carga de los recursos... Cargando...

Estrategia de búsqueda y búsqueda basada en canales internos de precios

El autor:¿ Qué pasa?, Fecha: 2023-12-11 15:56:28
Las etiquetas:

Resumen general

Esta estrategia utiliza canales de precios internos para determinar las tendencias futuras de los precios y pertenece a las estrategias de seguimiento de tendencias. Cuando los precios forman un cierto número de canales de fluctuación de precios internos, se juzga como una señal de inversión de tendencia para hacer entradas largas o cortas. También incorpora filtrado de promedio móvil y stop-loss / take-profit para bloquear las ganancias y es una estrategia comercial cuantitativa relativamente común.

Principio de la estrategia

La estrategia determina la formación de canales internos de acuerdo con la relación de tamaño entre los precios más altos y más bajos de las dos velas anteriores.

Cuando se identifica un canal interno, la estrategia también juzga la dirección del canal. Si es un canal interno alcista, se genera una señal de entrada larga. Si es un canal interno bajista, se genera una señal de entrada corta. Por lo tanto, esta es una estrategia comercial bidireccional.

Para filtrar señales falsas, también se introduce un indicador de promedio móvil. Las señales comerciales reales solo se generan cuando el precio está por encima o por debajo de la línea promedio móvil. Esto puede evitar operaciones erróneas hasta cierto punto en los mercados laterales.

Después de la entrada, los puntos de stop-loss y take-profit también se pueden establecer de acuerdo con la elección del usuario. Hay tres métodos de stop loss disponibles: stop loss de punto fijo, stop loss ATR, stop loss anterior más alto / más bajo.

Análisis de ventajas

La mayor ventaja de esta estrategia es su fuerte capacidad para identificar puntos de inversión de tendencia. Cuando los precios forman un cierto número de canales internos, a menudo señala que está a punto de ocurrir un movimiento de precios relativamente grande hacia arriba / abajo. Este juicio es muy consistente con las teorías tradicionales del análisis técnico.

Además, la configurabilidad de la estrategia en sí es muy fuerte. Los usuarios pueden seleccionar libremente parámetros como el número de canales internos, el ciclo de promedio móvil, el método de stop loss / take profit, etc. Esto proporciona una gran flexibilidad para diferentes productos y estilos de negociación.

Por último, el filtro de promedio móvil y los ajustes de stop-loss/take-profit introducidos en la estrategia también reducen en gran medida los riesgos comerciales, lo que hace que la estrategia sea adaptable al comercio en diversos entornos de mercado.

Análisis de riesgos

El mayor riesgo de esta estrategia es la probabilidad relativamente alta de juicios de tendencia incorrectos. Los canales internos no pueden determinar completamente las reversiones de precios, existe una cierta probabilidad de error de juicio. Si la cantidad determinada es insuficiente, pueden ocurrir señales falsas.

Además, la estrategia es completamente inútil en mercados laterales o volátiles. Cuando los precios fluctúan hacia arriba y hacia abajo sin establecer una tendencia, la estrategia generará continuamente señales incorrectas. Esto está determinado por el mecanismo de la estrategia.

Por último, si el stop loss se establece de manera demasiado conservadora, la estrategia puede no ser capaz de mantener posiciones el tiempo suficiente para capturar ganancias en las tendencias principales.

Direcciones de optimización

El espacio de optimización de esta estrategia es todavía bastante grande.

Optimizar la cantidad y los patrones de los canales internos.
Optimizar el parámetro de ciclo de la media móvil para determinar mejor la dirección de la tendencia.
Añadir otros filtros de indicadores, por ejemplo, introducir bandas de Bollinger y sólo generar señales de negociación cuando los precios rompen a través de los rieles superiores o inferiores de las bandas.
Optimizar los parámetros de stop loss/take profit para permitir que la estrategia mantenga posiciones por más tiempo.

En general, la existencia de esta estrategia radica en la exactitud de su juicio sobre la tendencia.

Conclusión

En resumen, esta estrategia es una estrategia de negociación cuantitativa que determina las tendencias futuras de precios basadas en canales de precios internos. Combina los métodos de juicio de seguimiento de tendencia y inversión de tendencia y tiene ciertas ventajas. Pero también hay espacio para la optimización para satisfacer productos y entornos comerciales específicos. Después de la optimización de parámetros, puede convertirse en una de las estrategias de negociación cuantitativa más ideales.

/*backtest
start: 2023-12-03 00:00:00
end: 2023-12-10 00:00:00
period: 3m
basePeriod: 1m
exchanges: [{"eid":"Futures_Binance","currency":"BTC_USDT"}]
*/

// This source code is subject to the terms of the Mozilla Public License 2.0 at https://mozilla.org/MPL/2.0/

// From "Day Trading Cryptocurrency 
// Strategies, Tactics, Mindset, and Tools Required To Build Your 
// New Income Stream"
// by Phil C. Senior

// "Inside bars are a two -bar pattern. They can indicate either a continuation of the 
// existing move or a reversal. A continuation occurs when there is no significant 
// support or resistance level in sight, while a reversal occurs close to a strong sup- 
// port or resistance level...
// ...A lot of traders are aware of inside bars but few manage to make money with 
// them. Why is this so? It goes back to interpreting price action. A lot of traders look 
// to trade in geometric ways. What I mean is that they search for fancy shapes on a 
// chart and think that this is what represents true price action. 
// This is not the case. A shape is just a shape. The formation by itself means 
// nothing unless underlying order flow backs it up. This is why it’s extremely impor- 
// tant that you look for inside bars when a trend is already in place. The best place to 
// look for them is in the beginning of trends."

// © tweakerID

//@version=4
strategy("Inside Bar Strategy w/ SL", 
     overlay=true, 
     default_qty_type=strategy.percent_of_equity, 
     default_qty_value=100, 
     initial_capital=10000, 
     commission_value=0.04, 
     calc_on_every_tick=false, 
     slippage=0)

direction = input(0, title = "Strategy Direction", type=input.integer, minval=-1, maxval=1)
strategy.risk.allow_entry_in(direction == 0 ? strategy.direction.all : (direction < 0 ? strategy.direction.short : strategy.direction.long))

/////////////////////// STRATEGY INPUTS ////////////////////////////////////////
title1=input(true, "-----------------Strategy Inputs-------------------")  

i_NBars = input(defval=1, type=input.integer, title="# Of Inside Bars in pattern", options=[1, 2, 3, 4])
i_BarsDirection = input(false, title="Only trade using complete bullish or bearish patterns")
i_MAFilter = input(true, title="Use MA Trend Filter")
i_MALen = input(65, title="MA Length")

/////////////////////// BACKTESTER /////////////////////////////////////////////
title2=input(true, "-----------------General Inputs-------------------")  

// Backtester General Inputs
i_SL=input(true, title="Use Stop Loss and Take Profit")
i_SLType=input(defval="ATR Stop", title="Type Of Stop", options=["Strategy Stop", "Swing Lo/Hi", "ATR Stop"])
i_SPL=input(defval=10, title="Swing Point Lookback")
i_PercIncrement=input(defval=1, step=.1, title="Swing Point SL Perc Increment")*0.01
i_ATR = input(14, title="ATR Length")
i_ATRMult = input(5, step=.1, title="ATR Multiple")
i_TPRRR = input(2, step=.1, title="Take Profit Risk Reward Ratio")
TS=input(false, title="Trailing Stop")

// Bought and Sold Boolean Signal
bought = strategy.position_size > strategy.position_size[1] 
 or strategy.position_size < strategy.position_size[1]

// Price Action Stop and Take Profit
LL=(lowest(i_SPL))*(1-i_PercIncrement)
HH=(highest(i_SPL))*(1+i_PercIncrement)
LL_price = valuewhen(bought, LL, 0)
HH_price = valuewhen(bought, HH, 0)
entry_LL_price = strategy.position_size > 0 ? LL_price : na 
entry_HH_price = strategy.position_size < 0 ? HH_price : na 
tp=strategy.position_avg_price + (strategy.position_avg_price - entry_LL_price)*i_TPRRR
stp=strategy.position_avg_price - (entry_HH_price - strategy.position_avg_price)*i_TPRRR

// ATR Stop
ATR=atr(i_ATR)*i_ATRMult
ATRLong = ohlc4 - ATR
ATRShort = ohlc4 + ATR
ATRLongStop = valuewhen(bought, ATRLong, 0)
ATRShortStop = valuewhen(bought, ATRShort, 0)
LongSL_ATR_price = strategy.position_size > 0 ? ATRLongStop : na 
ShortSL_ATR_price = strategy.position_size < 0 ? ATRShortStop : na 
ATRtp=strategy.position_avg_price + (strategy.position_avg_price - LongSL_ATR_price)*i_TPRRR
ATRstp=strategy.position_avg_price - (ShortSL_ATR_price - strategy.position_avg_price)*i_TPRRR


// Strategy Stop
float LongStop = valuewhen(bought,low[1],0)*(1-i_PercIncrement)
float ShortStop = valuewhen(bought,high[1],0)*(1+i_PercIncrement)
float StratTP = na
float StratSTP = na

/////////////////////// STRATEGY LOGIC /////////////////////////////////////////

MAFilter=close > sma(close, i_MALen)
plot(i_MAFilter ? sma(close, i_MALen) : na)
bullBar=close > open
bearBar=close < open
contbullBar=barssince(not bullBar) >= (i_NBars+1)
contbearBar=barssince(not bearBar) >= (i_NBars+1)

InsideBar(NBars) =>
    Inside1Bar=high < high[1] and low > low[1] 
    Inside2Bar=high < high[2] and low > low[2] and Inside1Bar
    Inside3Bar=high < high[3] and low > low[3] and Inside1Bar and Inside2Bar
    Inside4Bar=high < high[4] and low > low[4] and Inside1Bar and Inside2Bar and Inside3Bar
    if NBars == 1
        inside1Bar=Inside1Bar
        [inside1Bar]
    else if NBars == 2
        inside2Bar=Inside2Bar
        [inside2Bar]
    else if NBars == 3
        inside3Bar=Inside3Bar   
        [inside3Bar]
    else if NBars == 4
        inside4Bar=Inside4Bar
        [inside4Bar]
    else
        [na]
[insideBar] = InsideBar(i_NBars) 
    
bullInsideBar=bar_index > 40 and insideBar and bullBar 
     and (i_BarsDirection ? contbullBar : true) and (i_MAFilter ? MAFilter : true)
bearInsideBar=bar_index > 40 and insideBar and bearBar 
     and (i_BarsDirection ? contbearBar : true) and (i_MAFilter ? not MAFilter : true)

BUY = bullInsideBar
SELL = bearInsideBar

//Debugging Plots
plot(contbullBar ? 1:0, transp=100, title="contbullBar")
plot(contbearBar ? 1:0, transp=100, title="contbearBar")

//Trading Inputs
DPR=input(true, "Allow Direct Position Reverse")
reverse=input(false, "Reverse Trades")

// Entries
if reverse
    if not DPR
        strategy.entry("long", strategy.long, when=SELL and strategy.position_size == 0)
        strategy.entry("short", strategy.short, when=BUY and strategy.position_size == 0)
    else     
        strategy.entry("long", strategy.long, when=SELL)
        strategy.entry("short", strategy.short, when=BUY)
else
    if not DPR 
        strategy.entry("long", strategy.long, when=BUY and strategy.position_size == 0)
        strategy.entry("short", strategy.short, when=SELL and strategy.position_size == 0)
    else
        strategy.entry("long", strategy.long, when=BUY)
        strategy.entry("short", strategy.short, when=SELL)

SL= i_SLType == "Swing Lo/Hi" ? entry_LL_price : i_SLType == "ATR Stop" ? LongSL_ATR_price : LongStop
SSL= i_SLType == "Swing Lo/Hi" ? entry_HH_price : i_SLType == "ATR Stop" ? ShortSL_ATR_price : ShortStop
TP= i_SLType == "Swing Lo/Hi" ? tp : i_SLType == "ATR Stop" ? ATRtp : StratTP
STP= i_SLType == "Swing Lo/Hi" ? stp : i_SLType == "ATR Stop" ? ATRstp : StratSTP

//TrailingStop
dif=(valuewhen(strategy.position_size>0 and strategy.position_size[1]<=0, high,0))
 -strategy.position_avg_price
trailOffset     = strategy.position_avg_price - SL
var tstop = float(na)
if strategy.position_size > 0
    tstop := high- trailOffset - dif
    if tstop<tstop[1]
        tstop:=tstop[1]
else
    tstop := na
StrailOffset     = SSL - strategy.position_avg_price
var Ststop = float(na)
Sdif=strategy.position_avg_price-(valuewhen(strategy.position_size<0 
 and strategy.position_size[1]>=0, low,0))
if strategy.position_size < 0
    Ststop := low+ StrailOffset + Sdif
    if Ststop>Ststop[1]
        Ststop:=Ststop[1]
else
    Ststop := na

strategy.exit("TP & SL", "long", limit=TP, stop=TS? tstop : SL, when=i_SL)
strategy.exit("TP & SL", "short", limit=STP, stop=TS? Ststop : SSL, when=i_SL)

/////////////////////// PLOTS //////////////////////////////////////////////////

plot(i_SL and strategy.position_size > 0 and not TS ? SL : i_SL and strategy.position_size > 0 and TS ? tstop : na , title='SL', style=plot.style_cross, color=color.red)
plot(i_SL and strategy.position_size < 0 and not TS ? SSL : i_SL and strategy.position_size < 0 and TS ? Ststop : na , title='SSL', style=plot.style_cross, color=color.red)
plot(i_SL and strategy.position_size > 0 ? TP : na, title='TP', style=plot.style_cross, color=color.green)
plot(i_SL and strategy.position_size < 0 ? STP : na, title='STP', style=plot.style_cross, color=color.green)
// Draw price action setup arrows
plotshape(BUY ? 1 : na, style=shape.triangleup, location=location.belowbar, 
 color=color.green, title="Bullish Setup", size=size.auto)
plotshape(SELL ? 1 : na, style=shape.triangledown, location=location.abovebar, 
 color=color.red, title="Bearish Setup", size=size.auto)

Más.