आविष्कारक ने पाइन भाषा के लिए क्वांटिफाइड परिचयात्मक ट्यूटोरियल

यह एक बहुत ही अच्छा विचार है। दो,trail_offsetपैरामीटरः ट्रैकिंग स्टॉप लॉस स्टॉप कैप क्रिया को करने के बाद, सबसे अधिक कीमत (अधिक करने पर) या सबसे कम कीमत (छोटे करने पर) की दूरी पर रखे गए पक्की इकाई की दूरी। 3।trail_pointsपैरामीटरः जैसेtrail_priceपैरामीटर, केवल एक स्थान के रूप में निर्दिष्ट है, जो कि लाभ संख्याओं के साथ निर्दिष्ट है।

यह समझना आसान नहीं है, कोई फर्क नहीं पड़ता! हम एक रणनीति के माध्यम से सीखने को समझने के लिए आते हैं, वास्तव में बहुत सरल है।

/*backtest
start: 2022-09-23 00:00:00
end: 2022-09-23 08:00:00
period: 1m
basePeriod: 1m
exchanges: [{"eid":"Binance","currency":"ETH_USDT"}]
args: [["RunMode",1,358374],["ZPrecision",0,358374]]
*/

strategy("test", overlay = true)

varip a = na
varip highPrice = na
varip isTrade = false 
varip offset = 30

if not barstate.ishistory and not isTrade
    strategy.entry("test 1", strategy.long, 1)
    strategy.exit("exit 1", "test 1", 1, trail_price=close+offset, trail_offset=offset)
    a := close + offset
    runtime.log("每点价格为：", syminfo.mintick, "，当前close:", close)
    isTrade := true 

if close > a and not barstate.ishistory
    highPrice := na(highPrice) ? close : highPrice
    highPrice := close > highPrice ? close : highPrice

plot(a, "trail_price 触发线")    
plot(strategy.position_size>0 ? highPrice : na, "当前最高价")
plot(strategy.position_size>0 ? highPrice-syminfo.mintick*offset : na, "移动止损触发线")

नीति को निष्पादित करने के तुरंत बाद बहु-प्रवेश करें, और तुरंत अगले पर क्लिक करेंstrategy.exitबाहर निकलने का आदेश (स्टॉप लॉस स्टॉप ब्रेक पैरामीटर निर्दिष्ट है) जब बाजार में बदलाव की कीमतों में वृद्धि ट्रेल_प्राइस ट्रिगर लाइन से अधिक होती है, तो ट्रेकिंग स्टॉप लॉस स्टॉप ब्रेक तर्क को निष्पादित करना शुरू होता है, स्टॉप लॉस स्टॉप ब्रेक लाइन (नीला) सबसे अधिक मूल्य गतिशील समायोजन का पालन करना शुरू करता है, नीली रेखा का स्थान स्टॉप लॉस स्टॉप ब्रेक ट्रिगर स्थिति का मूल्य है, और अंत में जब बाजार में बदलाव की कीमतें नीली रेखा को तोड़ती हैं, तो यह एक ब्रेक को ट्रिगर करती है। इस संयोजन में चार्ट पर खींची गई रेखाओं को समझना आसान है या नहीं।

तो हम इस सुविधा का उपयोग एक सुपर ट्रेंडिंग रणनीति को अनुकूलित करने के लिए करते हैं, और हम केवल रणनीति के लिए एक प्रवेश आदेश निर्दिष्ट करते हैं।strategy.exitइस तरह के ट्रैकिंग को रोकना और नुकसान को रोकना संभव है।

if not barstate.ishistory and findOrderIdx("open") >= 0 and state == 1
    trail_price := strategy.position_size > 0 ? close + offset : close - offset
    strategy.exit("exit", "open", 1, trail_price=trail_price, trail_offset=offset)
    runtime.log("每点价格为：", syminfo.mintick, "，当前close:", close, "，trail_price：", trail_price)
    state := 2 
    tradeBarIndex := bar_index

पूरी रणनीति कोडः

/*backtest
start: 2022-05-01 00:00:00
end: 2022-09-27 00:00:00
period: 1d
basePeriod: 5m
exchanges: [{"eid":"Binance","currency":"ETH_USDT"}]
args: [["RunMode",1,358374],["ZPrecision",0,358374]]
*/

varip trail_price = na
varip offset = input(50, "offset")
varip tradeBarIndex = 0
// 0 : idle , 1 current_open , 2 current_close
varip state = 0  

findOrderIdx(idx) =>
    ret = -1 
    if strategy.opentrades == 0 
        ret
    else 
        for i = 0 to strategy.opentrades - 1 
            if strategy.opentrades.entry_id(i) == idx
                ret := i 
                break
        ret

if strategy.position_size == 0 
    trail_price := na 
    state := 0

[superTrendPrice, dir] = ta.supertrend(input(2, "atr系数"), input(20, "atr周期"))

if ((dir[1] < 0 and dir[2] > 0) or (superTrendPrice[1] > superTrendPrice[2])) and state == 0 and tradeBarIndex != bar_index
    strategy.entry("open", strategy.long, 1)
    state := 1
else if ((dir[1] > 0 and dir[2] < 0) or (superTrendPrice[1] < superTrendPrice[2])) and state == 0 and tradeBarIndex != bar_index
    strategy.entry("open", strategy.short, 1)
    state := 1


// 反向信号，全平
if strategy.position_size > 0 and dir[2] < 0 and dir[1] > 0
    strategy.cancel_all()
    strategy.close_all()
    runtime.log("趋势反转，多头全平")
else if strategy.position_size < 0 and dir[2] > 0 and dir[1] < 0
    strategy.cancel_all()
    strategy.close_all()
    runtime.log("趋势反转，空头全平")


if not barstate.ishistory and findOrderIdx("open") >= 0 and state == 1
    trail_price := strategy.position_size > 0 ? close + offset : close - offset
    strategy.exit("exit", "open", 1, trail_price=trail_price, trail_offset=offset)
    runtime.log("每点价格为：", syminfo.mintick, "，当前close:", close, "，trail_price：", trail_price)
    state := 2 
    tradeBarIndex := bar_index


plot(superTrendPrice, "superTrendPrice", color=dir>0 ? color.red : color.green, overlay=true)