Les ressources ont été chargées... Je charge...

Stratégie de négociation à double sens de la moyenne mobile multiplicative

Auteur:ChaoZhang est là., Date: 2024-01-15 14h50: 32
Les étiquettes:

Résumé

Cette stratégie calcule la ligne de moyenne mobile multiplicative et combine les croisements de prix et l'indicateur PMax pour déterminer la direction de la tendance.

Principe de stratégie

L'indicateur de base de cette stratégie est la ligne de moyenne mobile multiplicative. Les paramètres de l'indicateur comprennent: période ATR, multiplicateur ATR, type et longueur de moyenne mobile. La valeur ATR représente la volatilité sur la période. La ligne de moyenne mobile multiplicative est égale au prix moyen plus / moins le produit du multiplicateur ATR et de l'ATR sur la période. Lorsque le prix est au-dessus de la ligne, il y a un signal long. Lorsque le prix est en dessous de la ligne, il y a un signal court.

L'indicateur PMax représente le prix de stop loss ou de prise de profit. Il est calculé à partir de la valeur de l'ATR et de la direction de la tendance. Dans la tendance haussière, PMax est égal à la moyenne mobile moins le multiplicateur ATR fois ATR, agissant comme une ligne de stop loss. Dans la tendance baissière, PMax est égal à la moyenne mobile plus le multiplicateur ATR fois ATR, agissant comme une ligne de prise de profit.

Lorsque le prix traverse l'indicateur PMax vers le haut, il y a un signal long. Lorsque le prix traverse l'indicateur PMax vers le bas, il y a un signal court. La stratégie entre et sort basée sur les signaux, allant long dans la tendance haussière et court dans la tendance baissière, avec un stop loss dynamique et un profit.

Analyse des avantages

Les avantages de cette stratégie:

L'adoption du commerce bidirectionnel le rend très inclusif de toutes les conditions du marché.
L'application d'une moyenne mobile multiplicative produit des signaux de négociation stables et fiables.
Avec PMax pour stop loss/take profit, il contrôle efficacement le risque.
Le cycle réglable et les paramètres du multiplicateur le rendent très adaptable.

Analyse des risques

Il y a aussi des risques:

Des paramètres mal réglés peuvent entraîner des pertes.
Faites attention aux limites d'effet de levier lors de la mise à court.
Les événements du cygne noir sont difficiles à éviter.

Les solutions:

Optimisez les paramètres pour réduire les coups de fouet.
Contrôlez l'effet de levier avec prudence et diversifiez.
Augmentez le multiplicateur ATR pour élargir la portée d'arrêt.

Directions d'optimisation

La stratégie peut être améliorée de manière à:

Testez la stabilité sur différents marchés et cycles.
Appliquer l'apprentissage automatique pour optimiser automatiquement les paramètres.
Jugez les régimes du marché avec des techniques d'apprentissage profond.
Intégrer plus de sources de données pour renforcer les décisions.

Résumé

La performance globale de cette stratégie est stable avec une forte inclusion. En adoptant le commerce bidirectionnel et le stop loss / take profit dynamique, il contrôle efficacement les risques. Grâce à l'ajustement des paramètres et à l'itération du modèle, l'aptitude et l'efficacité de la stratégie peuvent être encore améliorées. En général, il s'agit d'une stratégie qui mérite une attention et une application à long terme.

/*backtest
start: 2023-01-08 00:00:00
end: 2024-01-14 00:00:00
period: 1d
basePeriod: 1h
exchanges: [{"eid":"Futures_Binance","currency":"BTC_USDT"}]
*/

// This source code is subject to the terms of the Mozilla Public License 2.0 at https://mozilla.org/MPL/2.0/
// © melihtuna
//developer: @KivancOzbilgic
//author: @KivancOzbilgic
//stretegy converter: @crypto_melih
//@version=4

strategy("Profit Maximizer Strategy Long-Short", shorttitle="PMax-Strategy", overlay=true, default_qty_type=strategy.cash, default_qty_value=10000, initial_capital=10000, currency=currency.USD, commission_value=0, commission_type=strategy.commission.percent)

