En la carga de los recursos... Cargando...
  1. Cuadrado
  2. Teoría de la negociación dinámica: media móvil exponencial y estrategia de cruce de período de volumen acumulado

Teoría de la negociación dinámica: media móvil exponencial y estrategia de cruce de período de volumen acumulado

El autor:¿ Qué pasa?, fecha: 2025-01-06 11:45:38
Las etiquetas:El EMAEl CVPEl PPAVTérmino de ejecución

img

Resumen general

Esta estrategia es un sistema de negociación que combina el promedio móvil exponencial (EMA) y el período de volumen acumulado (CVP). Captura los puntos de inversión de tendencia del mercado mediante el análisis del cruce entre el precio EMA y el precio ponderado por volumen acumulado. La estrategia incluye un filtro de tiempo incorporado para limitar las sesiones de negociación y admite el cierre automático de la posición al final de los períodos de negociación. Ofrece dos métodos de salida diferentes: salida de cruce inverso y salida CVP personalizada, proporcionando una gran flexibilidad y adaptabilidad.

Principio de la estrategia

La lógica central de la estrategia se basa en los siguientes cálculos clave:

  1. Cálcule el precio promedio (AVWP): Multiplique la media aritmética de los precios altos, bajos y cerrados con el volumen.
  2. Calcular el valor acumulado del volumen durante el período: sumar los precios ponderados por volumen durante el período establecido y dividir por el volumen acumulado.
  3. Se calculará la EMA del precio de cierre y la EMA del CVP por separado.
  4. Generar señales largas cuando el precio cruza la EMA por encima de la EMA del CVP; generar señales cortas cuando el precio cruza la EMA por debajo de la EMA del CVP.
  5. Las señales de salida pueden ser señales de cruce inverso o señales basadas en períodos CVP personalizados.

Ventajas estratégicas

  1. Sistema de señal robusto: combina la tendencia de precios y la información sobre el volumen para un juicio más preciso de la dirección del mercado.
  2. Alta adaptabilidad: puede adaptarse a diferentes entornos de mercado ajustando los períodos de EMA y CVP.
  3. Gestión completa del riesgo: El filtro de tiempo incorporado evita que se negocie durante períodos inadecuados.
  4. Mecanismo de salida flexible: Proporciona dos métodos de salida diferentes para elegir según las características del mercado.
  5. Buena visualización: La estrategia proporciona una interfaz gráfica clara que incluye marcadores de señal y llenado de área de tendencia.

Riesgos estratégicos

  1. Riesgo de retraso: la EMA tiene un retraso inherente, que puede causar ligeros retrasos en los plazos de entrada y salida.
  2. Riesgo de oscilación: puede generar señales falsas en los mercados laterales.
  3. Sensibilidad de los parámetros: las diferentes combinaciones de parámetros pueden dar lugar a variaciones significativas en el rendimiento.
  4. Riesgo de liquidez: los cálculos de CVP pueden ser inexactos en mercados con baja liquidez.
  5. Dependencia de la zona horaria: La estrategia utiliza la hora de Nueva York para el filtrado del tiempo, lo que requiere atención a las diferentes horas de negociación del mercado.

Direcciones para la optimización de la estrategia

  1. Introducir un filtro de volatilidad: ajustar los parámetros de la estrategia basados en la volatilidad del mercado para mejorar la adaptabilidad.
  2. Optimizar el filtro de tiempo: agregar varias ventanas de tiempo para un control más preciso de la sesión de negociación.
  3. Añadir evaluación de calidad de volumen: introducir indicadores de análisis de volumen para filtrar las señales de volumen de baja calidad.
  4. Ajuste dinámico de parámetros: Desarrollar un sistema de parámetros adaptativos para ajustar automáticamente los períodos de EMA y CVP en función de las condiciones del mercado.
  5. Añadir Indicadores de Sentimiento del Mercado: Combinar con otros indicadores técnicos para confirmar las señales comerciales.

