Les ressources ont été chargées... Je charge...
  1. Carré
  2. Stratégie de capture de ligne de moyenne mobile double

Stratégie de capture de ligne de moyenne mobile double

Auteur:ChaoZhang est là., Date: 2023-12-13 à 15h28
Les étiquettes:

img

Résumé

Cette stratégie utilise deux lignes moyennes mobiles pour déterminer la direction de la tendance du marché, combinées à des bandes de Bollinger pour identifier les conditions de surachat et de survente, afin d'obtenir des achats bas et des ventes élevées en vue de réaliser un profit.

La logique de la stratégie

La stratégie utilise des moyennes mobiles doubles pour déterminer l'orientation globale du marché, tout en s'appuyant sur les bandes de Bollinger pour des signaux d'entrée spécifiques.

La règle de la moyenne mobile double stipule le calcul d'une ligne moyenne mobile exponentielle à court terme et à long terme, la ligne à court terme traversant la ligne à long terme vers le haut indiquant un signal d'achat; la ligne à court terme traversant la ligne à long terme vers le bas constitue un signal de vente.

L'indicateur des bandes de Bollinger détermine si les prix sont surachetés ou survendus. La bande moyenne des bandes de Bollinger est la ligne moyenne mobile des prix de clôture de n périodes, tandis que la largeur de bande représente l'écart type de la moyenne mobile au cours des n dernières périodes. Les prix qui s'approchent de la bande supérieure indiquent une condition de surachat et ceux qui s'approchent de la bande inférieure constituent une situation de survente.

Les règles de stratégie sont définies comme suit: Lorsque la ligne moyenne courte traverse la ligne moyenne longue vers le haut plus le prix de clôture qui pénètre au-dessus de la bande supérieure de Bollinger, passez long. Lorsque la ligne courte traverse la ligne longue vers le bas plus les prix de clôture qui tombent en dessous de la bande inférieure de Bollinger, passez court.

Le stop loss après une vente à découvert est fixé au plus bas des derniers n jours, tandis que le take profit est placé à 1,6 fois le prix d'entrée.

En outre, la stratégie tient compte de l'indice de tendance EMA afin d'éviter les renversements de tendance.

Analyse des avantages

  1. L' utilisation de moyennes mobiles doubles pour déterminer la direction globale combinée à des bandes de Bollinger pour mettre en évidence des points d' entrée spécifiques représente une combinaison d' indicateurs raisonnable;
  2. L' adoption du plus bas niveau sur n jours comme stop loss pour les longs et du plus haut niveau sur n jours comme stop loss pour les shorts contribue à réduire les chances d' exécution des stops;
  3. La fixation de l'objectif de réalisation de bénéfices à 1,6 fois le prix d'entrée facilite la réalisation de gains suffisants;
  4. En tenant compte de l'indice de tendance de l'EMA, il aide à éviter les transactions contre tendance majeure, réduisant les pertes du système.

Analyse des risques

  1. Une optimisation inappropriée des paramètres des bandes de Bollinger peut entraîner une négociation trop fréquente ou des signaux insuffisants;
  2. Les points d'arrêt de perte trop lâches entraînent des pertes plus importantes;
  3. Des restrictions de prise de profit trop strictes entraînent la perte de gains plus importants.

Pour faire face aux risques susmentionnés, optimiser les combinaisons de paramètres de Bollinger et tester différents niveaux de seuil de stop loss/capture de profit afin de sélectionner les paramètres optimaux.

Direction de l'optimisation

  1. Optimiser les paramètres d'entrée des bandes de Bollinger pour localiser les combinaisons idéales;
  2. Examiner les différents paramètres d'augmentation des stops pour réduire les risques d'arrêt;
  3. Les tests assortis prennent des valeurs de multiplicateur de profit pour capturer les gains les plus importants possibles.

Conclusion

Cette stratégie s'est avérée crédible dans les backtests en confirmant la tendance globale à l'aide de moyennes mobiles doubles et en s'appuyant sur les bandes de Bollinger pour des signaux d'entrée spécifiques. Des améliorations supplémentaires de la performance peuvent être anticipées grâce à une optimisation continue des paramètres et à des modifications des règles. Le mécanisme de stop loss / profit taking est également transférable à d'autres systèmes pour l'adaptation.

/*backtest
start: 2023-12-05 00:00:00
end: 2023-12-06 22:00:00
period: 15m
basePeriod: 5m
exchanges: [{"eid":"Futures_Binance","currency":"BTC_USDT"}]
*/

// This close code is subject to the terms of the Mozilla Public License 2.0 at https://mozilla.org/MPL/2.0/
// © AugustoErni

//@version=5
strategy('Bollinger Bands Modified (Stormer)', overlay=true)

