1. वर्ग
2. डबल सुपरट्रेंड मल्टी-स्टेप ट्रेलिंग टेक-प्रॉफिट रणनीति

डबल सुपरट्रेंड मल्टी-स्टेप ट्रेलिंग टेक-प्रॉफिट रणनीति

लेखक:चाओझांग, दिनांकः 2024-06-21 14:36:35
टैगःएटीआरएसटीटीपी

---

---

/*backtest
start: 2024-05-21 00:00:00
end: 2024-06-20 00:00:00
period: 4h
basePeriod: 15m
exchanges: [{"eid":"Futures_Binance","currency":"BTC_USDT"}]
*/

//@version=5
strategy("Strategic Multi-Step Supertrend Trader - Strategy [presentTrading]", overlay=true )

// this strategy utilizes a double Supertrend indicator to determine entry and exit conditions for both long and short trades, with user-configurable take profit levels and trade direction settings. 
// The strategy dynamically updates highest and lowest prices during trades and exits positions based on multi-step profit targets or opposing Supertrend signals.


// User inputs for take profit settings
// Grouping Take Profit settings
useTakeProfit = input.bool(true, title="Use Take Profit", group="Take Profit Settings")
takeProfitPercent1 = input.float(6.0, title="Take Profit % Step 1", group="Take Profit Settings")
takeProfitPercent2 = input.float(12.0, title="Take Profit % Step 2", group="Take Profit Settings")
takeProfitPercent3 = input.float(18.0, title="Take Profit % Step 3", group="Take Profit Settings")
takeProfitPercent4 = input.float(50.0, title="Take Profit % Step 4", group="Take Profit Settings")

takeProfitAmount1 = input.float(12, title="Take Profit Amount % Step 1", group="Take Profit Settings")
takeProfitAmount2 = input.float(8, title="Take Profit Amount % Step 2", group="Take Profit Settings")
takeProfitAmount3 = input.float(4, title="Take Profit Amount % Step 3", group="Take Profit Settings")
takeProfitAmount4 = input.float(0, title="Take Profit Amount % Step 4", group="Take Profit Settings")

numberOfSteps = input.int(3, title="Number of Take Profit Steps", minval=1, maxval=4, group="Take Profit Settings")

// Grouping Trade Direction
tradeDirection = input.string("Both", title="Trade Direction", options=["Long", "Short", "Both"], group="Trade Direction")

// Grouping Supertrend settings
atrPeriod1 = input(10, title="ATR Length for Supertrend 1", group="Supertrend Settings")
factor1 = input.float(3.0, title="Factor for Supertrend 1", step=0.01, group="Supertrend Settings")

atrPeriod2 = input(5, title="ATR Length for Supertrend 2", group="Supertrend Settings")
factor2 = input.float(4.0, title="Factor for Supertrend 2", step=0.01, group="Supertrend Settings")


// Function to calculate Supertrend
supertrend(factor, atrPeriod) =>
    [a, direction] = ta.supertrend(factor, atrPeriod)
    direction

// Calculate Double Supertrend
supertrend1 = supertrend(factor1, atrPeriod1)
supertrend2 = supertrend(factor2, atrPeriod2)

// Entry conditions
longCondition = (supertrend1 < 0 and supertrend2 < 0) and (tradeDirection == "Long" or tradeDirection == "Both")
shortCondition = (supertrend1 > 0 and supertrend2 > 0) and (tradeDirection == "Short" or tradeDirection == "Both")

// Exit conditions
longExitCondition = (supertrend1 > 0 and supertrend2 > 0) and (tradeDirection == "Long" or tradeDirection == "Both")
shortExitCondition = (supertrend1 < 0 and supertrend2 < 0) and (tradeDirection == "Short" or tradeDirection == "Both")

// Variables to store the highest and lowest prices during the trade
var float highestPrice = na
var float lowestPrice = na

// Get the entry price from open trades
entryPrice = strategy.opentrades.entry_price(strategy.opentrades - 1)

// Reset highestPrice or lowestPrice when entering new trades
if (longCondition and strategy.position_size <= 0)
    highestPrice := na // Reset the highest price
    strategy.entry("My Long Entry Id", strategy.long) // Enter long position
    strategy.close("My Short Entry Id", "Short Exit") // Close short position if any

if (shortCondition and strategy.position_size >= 0)
    lowestPrice := na // Reset the lowest price
    strategy.entry("My Short Entry Id", strategy.short) // Enter short position
    strategy.close("My Long Entry Id", "Long Exit") // Close long position if any

// Exit trades based on conditions
if (longExitCondition and strategy.position_size > 0)
    strategy.close("My Long Entry Id", "Long Exit") // Exit long position

if (shortExitCondition and strategy.position_size < 0)
    strategy.close("My Short Entry Id", "Short Exit") // Exit short position

if (strategy.position_size > 0)
    // Update the highest price for long positions
    highestPrice := na(highestPrice) ? high : math.max(highestPrice, high)

    // Step 1
    if (useTakeProfit and numberOfSteps >= 1)
        strategy.exit("Take Profit 1", from_entry="My Long Entry Id", qty_percent=takeProfitAmount1, limit=entryPrice * (1 + takeProfitPercent1 / 100))
    // Step 2
    if (useTakeProfit and numberOfSteps >= 2)
        strategy.exit("Take Profit 2", from_entry="My Long Entry Id", qty_percent=takeProfitAmount2, limit=entryPrice * (1 + takeProfitPercent2 / 100))
    // Step 3
    if (useTakeProfit and numberOfSteps >= 3)
        strategy.exit("Take Profit 3", from_entry="My Long Entry Id", qty_percent=takeProfitAmount3, limit=entryPrice * (1 + takeProfitPercent3 / 100))
    // Step 4
    if (useTakeProfit and numberOfSteps == 4)
        strategy.exit("Take Profit 4", from_entry="My Long Entry Id", qty_percent=takeProfitAmount4, limit=entryPrice * (1 + takeProfitPercent4 / 100))