Resumen de las actividades

Esta es una estrategia de negociación cuantitativa con una estructura completa y una lógica clara. Al combinar las ventajas de EMA y CVP, crea un sistema de negociación que puede capturar tendencias y centrarse en el control de riesgos. La estrategia es altamente personalizable y adecuada para su uso en diferentes entornos de mercado. A través de la implementación de sugerencias de optimización, hay espacio para una mayor mejora del rendimiento.

/*backtest
start: 2019-12-23 08:00:00
end: 2025-01-04 08:00:00
period: 1d
basePeriod: 1d
exchanges: [{"eid":"Futures_Binance","currency":"BTC_USDT"}]
*/

//@version=5
// © sapphire_edge 

// # ========================================================================= #
// #                  
// #        _____                   __    _              ______    __         
// #      / ___/____ _____  ____  / /_  (_)_______     / ____/___/ /___ ____ 
// #      \__ \/ __ `/ __ \/ __ \/ __ \/ / ___/ _ \   / __/ / __  / __ `/ _ \
// #     ___/ / /_/ / /_/ / /_/ / / / / / /  /  __/  / /___/ /_/ / /_/ /  __/
// #    /____/\__,_/ .___/ .___/_/ /_/_/_/   \___/  /_____/\__,_/\__, /\___/ 
// #              /_/   /_/                                     /____/       
// #                                      
// # ========================================================================= #

strategy(shorttitle="⟡Sapphire⟡ EMA/CVP", title="[Sapphire] EMA/CVP Strategy", initial_capital= 50000, currency= currency.USD,default_qty_value = 1,commission_type= strategy.commission.cash_per_contract,overlay= true )

// # ========================================================================= #
// #                       // Settings Menu //
// # ========================================================================= #

// --------------------    Main Settings    -------------------- //
groupEMACVP = "EMA / Cumulative Volume Period"
tradeDirection = input.string(title='Trade Direction', defval='LONG', options=['LONG', 'SHORT'], group=groupEMACVP)
emaLength = input.int(25, title='EMA Length', minval=1, maxval=200, group=groupEMACVP)
cumulativePeriod = input.int(100, title='Cumulative Volume Period', minval=1, maxval=200, step=5, group=groupEMACVP)
exitType = input.string(title="Exit Type", defval="Crossover", options=["Crossover", "Custom CVP" ], group=groupEMACVP)
cumulativePeriodForClose = input.int(50, title='Cumulative Period for Close Signal', minval=1, maxval=200, step=5, group=groupEMACVP)
showSignals = input.bool(true, title="Show Signals", group=groupEMACVP)
signalOffset = input.int(5, title="Signal Vertical Offset", group=groupEMACVP)

// --------------------    Time Filter Inputs    -------------------- //
groupTimeOfDayFilter = "Time of Day Filter"
useTimeFilter1  = input.bool(false, title="Enable Time Filter 1", group=groupTimeOfDayFilter)
startHour1      = input.int(0, title="Start Hour (24-hour format)", minval=0, maxval=23, group=groupTimeOfDayFilter)
startMinute1    = input.int(0, title="Start Minute", minval=0, maxval=59, group=groupTimeOfDayFilter)
endHour1        = input.int(23, title="End Hour (24-hour format)", minval=0, maxval=23, group=groupTimeOfDayFilter)
endMinute1      = input.int(45, title="End Minute", minval=0, maxval=59, group=groupTimeOfDayFilter)
closeAtEndTimeWindow = input.bool(false, title="Close Trades at End of Time Window", group=groupTimeOfDayFilter)

