FMZ PINE Script Doc

le dari nilai string const: [val1, val2,...]) Daftar opsi untuk dipilih.

• tooltip(const string) string yang akan ditampilkan kepada pengguna saat menggeser ikon tooltip.
• inline(const string) Menggabungkan semua panggilan input menggunakan argumen yang sama dalam satu baris. string yang digunakan sebagai argumen tidak ditampilkan.
• group(const string) Membuat header di atas semua input menggunakan string argumen grup yang sama.
• confirm(const bool) Jika true, maka pengguna akan diminta untuk mengkonfirmasi nilai input sebelum indikator ditambahkan ke grafik. Nilai default adalah false.

PengamatanHasil dari fungsi input.timeframe selalu harus ditugaskan ke variabel, lihat contoh di atas.

Lihat juga input.bool input.int input.float input.string input.source input.color input

input.integer

Tidak tersedia.

input.resolution

Tidak tersedia.

Tn

ta.alma

Arnaud Legoux Moving Average. menggunakan distribusi Gaussian sebagai bobot untuk moving average.

ta.alma(series, length, offset, sigma) 

ta.alma(series, length, offset, sigma, floor) 

Contoh

plot(ta.alma(close, 9, 0.85, 6))

// same on pine, but much less efficient
pine_alma(series, windowsize, offset, sigma) =>
    m = offset * (windowsize - 1)
    //m = math.floor(offset * (windowsize - 1)) // Used as m when math.floor=true
    s = windowsize / sigma
    norm = 0.0
    sum = 0.0
    for i = 0 to windowsize - 1
        weight = math.exp(-1 * math.pow(i - m, 2) / (2 * math.pow(s, 2)))
        norm := norm + weight
        sum := sum + series[windowsize - i - 1] * weight
    sum / norm
plot(pine_alma(close, 9, 0.85, 6))

PengembalianArnaud Legoux Moving Rata-rata.

Argumen

• series(serangkaian int/float) Serangkaian nilai untuk diproses.
• length(seri int) Jumlah batang (panjang).
• offset(simple int/float) Mengontrol tradeoff antara kelancaran (dekat dengan 1) dan responsif (dekat dengan 0).
• sigma(simple int/float) Mengubah kelancaran ALMA. Sigma yang lebih besar ALMA yang lebih halus.
• floor(simple bool) Sebuah argumen opsional. Menentukan apakah perhitungan offset diturunkan sebelum ALMA dihitung. Nilai default adalah false.

Lihat juga ta.sma ta.ema ta.rma ta.wma ta.vwma ta.swma

ta.sma

Fungsi sma mengembalikan rata-rata bergerak, yaitu jumlah nilai y terakhir dari x, dibagi dengan y.

ta.sma(source, length) 

Contoh

plot(ta.sma(close, 15))

// same on pine, but much less efficient
pine_sma(x, y) =>
    sum = 0.0
    for i = 0 to y - 1
        sum := sum + x[i] / y
    sum
plot(pine_sma(close, 15))

PengembalianRata-rata bergerak sederhana darisourceuntuklengthBar kembali.

Argumen

• source(serangkaian int/float) Serangkaian nilai untuk diproses.
• length(seri int) Jumlah batang (panjang).

Lihat juga ta.ema ta.rma ta.wma ta.vwma ta.swma ta.alma

ta.cog

Pedal (pusat gravitasi) adalah indikator yang didasarkan pada statistik dan rasio emas Fibonacci.

ta.cog(source, length) 

Contoh

plot(ta.cog(close, 10))

// the same on pine
pine_cog(source, length) =>
    sum = math.sum(source, length)
    num = 0.0
    for i = 0 to length - 1
        price = source[i]
        num := num + price * (i + 1)
    -num / sum

plot(pine_cog(close, 10))

PengembalianPusat Gravitasi.

Argumen

• source(serangkaian int/float) Serangkaian nilai untuk diproses.
• length(seri int) Jumlah batang (panjang).

Lihat juga ta.stoch

ta.dev

Ukuran perbedaan antara seri dan ta.sma

ta.dev(source, length) 

Contoh

plot(ta.dev(close, 10))

// the same on pine
pine_dev(source, length) =>
    mean = ta.sma(source, length)
    sum = 0.0
    for i = 0 to length - 1
        val = source[i]
        sum := sum + math.abs(val - mean)
    dev = sum/length
plot(pine_dev(close, 10))

PengembalianPenyimpangan darisourceuntuklengthBar kembali.

Argumen

• source(serangkaian int/float) Serangkaian nilai untuk diproses.
• length(seri int) Jumlah batang (panjang).

Lihat juga ta.variance ta.stdev

ta.stdev

ta.stdev(source, length, biased) 

Contoh

plot(ta.stdev(close, 5))

//the same on pine
isZero(val, eps) => math.abs(val) <= eps

SUM(fst, snd) =>
    EPS = 1e-10
    res = fst + snd
    if isZero(res, EPS)
        res := 0
    else
        if not isZero(res, 1e-4)
            res := res
        else
            15

pine_stdev(src, length) =>
    avg = ta.sma(src, length)
    sumOfSquareDeviations = 0.0
    for i = 0 to length - 1
        sum = SUM(src[i], -avg)
        sumOfSquareDeviations := sumOfSquareDeviations + sum * sum

    stdev = math.sqrt(sumOfSquareDeviations / length)
plot(pine_stdev(close, 5))

PengembalianPenyimpangan standar.

Argumen

• source(serangkaian int/float) Serangkaian nilai untuk diproses.
• length(seri int) Jumlah batang (panjang).
• biased(seri bool) Menentukan perkiraan mana yang harus digunakan. Opsional. default adalah benar.

PengamatanJikabiasedadalah benar, fungsi akan menghitung menggunakan estimasi bias dari seluruh populasi, jika salah - estimasi bias dari sampel.

Lihat juga ta.dev ta.variance

ta.ema

Fungsi ema mengembalikan rata-rata bergerak yang diberi bobot eksponensial. Dalam faktor bobot ema menurun secara eksponensial. Fungsi ini dihitung dengan menggunakan rumus: EMA = alpha * sumber + (1 - alpha) * EMA[1], di mana alpha = 2 / (panjang + 1).

ta.ema(source, length) 

Contoh

plot(ta.ema(close, 15))

//the same on pine
pine_ema(src, length) =>
    alpha = 2 / (length + 1)
    sum = 0.0
    sum := na(sum[1]) ? src : alpha * src + (1 - alpha) * nz(sum[1])
plot(pine_ema(close,15))

PengembalianRata-rata bergerak eksponensial darisourcedengan alfa = 2 / (panjang + 1).