if (strategy.position_size < 0)
    // Update the lowest price for short positions
    lowestPrice := na(lowestPrice) ? low : math.min(lowestPrice, low)

    // Step 1
    if (useTakeProfit and numberOfSteps >= 1)
        strategy.exit("Take Profit 1", from_entry="My Short Entry Id", qty_percent=takeProfitAmount1, limit=entryPrice * (1 - takeProfitPercent1 / 100))
    // Step 2
    if (useTakeProfit and numberOfSteps >= 2)
        strategy.exit("Take Profit 2", from_entry="My Short Entry Id", qty_percent=takeProfitAmount2, limit=entryPrice * (1 - takeProfitPercent2 / 100))
    // Step 3
    if (useTakeProfit and numberOfSteps >= 3)
        strategy.exit("Take Profit 3", from_entry="My Short Entry Id", qty_percent=takeProfitAmount3, limit=entryPrice * (1 - takeProfitPercent3 / 100))
    // Step 4
    if (useTakeProfit and numberOfSteps == 4)
        strategy.exit("Take Profit 4", from_entry="My Short Entry Id", qty_percent=takeProfitAmount4, limit=entryPrice * (1 - takeProfitPercent4 / 100))

---

• सुपरट्रेंड इंडिकेटर पर आधारित सटीक ट्रेडिंग रणनीति और जोखिम प्रबंधन प्रणाली
• बड़ी अस्थिरता ब्रेकआउट द्विदिशात्मक ट्रेडिंग रणनीतिः बिंदु आधारित थ्रेशोल्ड प्रवेश प्रणाली
• गतिशील अनुकूलित सुपरट्रेंड ट्रेडिंग रणनीति
• सुपरट्रेंड और ईएमए क्रॉसओवर मात्रात्मक ट्रेडिंग रणनीति
• सुपरट्रेंड और ईएमए को जोड़ने वाली रणनीति के बाद गतिशील प्रवृत्ति
• गतिशील प्रवृत्ति सटीक लाभ लेने और स्टॉप-लॉस रणनीति के साथ
• गतिशील जोखिम प्रबंधन के साथ दोहरी चलती औसत क्रॉसओवर रणनीति
• मल्टी-इंडिकेटर क्रॉसओवर डायनेमिक स्ट्रेटेजी सिस्टमः ईएमए, आरवीआई और ट्रेडिंग सिग्नल पर आधारित एक मात्रात्मक ट्रेडिंग मॉडल
• गतिशील ले लाभ और स्टॉप लॉस अनुकूलन के साथ एमएसीडी क्रॉसओवर गति रणनीति
• हिलो एक्टिवेटर एमएसीडी गतिशील स्टॉप-लॉस टेक-प्रॉफिट ट्रेडिंग रणनीति

---

• बहु-ईएमए क्रॉसओवर रुझान रणनीति का पालन करना
• गतिशील दोलन प्रवृत्ति को पकड़ने की रणनीति
• VAWSI और गतिशील लंबाई गणना बहु-सूचक विश्लेषण प्रणाली के साथ प्रवृत्ति स्थिरता उलट रणनीति
• गतिशील चैनल प्रतिशत परिपत्र रणनीति
• सुपरट्रेंड रणनीति अनुकूलन: गतिशील अस्थिरता ट्रैकिंग और उन्नत ट्रेडिंग सिग्नल प्रणाली
• मशीन लर्निंग से प्रेरित दोहरी चलती औसत आरएसआई ट्रेडिंग रणनीति
• बहु-सूचक उच्च आवृत्ति व्यापार रणनीतिः अल्पकालिक व्यापार प्रणाली जो घातीय चलती औसत और गति संकेतक को जोड़ती है
• ट्रिपल स्टैंडर्ड डिवीजन मोमेंटम रिवर्स ट्रेडिंग रणनीति
• विकल्प व्यापार सुझाव प्रणाली के साथ बहु-अवधि घातीय चलती औसत क्रॉसओवर रणनीति
• कस्टम सिग्नल ऑसिलेटर रणनीति (CSO)
• गतिशील अस्थिरता समायोजन के साथ बहु-स्तरीय आरएसआई औसत प्रतिवर्तन रणनीति
• बोलिंगर बैंड्स गति क्रॉसओवर रणनीति
• सुपर ट्रिपल इंडिकेटर आरएसआई-एमएसीडी-बीबी मोमेंटम रिवर्स रणनीति
• सीसीआई मोमेंटम डिवर्जेंस ट्रेंड ट्रेडिंग रणनीति
• हिलो एक्टिवेटर एमएसीडी गतिशील स्टॉप-लॉस टेक-प्रॉफिट ट्रेडिंग रणनीति
• डायनामिक टेक-प्रॉफिट और स्टॉप-लॉस डबल मूविंग एवरेज क्रॉसओवर ट्रेडिंग रणनीति
• गतिशील जोखिम प्रबंधन प्रणाली के साथ आरएसआई दो-अवधि मूविंग एवरेज रिवर्सल रणनीति
• मार्कोव श्रृंखला संभावना संक्रमण राज्य मात्रात्मक व्यापार रणनीति
• आरएसआई फ़िल्टर और अलर्ट के साथ एसएमए क्रॉसओवर रणनीति