// --------------------    Trading Window    -------------------- //
isWithinTradingWindow(startHour, startMinute, endHour, endMinute) =>
    nyTime            = timestamp("America/New_York", year, month, dayofmonth, hour, minute)
    nyHour            = hour(nyTime)
    nyMinute          = minute(nyTime)
    timeInMinutes     = nyHour * 60 + nyMinute
    startInMinutes    = startHour * 60 + startMinute
    endInMinutes      = endHour * 60 + endMinute
    timeInMinutes    >= startInMinutes and timeInMinutes <= endInMinutes

timeCondition =  (useTimeFilter1 ? isWithinTradingWindow(startHour1, startMinute1, endHour1, endMinute1) : true)

// Check if the current bar is the last one within the specified time window
isEndOfTimeWindow() =>
    nyTime            = timestamp("America/New_York", year, month, dayofmonth, hour, minute)
    nyHour            = hour(nyTime)
    nyMinute          = minute(nyTime)
    timeInMinutes     = nyHour * 60 + nyMinute
    endInMinutes      = endHour1 * 60 + endMinute1
    timeInMinutes == endInMinutes

// Logic to close trades if the time window ends
if timeCondition and closeAtEndTimeWindow and isEndOfTimeWindow()
    strategy.close_all(comment="Closing trades at end of time window")

// # ========================================================================= #
// #                       // Calculations //
// # ========================================================================= #

avgPrice = (high + low + close) / 3
avgPriceVolume = avgPrice * volume

cumulPriceVolume = math.sum(avgPriceVolume, cumulativePeriod)
cumulVolume = math.sum(volume, cumulativePeriod)
cumValue = cumulPriceVolume / cumulVolume

cumulPriceVolumeClose = math.sum(avgPriceVolume, cumulativePeriodForClose)
cumulVolumeClose = math.sum(volume, cumulativePeriodForClose)
cumValueClose = cumulPriceVolumeClose / cumulVolumeClose

emaVal = ta.ema(close, emaLength)
emaCumValue = ta.ema(cumValue, emaLength)

// # ========================================================================= #
// #                       // Signal Logic //
// # ========================================================================= #

// Strategy Entry Conditions
longEntryCondition = ta.crossover(emaVal, emaCumValue) and tradeDirection == 'LONG'
shortEntryCondition = ta.crossunder(emaVal, emaCumValue) and tradeDirection == 'SHORT'

// User-Defined Exit Conditions
longExitCondition = false
shortExitCondition = false

if exitType == "Crossover"
    longExitCondition := ta.crossunder(emaVal, emaCumValue)
    shortExitCondition := ta.crossover(emaVal, emaCumValue)

if exitType == "Custom CVP"
    emaCumValueClose = ta.ema(cumValueClose, emaLength)
    longExitCondition := ta.crossunder(emaVal, emaCumValueClose)
    shortExitCondition := ta.crossover(emaVal, emaCumValueClose)

// # ========================================================================= #
// #                       // Strategy Management //
// # ========================================================================= #

// Strategy Execution
if longEntryCondition and timeCondition
    strategy.entry('Long', strategy.long)
    label.new(bar_index, high - signalOffset, "◭", style=label.style_label_up, color = color.rgb(119, 0, 255, 20), textcolor=color.white)

if shortEntryCondition and timeCondition
    strategy.entry('Short', strategy.short)
    label.new(bar_index, low + signalOffset, "⧩", style=label.style_label_down, color = color.rgb(255, 85, 0, 20), textcolor=color.white)

if strategy.position_size > 0 and longExitCondition
    strategy.close('Long')

if strategy.position_size < 0 and shortExitCondition
    strategy.close('Short')

// # ========================================================================= #
// #                         // Plots and Charts //
// # ========================================================================= #

plot(emaVal, title='EMA', color=color.new(color.green, 25))
plot(emaCumValue, title='Cumulative EMA', color=color.new(color.purple, 35))
fill(plot(emaVal), plot(emaCumValue), color=emaVal > emaCumValue ? #008ee6 : #d436a285, title='EMA and Cumulative Area', transp=70)
Relacionados
Más.

2019 FMZ - Todos los derechos reservados