Argumen

• source(serangkaian int/float) Serangkaian nilai untuk diproses.
• length(Int sederhana) Jumlah batang (panjang).

PengamatanHarap dicatat bahwa menggunakan variabel/fungsi ini dapat menyebabkan pencelupan ulang indikator.

Lihat juga ta.sma ta.rma ta.wma ta.vwma ta.swma ta.alma

ta.wma

Fungsi wma mengembalikan rata-rata bergerak tertimbang darisourceuntuklengthDalam WMA faktor bobot menurun dalam progresi aritmatika.

ta.wma(source, length) 

Contoh

plot(ta.wma(close, 15))

// same on pine, but much less efficient
pine_wma(x, y) =>
    norm = 0.0
    sum = 0.0
    for i = 0 to y - 1
        weight = (y - i) * y
        norm := norm + weight
        sum := sum + x[i] * weight
    sum / norm
plot(pine_wma(close, 15))

PengembalianRata-rata bergerak tertimbang darisourceuntuklengthBar kembali.

Argumen

• source(serangkaian int/float) Serangkaian nilai untuk diproses.
• length(seri int) Jumlah batang (panjang).

Lihat juga ta.sma ta.ema ta.rma ta.vwma ta.swma ta.alma

ta.swma

Rata-rata bergerak bertimbalan simetris dengan panjang tetap: 4. Berat: [1/6, 2/6, 2/6, 1/6].

ta.swma(source)

Contoh

plot(ta.swma(close))

// same on pine, but less efficient
pine_swma(x) =>
    x[3] * 1 / 6 + x[2] * 2 / 6 + x[1] * 2 / 6 + x[0] * 1 / 6
plot(pine_swma(close))

PengembalianRata-rata bergerak yang ditimbang secara simetris.

Argumen

• source(seri int/float) Seri sumber.

Lihat juga ta.sma ta.ema ta.rma ta.wma ta.vwma ta.alma

ta.hma

Fungsi hma mengembalikan Hull Moving Average.

ta.hma(source, length)

Contoh

