FMZ Quant プラットフォームでの温度計戦略の実践と適用

FMZ Quant プラットフォームでの温度計戦略の実践と適用

なぜ恒温器と呼ばれるのか.我々は,市場変動とトレンドパターンの両方でシフトと取引に適応する能力に応じてシステムを命名した.このシステムは,特定の市場領域における特定のシステムの成功の観察から派生した.このシステムは,市場の両方のパターンを完全に利用するために二重性のある戦略を作成することができます.

まず,市場パターンを決定する機能を作成します. この機能の出力に応じて,温度調節器はフォローモードから短期スイングモードに切り替えます.

トレンドトラッキングモードは,ボリンジャー帯のトレンドトラッキングメカニズムに似ている.短期スウィングシステムはパターン認識を含むオープンブレークスルーである.この機能は,市場の移動距離と実際の距離を比較する.

Abs (終了価格 - 終了価格[29])/ ((最高価格(30) - 最低価格 (最低価格,30日) * 100

この関数は 0 から 100 の間の値を生成する.値が高くなるほど,現在の市場は混雑が少なくなる.関数によって返される値は 20 未満である場合,システムは短期スイングモードに入ります.

基本的には,市場のほとんどはスイング動きを示しており,システムは変動を捉え,そこから小さな利益を得ようとします. 恒温台は,小さな市場インパルスで購入/販売することでこの壮大な業績を達成しようとします. 変動が十分に大きい場合は,システムはモードを切り替えます.

短期変動の深層分析を通じて,時折購入は販売よりも優れている,そしてその逆のことも発見する.この時点で,それは単純な視覚モードで決定することができます.今日の閉店価格が昨日の高点,低点,閉店価格 (また,日のキーポイントとしても知られています) より高い場合,我々は明日市場の動きが下落傾向にあると考えます.しかし,今日の閉店価格が昨日の高点,低点,平均閉店価格よりも低い場合,今日の市場は上昇傾向にある可能性があります.これらの時期は,購入と販売が容易な価格として分類します.

FMZ Quant プラットフォームでは,サーモスタット戦略は非常に人気のある戦略です.ユーザーは,戦略のパフォーマンスを向上させるために,自分のニーズに応じて追加の取引論理を追加することができます.以下は,FMZ Quant プラットフォーム上のサーモスタット戦略の典型的なフレームワークです:

• メインチャート: 上回線式:TOP^^MAC+N_TMPTMP;//ボリンガー・チャネル上回線 ダウントラック式: BTTOM^^MAC-N_TMPTMP;//ボリンガー・チャネルダウントラック

• サブチャート: CMI公式: CMI:ABS(C-REF(C,N_CMI-1))/(HHV(H,N_CMI)-LLV(L,N_CMI))*100;//0〜100の値が大きいほど,トレンドが強くなる.CMI <20は変動モードであり,CMI >20はトレンドである.

• コード (MyLanguage):

MAC:=MA(CLOSE,N);
TMP:=STD(CLOSE,N);
TOP^^MAC+N_TMP*TMP;      // Bollinger channel upper track
BOTTOM^^MAC-N_TMP*TMP;   // Bollinger channel down track
BBOLL:=C>MAC;
SBOLL:=C<MAC;
N_CMI:=30;

CMI:ABS(C-REF(C,N_CMI-1))/(HHV(H,N_CMI)-LLV(L,N_CMI))*100; // The greater the value of 0-100 is, the stronger the trend will be. CMI < 20 is volatility mode, CMI >20 is the trend.

N_KD:=9;
M1:=3;
M2:=3;
RSV:=(CLOSE-LLV(LOW,N_KD))/(HHV(HIGH,N_KD)-LLV(LOW,N_KD))*100; // The difference between the closing price and the lowest value of N period is made, the difference between the highest value of N period and the lowest value of N period is made, and the ratio between the two differences is made.

K:=SMA(RSV,M1,1); // Moving average of RSV
D:=SMA(K,M2,1);   // Moving average of K
MIND:=30;
BKD:=K>D AND D<MIND;
SKD:=K<D AND D>100-MIND;

// Oscillation mode
BUYPK1:=CMI < 20 AND BKD;  // Oscillating long position, buy close
SELLPK1:=CMI < 20 AND SKD; // Oscillating short position, sell close

// Handling of original oscillating positions in trend mode
SELLY1:=REF(CMI,BARSBK) < 20 AND C>BKPRICE*(1+0.01*STOPLOSS*3) AND K<D; // Oscillation long position stop-profit
BUYY1:=REF(CMI,BARSSK) < 20 AND C<SKPRICE*(1-0.01*STOPLOSS*3) AND K>D;  // Oscillation short position stop-profit

// Trend mode
BUYPK2:=CMI >= 20 AND C > TOP;        // Trend long position, buy close
SELLPK2:=CMI >= 20 AND C < BOTTOM;    // Trend short position, sell close

// Handling of original oscillating positions in trend mode
SELLY2:=REF(CMI,BARSBK) >= 20 AND C>BKPRICE*(1+0.01*STOPLOSS*3) AND SBOLL;// Trend long position stop-profit
BUYY2:=REF(CMI,BARSSK) >= 20 AND C<SKPRICE*(1-0.01*STOPLOSS*3) AND BBOLL;// Trend short position stop-profit
SELLS2:=REF(CMI,BARSBK) >= 20 AND C<BKPRICE*(1-0.01*STOPLOSS) AND SBOLL;// Trend long position stop-loss
BUYS2:=REF(CMI,BARSSK) >= 20 AND C>SKPRICE*(1+0.01*STOPLOSS) AND BBOLL;// Trend short position stop-loss

IF BARPOS>N THEN BEGIN
    BUYPK1,BPK;
    SELLPK1,SPK;
    BUYPK2,BPK;
    SELLPK2,SPK;
END
BUYY1,BP(SKVOL);
BUYY2,BP(SKVOL);
BUYS2,BP(SKVOL);
SELLY1,SP(BKVOL);
SELLY2,SP(BKVOL);
SELLS2,SP(BKVOL);

戦略のバックテストの結果は以下のとおりです.

詳細については,以下を参照してください.https://www.fmz.com/strategy/129086.