bbL                   = input.int(20, title='BB Length/Comprimento da Banda de Bollinger', minval=1, step=1, tooltip='Calculate the length of bollinger bands./Calcula o comprimento das bandas de bollinger.')
mult                  = input.float(0.38, title='BB Standard Deviation/Desvio Padrão da Banda de Bollinger', minval=0.01, step=0.01, tooltip='Calculate the standard deviation of bollinger bands./Calcula o desvio padrão das bandas de bollinger.')
emaL                  = input.int(80, title='EMA Length/Comprimento da Média Móvel Exponencial', minval=1, step=1, tooltip='Calculate the length of EMA./Calcula o comprimento da EMA.')
highestHighL          = input.int(7, title='Highest High Length/Comprimento da Alta Maior', minval=1, step=1, tooltip='Fetches the highest high candle from length input. Use to set stop loss for short position./Obtém a vela de maior alta com base na medida fornecida. Usa para definir o stop loss para uma posição curta.')
lowestLowL            = input.int(7, title='Lowest Low Length/Comprimento da Baixa Menor', minval=1, step=1, tooltip='Fetches the lowest low candle from length input. Use to set stop loss for long position./Obter a vela de menor baixa com base na medida fornecida. Usa para definir o stop loss para uma posição longa.')
targetFactor          = input.float(1.6, title='Target Take Profit/Objetivo de Lucro Alvo', minval=0.1, step=0.1, tooltip='Calculate the take profit factor when entry position./Calcula o fator do alvo lucro ao entrar na posição.')
emaTrend              = input.bool(true, title='Check Trend EMA/Verificar Tendência da Média Móvel Exponencial', tooltip='Use EMA as trend verify for opening position./Usa a EMA como verificação de tendência para abrir posição.')
crossoverCheck        = input.bool(false, title='Add Another Crossover Check/Adicionar Mais uma Verificação de Cruzamento Superior', tooltip='This option is to add one more veryfication attempt to check if price is crossover upper bollinger band./Esta opção é para adicionar uma verificação adicional para avaliar se o preço cruza a banda superior da banda de bollinger.')
crossunderCheck       = input.bool(false, title='Add Another Crossunder Check/Adicionar Mais uma Verificação de Cruzamento Inferior', tooltip='This option is to add one more veryfication attempt to check if price is crossunder lower bollinger band./Esta opção é para adicionar uma verificação adicional para avaliar se o preço cruza a banda inferior da banda de bollinger.')
insideBarPatternCheck = input.bool(true, title='Show Inside Bar Pattern/Mostrar Padrão de Inside Bar', tooltip='This option is to show possible inside bar pattern./Esta opção é para mostrar um possível padrão de inside bar.')

[middle, upper, lower] = ta.bb(close, bbL, mult)
ema                    = ta.ema(close, emaL)
highestHigh            = ta.highest(high, highestHighL)
lowestLow              = ta.lowest(low, lowestLowL)
isCrossover            = ta.crossover(close, upper) ? 1 : 0
isCrossunder           = ta.crossunder(close, lower) ? 1 : 0

isPrevBarHighGreaterCurBarHigh = high[1] > high ? 1 : 0
isPrevBarLowLesserCurBarLow    = low[1] < low ? 1 : 0
isInsideBar                    = isPrevBarHighGreaterCurBarHigh and isPrevBarLowLesserCurBarLow ? 1 : 0

isBarLong  = ((close - open) > 0) ? 1 : 0
isBarShort = ((close - open) < 0) ? 1 : 0

isLongCross  = crossoverCheck ? ((isBarLong and not isBarShort) and (open < upper and close > upper)) ? 1 : 0 : isCrossover ? 1 : 0
isShortCross = crossunderCheck ? ((isBarShort and not isBarLong) and (close < lower and open > lower)) ? 1 : 0 : isCrossunder ? 1 : 0

isCandleAboveEma = close > ema ? 1 : 0
isCandleBelowEma = close < ema ? 1 : 0

isLongCondition  = emaTrend ? isLongCross and isCandleAboveEma ? 1 : 0 : isLongCross
isShortCondition = emaTrend ? isShortCross and isCandleBelowEma ? 1 : 0 : isShortCross

isPositionNone  = strategy.position_size == 0 ? 1 : 0
isPositionLong  = strategy.position_size > 0 ? 1 : 0
isPositionShort = strategy.position_size < 0 ? 1 : 0

var float enterLong     = 0.0
var float stopLossLong  = 0.0
var float targetLong    = 0.0
var float enterShort    = 0.0
var float stopLossShort = 0.0
var float targetShort   = 0.0
var bool isLongEntry    = false
var bool isShortEntry   = false