src = input(hl2, title="Source")
Periods = input(title="ATR Length", type=input.integer, defval=10)
Multiplier = input(title="ATR Multiplier", type=input.float, step=0.1, defval=3.0)
mav = input(title="Moving Average Type", defval="EMA", options=["SMA", "EMA", "WMA", "TMA", "VAR", "WWMA", "ZLEMA", "TSF"])
length =input(10, "Moving Average Length", minval=1)
condition = input(title="Signal Type", defval="Only Crossing Signals", options=["Only Crossing Signals", "Only Price/Pmax Crossing Signals"])
changeATR= input(title="Change ATR Calculation Method ?", type=input.bool, defval=true)
showsupport = input(title="Show Moving Average?", type=input.bool, defval=true)
//showsignalsk = input(title="Show Crossing Signals?", type=input.bool, defval=true)
//showsignalsc = input(title="Show Price/Pmax Crossing Signals?", type=input.bool, defval=false)
highlighting = input(title="Highlighter On/Off ?", type=input.bool, defval=true)
long_short = input(defval = false, title = "Long-Short", type=input.bool)
atr2 = sma(tr, Periods)
atr= changeATR ? atr(Periods) : atr2
valpha=2/(length+1)
vud1=src>src[1] ? src-src[1] : 0
vdd1=src<src[1] ? src[1]-src : 0
vUD=sum(vud1,9)
vDD=sum(vdd1,9)
vCMO=nz((vUD-vDD)/(vUD+vDD))
VAR=0.0
VAR:=nz(valpha*abs(vCMO)*src)+(1-valpha*abs(vCMO))*nz(VAR[1])
wwalpha = 1/ length
WWMA = 0.0
WWMA := wwalpha*src + (1-wwalpha)*nz(WWMA[1])
zxLag = length/2==round(length/2) ? length/2 : (length - 1) / 2
zxEMAData = (src + (src - src[zxLag]))
ZLEMA = ema(zxEMAData, length)
lrc = linreg(src, length, 0)
lrc1 = linreg(src,length,1)
lrs = (lrc-lrc1)
TSF = linreg(src, length, 0)+lrs
getMA(src, length) =>
    ma = 0.0
    if mav == "SMA"
        ma := sma(src, length)
        ma

    if mav == "EMA"
        ma := ema(src, length)
        ma

    if mav == "WMA"
        ma := wma(src, length)
        ma

    if mav == "TMA"
        ma := sma(sma(src, ceil(length / 2)), floor(length / 2) + 1)
        ma

    if mav == "VAR"
        ma := VAR
        ma

    if mav == "WWMA"
        ma := WWMA
        ma

    if mav == "ZLEMA"
        ma := ZLEMA
        ma

    if mav == "TSF"
        ma := TSF
        ma
    ma
    
MAvg=getMA(src, length)
longStop = MAvg - Multiplier*atr
longStopPrev = nz(longStop[1], longStop)
longStop := MAvg > longStopPrev ? max(longStop, longStopPrev) : longStop
shortStop = MAvg + Multiplier*atr
shortStopPrev = nz(shortStop[1], shortStop)
shortStop := MAvg < shortStopPrev ? min(shortStop, shortStopPrev) : shortStop
dir = 1
dir := nz(dir[1], dir)
dir := dir == -1 and MAvg > shortStopPrev ? 1 : dir == 1 and MAvg < longStopPrev ? -1 : dir
PMax = dir==1 ? longStop: shortStop
plot(showsupport ? MAvg : na, color=#0585E1, linewidth=2, title="Moving Avg Line")
pALL=plot(PMax, color=color.red, linewidth=2, title="PMax", transp=0)
alertcondition(cross(MAvg, PMax), title="Cross Alert", message="PMax - Moving Avg Crossing!")
alertcondition(crossover(MAvg, PMax), title="Crossover Alarm", message="Moving Avg BUY SIGNAL!")
alertcondition(crossunder(MAvg, PMax), title="Crossunder Alarm", message="Moving Avg SELL SIGNAL!")
alertcondition(cross(src, PMax), title="Price Cross Alert", message="PMax - Price Crossing!")
alertcondition(crossover(src, PMax), title="Price Crossover Alarm", message="PRICE OVER PMax - BUY SIGNAL!")
alertcondition(crossunder(src, PMax), title="Price Crossunder Alarm", message="PRICE UNDER PMax - SELL SIGNAL!")
buySignalk = crossover(MAvg, PMax)
//plotshape(buySignalk and showsignalsk ? PMax*0.995 : na, title="Buy", text="Buy", location=location.absolute, style=shape.labelup, size=size.tiny, color=color.green, textcolor=color.white, transp=0)
sellSignallk = crossunder(MAvg, PMax)
//plotshape(sellSignallk and showsignalsk ? PMax*1.005 : na, title="Sell", text="Sell", location=location.absolute, style=shape.labeldown, size=size.tiny, color=color.red, textcolor=color.white, transp=0)
buySignalc = crossover(src, PMax)
//plotshape(buySignalc and showsignalsc ? PMax*0.995 : na, title="Buy", text="Buy", location=location.absolute, style=shape.labelup, size=size.tiny, color=#0F18BF, textcolor=color.white, transp=0)
sellSignallc = crossunder(src, PMax)
//plotshape(sellSignallc and showsignalsc ? PMax*1.005 : na, title="Sell", text="Sell", location=location.absolute, style=shape.labeldown, size=size.tiny, color=#0F18BF, textcolor=color.white, transp=0)
mPlot = plot(ohlc4, title="", style=plot.style_circles, linewidth=0,display=display.none)
longFillColor = highlighting ? (MAvg>PMax ? color.green : na) : na
shortFillColor = highlighting ? (MAvg<PMax ? color.red : na) : na
fill(mPlot, pALL, title="UpTrend Highligter", color=longFillColor)
fill(mPlot, pALL, title="DownTrend Highligter", color=shortFillColor)

if(condition=="Only Crossing Signals")
    strategy.entry("BUY", strategy.long, when = buySignalk)
else
    strategy.entry("BUY", strategy.long, when = buySignalc)

if(long_short)
    if(condition=="Only Crossing Signals")
        strategy.entry("SELL", strategy.short, when = sellSignallk)
    else
        strategy.entry("SELL", strategy.short, when = sellSignallc)
else
    if(condition=="Only Crossing Signals")
        strategy.close("BUY", when = sellSignallk)
    else
        strategy.close("BUY", when = sellSignallc)

Plus de

2019 FMZ - Tous les droits réservés