src = input(defval=close, title="Source")
length = input(defval=9, title="Length")
hmaBuildIn = ta.hma(src, length)
plot(hmaBuildIn, title="Hull MA", color=#674EA7)

PengembalianHull moving average of source untuk length bar back.

Argumen

• source(serangkaian int/float) Serangkaian nilai untuk diproses.
• length(Int sederhana) Jumlah bar.

Lihat juga ta.ema ta.rma ta.wma ta.vwma ta.sma

ta.rma

Rata-rata bergerak yang digunakan dalam RSI. Ini adalah rata-rata bergerak yang diberi bobot eksponensial dengan alfa = 1 / panjang.

ta.rma(source, length)

Contoh

plot(ta.rma(close, 15))

//the same on pine
pine_rma(src, length) =>
  alpha = 1/length
  sum = 0.0
  sum := na(sum[1]) ? ta.sma(src, length) : alpha * src + (1 - alpha) * nz(sum[1])
plot(pine_rma(close, 15))

PengembalianRata-rata bergerak eksponensial darisourcedengan alfa = 1 /length.

Argumen

• source(serangkaian int/float) Serangkaian nilai untuk diproses.
• length(Int sederhana) Jumlah batang (panjang).

Lihat juga ta.sma ta.ema ta.wma ta.vwma ta.swma ta.alma ta.rsi

ta.rsi

Indeks kekuatan relatif.ta.rma()dari perubahan ke atas dan ke bawah darisourcedi tahun lalulength bars.

ta.rsi(source, length)

Contoh

plot(ta.rsi(close, 7))

// same on pine, but less efficient
pine_rsi(x, y) => 
    u = math.max(x - x[1], 0) // upward ta.change
    d = math.max(x[1] - x, 0) // downward ta.change
    rs = ta.rma(u, y) / ta.rma(d, y)
    res = 100 - 100 / (1 + rs)
    res

plot(pine_rsi(close, 7))

PengembalianIndeks kekuatan relatif.

Argumen

• source(serangkaian int/float) Serangkaian nilai untuk diproses.
• length(Int sederhana) Jumlah batang (panjang).

Lihat juga ta.rma

ta.tsi

Indeks kekuatan sejati. Ini menggunakan rata-rata bergerak dari momentum yang mendasari instrumen keuangan.

ta.tsi(source, short_length, long_length)

PengembalianIndeks kekuatan sejati. nilai dalam kisaran [-1, 1].

Argumen

• source(seri int/float) Seri sumber.
• short_length(Int sederhana) panjang pendek.
• long_length(Int sederhana) panjang panjang.

ta.roc

Fungsi roc (tingkat perubahan) menunjukkan perbedaan antara nilai saat ini darisourcedan nilai darisourceItu adalahlengthBeberapa hari yang lalu. Hal ini dihitung dengan rumus: 100 * perubahan ((src, panjang) / src[panjang].

ta.roc(source, length)

PengembalianTingkat perubahansourceuntuklengthBar kembali.

Argumen

• source(serangkaian int/float) Serangkaian nilai untuk diproses.
• length(seri int) Jumlah batang (panjang).

ta.range

Mengembalikan perbedaan antara nilai min dan max dalam seri.

ta.range(source, length)

PengembalianPerbedaan antara nilai min dan max dalam seri.

Argumen

• source(serangkaian int/float) Serangkaian nilai untuk diproses.
• length(seri int) Jumlah batang (panjang).

ta.macd

MACD (moving average convergence/divergence). Hal ini dimaksudkan untuk mengungkapkan perubahan dalam kekuatan, arah, momentum, dan durasi tren dalam harga saham.

ta.macd(source, fastlen, slowlen, siglen) 

Contoh

[macdLine, signalLine, histLine] = ta.macd(close, 12, 26, 9)
plot(macdLine, color=color.blue)
plot(signalLine, color=color.orange)
plot(histLine, color=color.red, style=plot.style_histogram)

Jika Anda hanya membutuhkan satu nilai, gunakan placeholder _ seperti ini:

Contoh

[_, signalLine, _] = ta.macd(close, 12, 26, 9)
plot(signalLine, color=color.orange)

PengembalianTupel dari tiga seri MACD: garis MACD, garis sinyal dan garis histogram.

Argumen

• source(serangkaian int/float) Serangkaian nilai untuk diproses.
• fastlenArgumen panjang cepat.
• slowlen(Int sederhana) Argumen panjang lambat.
• siglen(Int sederhana) Argumen panjang sinyal.

Lihat juga ta.sma ta.ema

ta.mode

Jika ada beberapa nilai dengan frekuensi yang sama, mengembalikan nilai terkecil.

ta.mode(source, length)

PengembalianMode dari seri.

Argumen

• source(serangkaian int/float) Serangkaian nilai untuk diproses.
• length(seri int) Jumlah batang (panjang).

ta.median

Mengembalikan median dari seri.

ta.median(source, length) 

PengembalianMedian dari seri.

Argumen

• source(serangkaian int/float) Serangkaian nilai untuk diproses.
• length(seri int) Jumlah batang (panjang).

ta.linreg

Kurva regresi linier. Garis yang paling sesuai dengan harga yang ditentukan selama periode waktu yang ditentukan oleh pengguna. Hal ini dihitung menggunakan metode paling kecil kuadrat. Hasil fungsi ini dihitung menggunakan rumus: linreg = intercept + slope * (panjang - 1 - offset), di mana intercept dan slope adalah nilai yang dihitung dengan metode paling kecil kuadrat padasource series.

ta.linreg(source, length, offset) 

PengembalianKurva regresi linier.

Argumen

• source(seri int/float) Seri sumber.
• length(seri int)
• offset(Int sederhana) Offset.

ta.bb

Bollinger Bands. Bollinger Band adalah alat analisis teknis yang didefinisikan oleh seperangkat garis yang digambarkan dua standar deviasi (positif dan negatif) dari rata-rata bergerak sederhana (SMA) dari harga sekuritas, tetapi dapat disesuaikan dengan preferensi pengguna.

ta.bb(series, length, mult) 

Contoh

[middle, upper, lower] = ta.bb(close, 5, 4)
plot(middle, color=color.yellow)
plot(upper, color=color.yellow)
plot(lower, color=color.yellow)

// the same on pine
f_bb(src, length, mult) =>
    float basis = ta.sma(src, length)
    float dev = mult * ta.stdev(src, length)
    [basis, basis + dev, basis - dev]

[pineMiddle, pineUpper, pineLower] = f_bb(close, 5, 4)

plot(pineMiddle)
plot(pineUpper)
plot(pineLower)

PengembalianBollinger Bands.

Argumen

• series(serangkaian int/float) Serangkaian nilai untuk diproses.
• length(seri int) Jumlah batang (panjang).
• mult(simple int/float) Faktor standar deviasi.

Lihat juga ta.sma ta.stdev ta.kc

ta.bbw

Lebar Bollinger Band adalah perbedaan antara Bollinger Band atas dan bawah dibagi dengan band tengah.

ta.bbw(series, length, mult) 

Contoh

plot(ta.bbw(close, 5, 4), color=color.yellow)

// the same on pine
f_bbw(src, length, mult) =>
    float basis = ta.sma(src, length)
    float dev = mult * ta.stdev(src, length)
    ((basis + dev) - (basis - dev)) / basis

plot(f_bbw(close, 5, 4))

PengembalianLebar Bollinger Bands.

Argumen

• series(serangkaian int/float) Serangkaian nilai untuk diproses.
• length(seri int) Jumlah batang (panjang).
• mult(simple int/float) Faktor standar deviasi.

Lihat juga ta.bb ta.sma ta.stdev

ta.cci

CCI (komoditas saluran indeks) dihitung sebagai perbedaan antara harga khas komoditas dan rata-rata bergerak sederhana, dibagi dengan rata-rata deviasi absolut dari harga khas.

ta.cci(source, length) 

PengembalianIndeks saluran komoditas sumber untuk panjang batang kembali.

Argumen

• source(serangkaian int/float) Serangkaian nilai untuk diproses.
• length(seri int) Jumlah batang (panjang).

ta.change

Perbedaan antara nilai saat ini dan nilai sebelumnya, sumber - sumber [panjang].

ta.change(source, length) 

ta.change(source) 

PengembalianHasil pengurangan.

Argumen

• source(seri int/float) Seri sumber.
• length(seri int) Offset dari bar saat ini ke bar sebelumnya. opsional, jika tidak diberikan, panjang = 1 digunakan.

Lihat juga ta.mom ta.cross

ta.mom

Momentum darisourceharga dansourcehargalengthIni hanya perbedaan: sumber - sumber [panjang].

ta.mom(source, length) 

PengembalianMomentum darisourceharga dansourcehargalengthbeberapa tahun yang lalu.

Argumen

• source(serangkaian int/float) Serangkaian nilai untuk diproses.
• length(seri int) Offset dari bar saat ini ke bar sebelumnya.

Lihat juga ta.change

ta.cmo

Menghitung perbedaan antara jumlah keuntungan baru-baru ini dan jumlah kerugian baru-baru ini dan kemudian membagi hasilnya dengan jumlah semua pergerakan harga selama periode yang sama.

ta.cmo(series, length) 

Contoh

plot(ta.cmo(close, 5), color=color.yellow)

// the same on pine
f_cmo(src, length) =>
    float mom = ta.change(src)
    float sm1 = math.sum((mom >= 0) ? mom : 0.0, length)
    float sm2 = math.sum((mom >= 0) ? 0.0 : -mom, length)
    100 * (sm1 - sm2) / (sm1 + sm2)

plot(f_cmo(close, 5))

PengembalianOsilator Momentum Chande.

Argumen

• series(serangkaian int/float) Serangkaian nilai untuk diproses.
• length(seri int) Jumlah batang (panjang).

Lihat juga ta.rsi ta.stoch math.sum

ta.percentile_linear_interpolation

Menghitung persentil menggunakan metode interpolasi linier antara dua baris terdekat.

ta.percentile_linear_interpolation(source, length, percentage) 

PengembalianPercentil ke-p darisourceseri untuklengthBar kembali.

Argumen

• source(serangkaian int/float) Serangkaian nilai untuk diproses (sumber).
• length(seri int) Jumlah batang belakang (panjang).
• percentage(simple int/float) Persentase, angka dari kisaran 0-100

PengamatanPerhatikan bahwa persentil yang dihitung menggunakan metode ini TIDAK akan selalu menjadi anggota dari set data input.

Lihat juga ta.percentile_nearest_rank

ta.percentile_nearest_rank

Menghitung persentase menggunakan metode peringkat terdekat.

ta.percentile_nearest_rank(source, length, percentage) 

PengembalianPercentil ke-p darisourceseri untuklengthBar kembali.

Argumen

• source(serangkaian int/float) Serangkaian nilai untuk diproses (sumber).
• length(seri int) Jumlah batang belakang (panjang).
• percentage(simple int/float) Persentase, angka dari kisaran 0-100

PengamatanMenggunakan metode Rank terdekat pada panjang kurang dari 100 bar kembali dapat menghasilkan angka yang sama yang digunakan untuk lebih dari satu persentil. Persentil yang dihitung menggunakan metode Rank terdekat akan selalu menjadi anggota dari set data input. Persentil ke-100 didefinisikan sebagai nilai terbesar dalam set data input.

Lihat juga ta.percentile_linear_interpolation

ta.percentrank

Peringkat persentase adalah persentase dari berapa banyak nilai sebelumnya kurang dari atau sama dengan nilai saat ini dari seri tertentu.

ta.percentrank(source, length) 

PengembalianPeratus pangkat darisourceuntuklengthBar kembali.

Argumen

• source(serangkaian int/float) Serangkaian nilai untuk diproses.
• length(seri int) Jumlah batang (panjang).

ta.variance

Variansi adalah ekspektasi dari penyimpangan kuadrat dari seri dari rata-ratanya (ta.sma), dan secara informal mengukur seberapa jauh seperangkat angka tersebar dari rata-ratanya.

ta.variance(source, length, biased) 

PengembalianVariansi darisourceuntuklengthBar kembali.

Argumen

• source(serangkaian int/float) Serangkaian nilai untuk diproses.
• length(seri int) Jumlah batang (panjang).
• biased(seri bool) Menentukan perkiraan mana yang harus digunakan. Opsional. default adalah benar.

PengamatanJikabiasedadalah benar, fungsi akan menghitung menggunakan estimasi bias dari seluruh populasi, jika salah - estimasi bias dari sampel.

Lihat juga ta.dev ta.stdev

ta.tr

ta.tr(handle_na) 

PengembalianReal range. Itu adalah math.max ((tinggi - rendah, math.abs ((tinggi - dekat[1]), math.abs ((rendah - dekat[1])).

Argumen

• handle_na(simple bool) Bagaimana nilai NaN ditangani. jika benar, dan hari sebelumnya s tutup adalah NaN maka tr akan dihitung sebagai hari saat ini tinggi-rendah. Jika tidak (jika salah) tr akan mengembalikan NaN dalam kasus seperti itu.ta.tr(benar).

Pengamatan ta.tr(false)sama persis denganta.tr.

Lihat juga ta.atr

ta.mfi

Indeks Aliran Uang Indeks Aliran Uang (MFI) adalah osilator teknis yang menggunakan harga dan volume untuk mengidentifikasi kondisi overbought atau oversold dalam aset.

ta.mfi(series, length) 

Contoh

plot(ta.mfi(hlc3, 14), color=color.yellow)

// the same on pine
pine_mfi(src, length) =>
    float upper = math.sum(volume * (ta.change(src) <= 0.0 ? 0.0 : src), length)
    float lower = math.sum(volume * (ta.change(src) >= 0.0 ? 0.0 : src), length)
    mfi = 100.0 - (100.0 / (1.0 + upper / lower))
    mfi

plot(pine_mfi(hlc3, 14))

PengembalianIndeks arus uang.

Argumen

• series(serangkaian int/float) Serangkaian nilai untuk diproses.
• length(seri int) Jumlah batang (panjang).

Lihat juga ta.rsi math.sum

ta.kc

Saluran Keltner adalah indikator analisis teknis yang menunjukkan garis rata-rata bergerak pusat ditambah garis saluran pada jarak di atas dan di bawah.

ta.kc(series, length, mult) 

ta.kc(series, length, mult, useTrueRange) 

Contoh

[middle, upper, lower] = ta.kc(close, 5, 4)
plot(middle, color=color.yellow)
plot(upper, color=color.yellow)
plot(lower, color=color.yellow)


// the same on pine
f_kc(src, length, mult, useTrueRange) =>
    float basis = ta.ema(src, length)
    float span = (useTrueRange) ? ta.tr : (high - low)
    float rangeEma = ta.ema(span, length)
    [basis, basis + rangeEma * mult, basis - rangeEma * mult]
    
[pineMiddle, pineUpper, pineLower] = f_kc(close, 5, 4, true)

plot(pineMiddle)
plot(pineUpper)
plot(pineLower)

PengembalianSaluran Keltner.

Argumen

• series(serangkaian int/float) Serangkaian nilai untuk diproses.
• length(Int sederhana) Jumlah batang (panjang).
• mult(simple int/float) Faktor standar deviasi.
• useTrueRange(simple bool) Sebuah argumen opsional. Menentukan apakah True Range digunakan; default adalah benar. Jika nilainya salah, rentang akan dihitung dengan ekspresi (tinggi - rendah).

Lihat juga ta.ema ta.atr ta.bb

ta.kcw

Lebar Saluran Keltner. Lebar Saluran Keltner adalah perbedaan antara Saluran Keltner atas dan bawah dibagi dengan saluran tengah.

ta.kcw(series, length, mult) 

ta.kcw(series, length, mult, useTrueRange) 

Contoh

plot(ta.kcw(close, 5, 4), color=color.yellow)

// the same on pine
f_kcw(src, length, mult, useTrueRange) =>
    float basis = ta.ema(src, length)
    float span = (useTrueRange) ? ta.tr : (high - low)
    float rangeEma = ta.ema(span, length)
    
    ((basis + rangeEma * mult) - (basis - rangeEma * mult)) / basis

plot(f_kcw(close, 5, 4, true))

PengembalianKeltner saluran lebar.

Argumen

• series(serangkaian int/float) Serangkaian nilai untuk diproses.
• length(Int sederhana) Jumlah batang (panjang).
• mult(simple int/float) Faktor standar deviasi.
• useTrueRange(simple bool) Sebuah argumen opsional. Menentukan apakah True Range digunakan; default adalah benar. Jika nilainya salah, rentang akan dihitung dengan ekspresi (tinggi - rendah).

Lihat juga ta.kc ta.ema ta.atr ta.bb

ta.correlation

Koefisien korelasi. Menjelaskan tingkat di mana dua deret cenderung menyimpang dari nilai tasma mereka.

ta.correlation(source1, source2, length) 

PengembalianKoefisien korelasi.

Argumen

• source1(seri int/float) Seri sumber.
• source2(seri int/float) Seri target.
• length(seri int) Panjang (jumlah batang kembali).

Lihat juga request.security

ta.cross

ta.cross(source1, source2) 

Pengembalianbenar jika dua deret telah saling melintasi, jika tidak salah.

Argumen

• source1(seri int/float) Seri data pertama.
• source2(seri int/float) Seri data kedua.

Lihat juga ta.change

ta.crossover

Peraturansource1-seri didefinisikan sebagai telah melintasisource2-seri jika, pada bar saat ini, nilaisource1lebih besar dari nilaisource2, dan pada bar sebelumnya, nilai darisource1adalah kurang dari nilaisource2.

ta.crossover(source1, source2) 

Pengembalianbenar jikasource1menyeberangsource2Jika tidak, itu salah.

Argumen

• source1(seri int/float) Seri data pertama.
• source2(seri int/float) Seri data kedua.

ta.crossunder

Peraturansource1-seri didefinisikan sebagai telah menyeberang di bawahsource2-seri jika, pada bar saat ini, nilaisource1adalah kurang dari nilaisource2, dan pada bar sebelumnya, nilai darisource1adalah lebih besar dari nilaisource2.

ta.crossunder(source1, source2) 

Pengembalianbenar jikasource1Dililit di bawahsource2Jika tidak, itu salah.

Argumen

• source1(seri int/float) Seri data pertama.
• source2(seri int/float) Seri data kedua.

ta.atr

Fungsi atr (rata-rata rentang benar) mengembalikan RMA dari rentang benar. rentang benar adalah max ((tinggi - rendah, abs ((tinggi - dekat[1]), abs ((rendah - dekat[1])).

ta.atr(length) 

Contoh

plot(ta.atr(14))

//the same on pine
pine_atr(length) =>
    trueRange = na(high[1])? high-low : math.max(math.max(high - low, math.abs(high - close[1])), math.abs(low - close[1]))
    //true range can be also calculated with ta.tr(true)
    ta.rma(trueRange, length)

plot(pine_atr(14))

PengembalianJangkauan rata-rata yang benar.

Argumenpanjang (int sederhana) Panjang (jumlah batang belakang).

Lihat juga ta.tr ta.rma

ta.sar

Parabolic SAR (parabolic stop and reverse) adalah metode yang dirancang oleh J. Welles Wilder, Jr., untuk menemukan potensi pembalikan dalam arah harga pasar barang yang diperdagangkan.

ta.sar(start, inc, max) 

Contoh

plot(ta.sar(0.02, 0.02, 0.2), style=plot.style_cross, linewidth=3)

// The same on Pine
pine_sar(start, inc, max) =>
  var float result = na
  var float maxMin = na
  var float acceleration = na
  var bool isBelow = na
  bool isFirstTrendBar = false
  
  if bar_index == 1
    if close > close[1]
      isBelow := true
      maxMin := high
      result := low[1]
    else
      isBelow := false
      maxMin := low
      result := high[1]
    isFirstTrendBar := true
    acceleration := start
  
  result := result + acceleration * (maxMin - result)
  
  if isBelow
    if result > low
      isFirstTrendBar := true
      isBelow := false
      result := math.max(high, maxMin)
      maxMin := low
      acceleration := start
  else
    if result < high
      isFirstTrendBar := true
      isBelow := true
      result := math.min(low, maxMin)
      maxMin := high
      acceleration := start
      
  if not isFirstTrendBar
    if isBelow
      if high > maxMin
        maxMin := high
        acceleration := math.min(acceleration + inc, max)
    else
      if low < maxMin
        maxMin := low
        acceleration := math.min(acceleration + inc, max)
  
  if isBelow
    result := math.min(result, low[1])
    if bar_index > 1
      result := math.min(result, low[2])
    
  else
    result := math.max(result, high[1])
    if bar_index > 1
      result := math.max(result, high[2])
  
  result
  
plot(pine_sar(0.02, 0.02, 0.2), style=plot.style_cross, linewidth=3)

PengembalianParabolik SAR.

Argumen

• start(sederhana int/float) Mulai.
• inc(sederhana int/float) Inkrement.
• max(sederhana int/float) Maksimal.

ta.barssince

Menghitung jumlah bar sejak terakhir kali kondisi itu benar.

ta.barssince(condition) 

Contoh

// get number of bars since last color.green bar
plot(ta.barssince(close >= open))

PengembalianJumlah batang sejak kondisi benar.

PengamatanJika kondisi tidak pernah terpenuhi sebelum bar saat ini, fungsi mengembalikan na. Harap dicatat bahwa menggunakan variabel/fungsi ini dapat menyebabkan pencelupan ulang indikator.

Lihat juga ta.lowestbars ta.highestbars ta.valuewhen ta.highest ta.lowest

ta.cum

Jumlah kumulatif (total) darisourceDengan kata lain itu adalah jumlah dari semua elemen darisource.

ta.cum(source) 

PengembalianTotal jumlah seri.

Argumen

• source(seri int/float)

Lihat juga math.sum

ta.dmi

Fungsi dmi mengembalikan indeks gerakan arah (DMI).

ta.dmi(diLength, adxSmoothing) 

Contoh

len = input.int(17, minval=1, title="DI Length")
lensig = input.int(14, title="ADX Smoothing", minval=1, maxval=50)
[diplus, diminus, adx] = ta.dmi(len, lensig)
plot(adx, color=color.red, title="ADX")
plot(diplus, color=color.blue, title="+DI")
plot(diminus, color=color.orange, title="-DI")

PengembalianDua dari tiga seri DMI: Gerakan Berarah Positif (+DI), Gerakan Berarah Negatif (-DI) dan Indeks Gerakan Berarah Rata-rata (ADX).

Argumen

• diLength(simple int) Periode DI.
• adxSmoothing(simple int) ADX Periode Smoothing.

Lihat juga ta.rsi ta.tsi ta.mfi

ta.falling

Uji apakahsourceseri sekarang jatuh untuklengthpanjang bar.

ta.falling(source, length) 

Pengembalianbenar jika saat inisourcenilai lebih rendah dari yang sebelumnyasourcenilai untuklengthBar kembali, palsu sebaliknya.

Argumen

• source(serangkaian int/float) Serangkaian nilai untuk diproses.
• length(seri int) Jumlah batang (panjang).

Lihat juga ta.rising

ta.rising

Uji apakahsourceseri sekarang meningkat untuklengthpanjang bar.

ta.rising(source, length) 

Pengembalianbenar jika saat inisourcelebih besar dari sebelumnyasourceuntuklengthBar kembali, palsu sebaliknya.

Argumen

• source(serangkaian int/float) Serangkaian nilai untuk diproses.
• length(seri int) Jumlah batang (panjang).

Lihat juga ta.falling

ta.pivothigh

Fungsi ini mengembalikan harga dari titik tinggi pivot.

ta.pivothigh(source, leftbars, rightbars) 

ta.pivothigh(leftbars, rightbars) 

Contoh

leftBars = input(2)
rightBars=input(2)
ph = ta.pivothigh(leftBars, rightBars)
plot(ph, style=plot.style_cross, linewidth=3, color= color.red, offset=-rightBars)

PengembalianHarga poin atau NaN.

Argumen

• source(seri int/float) Sebuah argumen opsional. Data seri untuk menghitung nilai. High secara default.
• leftbars(seri int/float) kekuatan kiri.
• rightbars(seri int/float) Panjang kanan.

PengamatanJika argumen leftbars atau rightbars adalah deret, Anda harus menggunakan fungsi max_bars_back untuk variabel source.

ta.pivotlow

Fungsi ini mengembalikan harga titik rendah poros.

ta.pivotlow(source, leftbars, rightbars) 

ta.pivotlow(leftbars, rightbars) 

Contoh

leftBars = input(2)
rightBars=input(2)
pl = ta.pivotlow(close, leftBars, rightBars)
plot(pl, style=plot.style_cross, linewidth=3, color= color.blue, offset=-rightBars)

PengembalianHarga poin atau NaN.

Argumen

• source(seri int/float) Sebuah argumen opsional. Data seri untuk menghitung nilai. Low secara default.
• leftbars(seri int/float) kekuatan kiri.
• rightbars(seri int/float) Panjang kanan.

PengamatanJika argumen leftbars atau rightbars adalah deret, Anda harus menggunakan fungsi max_bars_back untuk variabel source.

ta.highest

Nilai tertinggi untuk jumlah batang yang diberikan kembali.

ta.highest(source, length) 

ta.highest(length) 

PengembalianNilai tertinggi dalam seri.

Argumen

• source(serangkaian int/float) Serangkaian nilai untuk diproses.
• length(seri int) Jumlah batang (panjang).

PengamatanDua versi args:sourceadalah seri danlengthadalah jumlah batang belakang. Satu versi arg:lengthadalah jumlah bar kembali. Algoritma menggunakan tinggi sebagaisource series.

Lihat juga ta.lowest ta.lowestbars ta.highestbars ta.valuewhen ta.barssince

ta.highestbars

Nilai tertinggi offset untuk jumlah bar yang diberikan kembali.

ta.highestbars(source, length) 

ta.highestbars(length) 

PengembalianOffset ke bar tertinggi.

Argumen

• source(serangkaian int/float) Serangkaian nilai untuk diproses.
• length(seri int) Jumlah batang (panjang).

PengamatanDua versi args:sourceadalah seri danlengthadalah jumlah batang belakang. Satu versi arg:lengthadalah jumlah bar kembali. Algoritma menggunakan tinggi sebagaisource series.

Lihat juga ta.lowest ta.highest ta.lowestbars ta.barssince ta.valuewhen

ta.stoch

Hal ini dihitung dengan rumus: 100 * (dekat - terendah ((rendah, panjang)) / (tinggi ((tinggi, panjang) - terendah ((rendah, panjang)).

ta.stoch(source, high, low, length) 

Pengembalian Stochastic.

Argumen

• source(seri int/float) Seri sumber.
• high(seri int/float) Seri tinggi.
• low(seri int/float) Seri rendah.
• length(seri int) Panjang (jumlah batang kembali).

Lihat juga ta.cog

ta.supertrend

Indikator Supertrend. Indikator Supertrend adalah indikator trend berikut.

ta.supertrend(factor, atrPeriod) 

Contoh

//@version=5
indicator("Pine Script™ Supertrend")

[supertrend, direction] = ta.supertrend(3, 10)
plot(direction < 0 ? supertrend : na, "Up direction", color = color.green, style=plot.style_linebr)
plot(direction > 0 ? supertrend : na, "Down direction", color = color.red, style=plot.style_linebr)

// The same on Pine Script™
pine_supertrend(factor, atrPeriod) =>
  src = hl2
  atr = ta.atr(atrPeriod)
  upperBand = src + factor * atr
  lowerBand = src - factor * atr
  prevLowerBand = nz(lowerBand[1])
  prevUpperBand = nz(upperBand[1])

  lowerBand := lowerBand > prevLowerBand or close[1] < prevLowerBand ? lowerBand : prevLowerBand
  upperBand := upperBand < prevUpperBand or close[1] > prevUpperBand ? upperBand : prevUpperBand
  int direction = na
  float superTrend = na
  prevSuperTrend = superTrend[1]
  if na(atr[1])
    direction := 1
  else if prevSuperTrend == prevUpperBand
    direction := close > upperBand ? -1 : 1
  else
    direction := close < lowerBand ? 1 : -1
  superTrend := direction == -1 ? lowerBand : upperBand
  [superTrend, direction]

[pineSupertrend, pineDirection] = pine_supertrend(3, 10)
plot(pineDirection < 0 ? pineSupertrend : na, "Up direction", color = color.green, style=plot.style_linebr)
plot(pineDirection > 0 ? pineSupertrend : na, "Down direction", color = color.red, style=plot.style_linebr)

PengembalianTuple dari dua seri supertrend: garis supertrend dan arah tren.

Argumen

• factor(seri int/float) Multiplikator dengan yang ATR akan mendapatkan dikalikan.
• atrPeriod(Int sederhana) Panjang ATR

Lihat juga ta.macd

ta.lowest

Nilai terendah untuk jumlah batang yang diberikan kembali.

ta.lowest(source, length) 

ta.lowest(length) 

PengembalianNilai terendah dalam seri.

Argumen

• source(serangkaian int/float) Serangkaian nilai untuk diproses.
• length(seri int) Jumlah batang (panjang).

PengamatanDua versi args:sourceadalah seri danlengthadalah jumlah batang belakang. Satu versi arg:lengthadalah jumlah bar kembali. Algoritma menggunakan rendah sebagaisource series.

Lihat juga ta.highest ta.lowestbars ta.highestbars ta.valuewhen ta.barssince

ta.lowestbars

Nilai terendah yang diimbangi untuk jumlah batang yang diberikan.

ta.lowestbars(source, length) 

ta.lowestbars(length) 

PengembalianOffset ke bar terendah.

Argumen

• source(serangkaian int/float) Serangkaian nilai untuk diproses.
• length(seri int) Jumlah batang kembali.

PengamatanDua versi args:sourceadalah seri danlengthadalah jumlah batang belakang. Satu versi arg:lengthadalah jumlah bar kembali. Algoritma menggunakan rendah sebagaisource series.

Lihat juga ta.lowest ta.highest ta.highestbars ta.barssince ta.valuewhen

ta.valuewhen

Mengembalikan nilai dari seri source pada bar di mana condition benar pada kejadian terbaru ke-n.

ta.valuewhen(condition, source, occurrence) 

Contoh

slow = ta.sma(close, 7)
fast = ta.sma(close, 14)
// Get value of `close` on second most recent cross
plot(ta.valuewhen(ta.cross(slow, fast), close, 1))

Argumen

• condition(seri bool) Kondisi untuk mencari.
• source(seri int/float/bool/color) Nilai yang akan dikembalikan dari bar di mana kondisi terpenuhi.
• occurrence(simple int) Terjadinya kondisi. Penomoran dimulai dari 0 dan kembali ke masa lalu, jadi 0 adalah kejadian terbaru dari condition, 1 adalah yang paling baru kedua dan seterusnya. Harus menjadi bilangan bulat >= 0.

PengamatanFungsi ini membutuhkan eksekusi pada setiap bar. Tidak disarankan untuk menggunakannya di dalam struktur loop for atau while, di mana perilakunya bisa tidak terduga. Harap dicatat bahwa menggunakan fungsi ini dapat menyebabkan pencelupan ulang indikator.

Lihat juga ta.lowestbars ta.highestbars ta.barssince ta.highest ta.lowest

ta.vwap

Harga rata-rata tertimbang volume.

ta.vwap(source) 

PengembalianRata-rata tertimbang volume.

Argumen

• source(seri int/float) Seri sumber.

Lihat juga ta.vwap

ta.vwma

Fungsi vwma mengembalikan rata-rata bergerak tertimbang volume darisourceuntuklengthsama dengan: sma ((sumber * volume, panjang) / sma ((volume, panjang).

ta.vwma(source, length) 

Contoh

plot(ta.vwma(close, 15))

// same on pine, but less efficient
pine_vwma(x, y) =>
    ta.sma(x * volume, y) / ta.sma(volume, y)
plot(pine_vwma(close, 15))

PengembalianRata-rata bergerak tertimbang volume darisourceuntuklengthBar kembali.

Argumen

• source(serangkaian int/float) Serangkaian nilai untuk diproses.
• length(seri int) Jumlah batang (panjang).

Lihat juga ta.sma ta.ema ta.rma ta.wma ta.swma ta.alma

ta.wpr

Williams %R. Osilator menunjukkan harga penutupan saat ini dalam kaitannya dengan harga tertinggi dan terendah dari periode waktu bar yang lalu.

ta.wpr(length) 

Contoh

plot(ta.wpr(14), title="%R", color=color.new(#ff6d00, 0))

PengembalianWilliams %R.

Argumen

• length(seri int) Jumlah batang.

Lihat juga ta.mfi ta.cmo

plot

plot

Membuat grafik serangkaian data pada grafik.

plot(series, title, color, linewidth, style, trackprice, histbase, offset, join, editable, show_last, display) 

Contoh

plot(high+low, title='Title', color=color.new(#00ffaa, 70), linewidth=2, style=plot.style_area, offset=15, trackprice=true)

// You may fill the background between any two plots with a fill() function:
p1 = plot(open)
p2 = plot(close)
fill(p1, p2, color=color.new(color.green, 90))

PengembalianObjek plot, yang bisa digunakan dalam mengisi.

Argumen

• series(seri int/float) Serangkaian data yang akan digambarkan.
• title(const string) Judul plot.
• colorAnda bisa menggunakan konstanta seperti warna=warna.merah atau color=#ff001a serta ekspresi kompleks seperti color = close >= open?color.green : color.redArgumen opsional.
• linewidth(input int) Lebar garis yang digambarkan. Nilai default adalah 1.
• style(plot_style) Jenis plot. Nilai yang mungkin adalah: plot.style_line, plot.style_stepline, plot.style_stepline_diamond, plot.style_histogram, plot.style_cross, plot.style_area, plot.style_columns, plot.style_circles, plot.style_linebr, plot.style_areabr. Nilai default adalah plot.style_line.
• trackprice(input bool) Jika benar maka garis harga horizontal akan ditampilkan pada tingkat nilai indikator terakhir.
• histbase(input int/float) Nilai harga yang digunakan sebagai tingkat referensi saat membuat plot dengan plot.style_histogram, plot.style_columns atau plot.style_area style.
• offset(series int) Menggeser plot ke kiri atau ke kanan pada jumlah batang yang diberikan.
• join(input bool) Jika benar maka titik plot akan bergabung dengan garis, hanya berlaku untuk gaya plot.style_cross dan plot.style_circles.
• editable(const bool) Jika benar maka gaya plot akan dapat diedit dalam dialog Format.
• show_last(input int) Jika ditetapkan, mendefinisikan jumlah bar (dari bar terakhir kembali ke masa lalu) untuk digambarkan pada grafik.
• display(plot_display) Kontrol di mana plot ditampilkan. Nilai yang mungkin adalah: display.none, display.all. Default adalah display.all.
• overlay(const bool) adalah argumen ekstensi dari platform FMZ, digunakan untuk mengatur fungsi saat ini untuk ditampilkan pada gambar utama (set to true) atau sub-image (set to false), nilai default adalah false.overlayargumen dalamstrategyatauindicatorJikastrategyatauindicatortidak mengaturoverlayArgumen, itu akan diproses sesuai dengan argumen default.

Lihat juga plotshape plotchar bgcolor

bentuk plot

Membuat grafik bentuk visual pada grafik.

plotshape(series, title, style, location, color, offset, text, textcolor, editable, size, show_last, display) 

Contoh

data = close >= open
plotshape(data, style=shape.xcross)

Argumen

• series(seri bool) Serangkaian data yang akan digambarkan sebagai bentuk. Seri diperlakukan sebagai serangkaian nilai boolean untuk semua nilai lokasi kecuali location.absolute.
• title(const string) Judul plot.
• style(input string) Jenis plot. Nilai yang mungkin adalah: shape.xcross, shape.cross, shape.triangleup, shape.triangledown, shape.flag, shape.circle, shape.arrowup, shape.arrowdown, shape.labelup, shape.labeldown, shape.square, shape.diamond. Nilai default adalah shape.xcross.
• location(input string) Lokasi bentuk pada grafik. Nilai yang mungkin adalah: location.abovebar, location.belowbar,location.top, location.bottom, location.absolute Nilai default adalah location.abovebar
• color(warna seri) Warna bentuk. Anda dapat menggunakan konstanta seperti warna=warna.merah atau color=#ff001a serta ekspresi kompleks seperti color = close >= open?color.green : color.redArgumen opsional.
• offset(series int) Menggeser bentuk ke kiri atau ke kanan pada jumlah batang yang diberikan.
• text(const string) Teks untuk ditampilkan dengan bentuk. Anda dapat menggunakan teks multiline, untuk memisahkan baris menggunakan \n escape sequence. contoh: line one\nline two
• textcolor(warna seri) Warna teks. Anda dapat menggunakan konstanta sepertitextcolor=color.red atau textcolor=#ff001a serta ekspresi kompleks seperti textcolor = close >= open?color.green : color.redArgumen opsional.
• editable(const bool) Jika benar maka gaya plotshape akan dapat diedit dalam dialog Format.
• show_last(input int) Jika ditetapkan, mendefinisikan jumlah bentuk (dari bar terakhir kembali ke masa lalu) untuk digambarkan pada grafik.
• size(const string) Ukuran bentuk pada grafik.size.auto, size.tiny, size.small, size.normal, size.large, size.huge.Default adalahsize.auto.
• display(plot_display) Kontrol di mana plot ditampilkan. Nilai yang mungkin adalah: display.none, display.all. Default adalah display.all.
• overlay(const bool) adalah argumen ekstensi dari platform FMZ, digunakan untuk mengatur fungsi saat ini untuk ditampilkan pada gambar utama (set to true) atau sub-image (set to false), nilai default adalah false.overlayargumen dalamstrategyatauindicatorJikastrategyatauindicatortidak mengaturoverlayArgumen, itu akan diproses sesuai dengan argumen default.

Lihat juga plot plotchar bgcolor

plotchar

Membuat grafik bentuk visual menggunakan karakter Unicode tertentu pada grafik.

plotchar(series, title, char, location, color, offset, text, textcolor, editable, size, show_last, display) 

Contoh

data = close >= open
plotchar(data, char='❄')

Argumen

• series(seri bool) Serangkaian data yang akan digambarkan sebagai bentuk. Seri diperlakukan sebagai serangkaian nilai boolean untuk semua nilai lokasi kecuali location.absolute.
• title(const string) Judul plot.
• char(input string) Karakter untuk digunakan sebagai bentuk visual.
• location(input string) Lokasi bentuk pada grafik. Nilai yang mungkin adalah: location.abovebar, location.belowbar,location.top, location.bottom, location.absolute Nilai default adalah location.abovebar
• color(warna seri) Warna bentuk. Anda dapat menggunakan konstanta seperti warna=warna.merah atau color=#ff001a serta ekspresi kompleks seperti color = close >= open?color.green : color.redArgumen opsional.
• offset(series int) Menggeser bentuk ke kiri atau ke kanan pada jumlah batang yang diberikan.
• text(const string) Teks untuk ditampilkan dengan bentuk. Anda dapat menggunakan teks multiline, untuk memisahkan baris menggunakan \n escape sequence. contoh: line one\nline two
• textcolor(warna seri) Warna teks. Anda dapat menggunakan konstanta sepertitextcolor=color.red atau textcolor=#ff001a serta ekspresi kompleks seperti textcolor = close >= open?color.green : color.redArgumen opsional.
• editable(const bool) Jika benar maka gaya plotchar akan dapat diedit dalam dialog Format.
• show_last(input int) Jika ditetapkan, mendefinisikan jumlah karakter (dari bar terakhir kembali ke masa lalu) untuk digambarkan pada grafik.
• size(const string) Ukuran karakter pada grafik.size.auto, size.tiny, size.small, size.normal, size.large, size.huge.Default adalahsize.auto.
• display(plot_display) Kontrol di mana plot ditampilkan. Nilai yang mungkin adalah: display.none, display.all. Default adalah display.all.
• overlay(const bool) adalah argumen ekstensi dari platform FMZ, digunakan untuk mengatur fungsi saat ini untuk ditampilkan pada gambar utama (set to true) atau sub-image (set to false), nilai default adalah false.overlayargumen dalamstrategyatauindicatorJikastrategyatauindicatortidak mengaturoverlayArgumen, itu akan diproses sesuai dengan argumen default.

Lihat juga plot plotshape bgcolor

plotcandle

Menggambar lilin pada bagan.

plotcandle(open, high, low, close, title, color, wickcolor, editable, show_last, bordercolor, display)

Contoh

indicator("plotcandle example", overlay=true)
plotcandle(open, high, low, close, title='Title', color = open < close ? color.green : color.red, wickcolor=color.black)

Argumen

• open(seri int/float) Serangkaian data terbuka yang akan digunakan sebagai nilai terbuka dari lilin.
• high(seri int/float) Seri data tinggi yang akan digunakan sebagai nilai tinggi dari lilin.
• low(seri int/float) Rangkaian data rendah yang akan digunakan sebagai nilai rendah dari lilin.
• close(seri int/float) Tutup rangkaian data yang akan digunakan sebagai nilai dekat lilin.
• title(const string) Judul dari plotcandles.
• color(warna seri) Warna lilin. Anda dapat menggunakan konstanta sepertiwarna=warna.merah atau color=#ff001a serta ekspresi kompleks seperti color = close >= open?color.green : color.redArgumen opsional.
• wickcolor(warna seri) Warna dari korek lilin. argumen opsional.
• editable(const bool) Jika benar maka gaya plotcandle akan dapat diedit di dialog Format.
• show_last(input int) Jika ditetapkan, mendefinisikan jumlah lilin (dari bar terakhir kembali ke masa lalu) untuk digambarkan pada grafik.
• bordercolor(warna seri) Warna tepi lilin. Argumen opsional.
• display(plot_display) Kontrol di mana plot ditampilkan. Nilai yang mungkin adalah: display.none, display.all. Default adalah display.all.
• overlay(const bool) adalah argumen ekstensi dari platform FMZ, digunakan untuk mengatur fungsi saat ini untuk ditampilkan pada gambar utama (set to true) atau sub-image (set to false), nilai default adalah false.overlayargumen dalamstrategyatauindicatorJikastrategyatauindicatortidak mengaturoverlayArgumen, itu akan diproses sesuai dengan argumen default.

PengamatanBahkan jika satu nilai terbuka, tinggi, rendah atau dekat sama dengan NaN, maka bar tidak perlu menarik. Nilai maksimum terbuka, tinggi, rendah atau dekat akan ditetapkan sebagai high, dan nilai minimum akan ditetapkan sebagai low.

Lihat juga plotbar

Plotarrow

Gambar panah ke atas dan ke bawah pada grafik. panah ke atas ditarik pada setiap nilai indikator positif, panah ke bawah ditarik pada setiap nilai negatif. jika indikator kembali na maka tidak ada panah yang ditarik. panah memiliki ketinggian yang berbeda, semakin mutlak

Lebih banyak