if (isPositionNone)
    isLongEntry   := false
    isShortEntry  := false
    enterLong     := 0.0
    stopLossLong  := 0.0
    targetLong    := 0.0
    enterShort    := 0.0
    stopLossShort := 0.0
    targetShort   := 0.0
if (isPositionShort or isPositionNone)
    isLongEntry  := false
    enterLong    := 0.0
    stopLossLong := 0.0
    targetLong   := 0.0
if (isPositionLong or isPositionNone)
    isShortEntry  := false
    enterShort    := 0.0
    stopLossShort := 0.0
    targetShort   := 0.0
if (isPositionLong and isLongEntry)
    isLongEntry   := true
    isShortEntry  := false
    enterShort    := 0.0
    stopLossShort := 0.0
    targetShort   := 0.0
if (isPositionShort and isShortEntry)
    isShortEntry := true
    isLongEntry  := false
    enterLong    := 0.0
    stopLossLong := 0.0
    targetLong   := 0.0

if (isLongCondition and not isLongEntry)
    isLongEntry  := true
    enterLong    := close
    stopLossLong := lowestLow
    targetLong   := (enterLong + (math.abs(enterLong - stopLossLong) * targetFactor))
    alertMessage = '{ "side/lado": "buy", "entry/entrada": ' + str.tostring(enterLong) + ', "stop": ' + str.tostring(stopLossLong) + ', "target/alvo": ' + str.tostring(targetLong) + ' }'
    alert(alertMessage)
    strategy.entry('Long', strategy.long)
    strategy.exit('Exit Long', 'Long', stop=stopLossLong, limit=targetLong)

if (isShortCondition and not isShortEntry)
    isShortEntry  := true
    enterShort    := close
    stopLossShort := highestHigh
    targetShort   := (enterShort - (math.abs(enterShort - stopLossShort) * targetFactor))
    alertMessage = '{ "side/lado": "sell", "entry/entrada": ' + str.tostring(enterShort) + ', "stop": ' + str.tostring(stopLossShort) + ', "target/alvo": ' + str.tostring(targetShort) + ' }'
    alert(alertMessage)
    strategy.entry('Short', strategy.short)
    strategy.exit('Exit Short', 'Short', stop=stopLossShort, limit=targetShort)

plot(upper, title='Upper Band', color=color.blue)
plot(middle, title='Middle Band', color=color.gray)
plot(lower, title='Lower Band', color=color.blue)
plot(ema, title='EMA', color=color.white)

barcolor(insideBarPatternCheck and isInsideBar and isBarLong ? color.lime : insideBarPatternCheck and isInsideBar and isBarShort ? color.maroon : na, title='Inside Bar Color in Long Bar Long and in Short Bar Short/Cor do Inside Bar em Barra Longa Longa e em Barra Curta Curta')

tablePosition    = position.bottom_right
tableColumns     = 2
tableRows        = 5
tableFrameWidth  = 1
tableBorderColor = color.gray
tableBorderWidth = 1

tableInfoTrade = table.new(position=tablePosition, columns=tableColumns, rows=tableRows, frame_width=tableFrameWidth, border_color=tableBorderColor, border_width=tableBorderWidth)

table.cell(table_id=tableInfoTrade, column=0, row=0)
table.cell(table_id=tableInfoTrade, column=1, row=0)

table.cell(table_id=tableInfoTrade, column=0, row=1, text='Entry Side/Lado da Entrada', text_color=color.white)
table.cell(table_id=tableInfoTrade, column=0, row=2, text=isLongEntry ? 'LONG' : isShortEntry ? 'SHORT' : 'NONE/NENHUM', text_color=color.yellow)

table.cell(table_id=tableInfoTrade, column=1, row=1, text='Entry Price/Preço da Entrada', text_color=color.white)
table.cell(table_id=tableInfoTrade, column=1, row=2, text=isLongEntry ? str.tostring(enterLong) : isShortEntry ? str.tostring(enterShort) : 'NONE/NENHUM', text_color=color.blue)

table.cell(table_id=tableInfoTrade, column=0, row=3, text='Take Profit Price/Preço Alvo Lucro', text_color=color.white)
table.cell(table_id=tableInfoTrade, column=0, row=4, text=isLongEntry ? str.tostring(targetLong) : isShortEntry ? str.tostring(targetShort) : 'NONE/NENHUM', text_color=color.green)

table.cell(table_id=tableInfoTrade, column=1, row=3, text='Stop Loss Price/Preço Stop Loss', text_color=color.white)
table.cell(table_id=tableInfoTrade, column=1, row=4, text=isLongEntry ? str.tostring(stopLossLong) : isShortEntry ? str.tostring(stopLossShort) : 'NONE/NENHUM', text_color=color.red)
Plus de

2019 FMZ - Tous les droits réservés