資源の読み込みに... 荷物...
  1. スクエア
  2. 複合期貨取引戦略 急速なRSIリスク管理

複合期貨取引戦略 急速なRSIリスク管理

作者: リン・ハーンチャオチャン,日付: 2023-11-13 11:36:34
タグ:

img

概要

この戦略は,スポット取引プラットフォームBitMEXのために設計されています. 急速なRSI指標を分析し,複数の技術指標をスクリーン信号に組み合わせることで,効率的なトレンド追跡取引を実現します. また,戦略は,取引リスクを効果的に制御するためのリスク管理とストップ損失メカニズムを設定します.

戦略の論理

  1. 7日間のパラメータとオーバーバイッドライン25とオーバーセールライン75を計算する. RSIがオーバーバイッドラインを越えると,それはオーバーバイッド信号です. RSIがオーバーセールラインを下回ると,それはオーバーセール信号です.

  2. キャンドルスタイルのボディにフィルターをセットします.キャンドルストイルのボディの長さは昨日の平均ボディ長さの20%未満で下落のキャンドルとして開く必要があります.

  3. キャンドルスタイルの色にフィルターを設定します.ショートに行くと最後の4個のキャンドルは下落し,ロングに行くと最後の4つのキャンドルは上昇します.

  4. ストップ・ロスト・ロジックを設定します.価格が不利な方向に動くとポジションを閉じる.

  5. ストップ・ロスト・レベルを 初期動き後 価格が回復したときにのみ 信号を受けます

  6. ポジションのサイズを設定します. 取引ごとに固定資本のパーセントを使用し,損失ごとにポジションのサイズを倍にする.

利点分析

  1. 合理的に設定された速いRSIパラメータは,トレンドを迅速に把握することができます.キャンドルスタイクボディとカラーフィルタを組み合わせることで,誤ったブレイクを効果的に防ぐことができます.

  2. 多層フィルターは取引の数を減らすことで 勝率を高めます

  3. ストップ・ロスのメカニズム内蔵 トレード・ロスの制限

  4. ダイナミックなポジションサイジングは 適度に積極的な資本管理を実現します

  5. 調整可能な取引タイムフレームは 大事なイベントからの騒音を回避します

リスク と 最適化

  1. 高速は取引の機会を逃すかもしれないし 柔軟性を高めるためにパラメータを緩めるかもしれない

  2. トレンド終結を判断するのは難しい.潜在的な逆転を検出するために他の指標と組み合わせることを検討してください.

  3. ポジションサイズメソッドが攻撃的すぎると ポジションをロックする方法を導入できます

  4. より良いパラメータの組み合わせを見つけるために,異なる市場のためのパラメータを最適化することができます.

結論

この戦略はかなり堅牢である.急速なRSIでトレンド方向を判断し,複数の指標でシグナルをフィルタリングすることで,トレンド中に良いリターンを得ることができます.また,戦略には最適化のための余地があります.パラメータの組み合わせを調整することで,異なる市場環境に適応し,良い実用性を持っています.

/*backtest
start: 2023-11-05 00:00:00
end: 2023-11-12 00:00:00
period: 5m
basePeriod: 1m
exchanges: [{"eid":"Futures_Binance","currency":"BTC_USDT"}]
*/

//Noro
//2018

//@version=2
strategy(title = "Robot BitMEX Fast RSI v1.0", shorttitle = "Robot BitMEX Fast RSI v1.0", overlay = false, default_qty_type = strategy.percent_of_equity, default_qty_value = 100, pyramiding = 10)

//Settings
needlong = input(true, defval = true, title = "Long")
needshort = input(true, defval = true, title = "Short")
usemar = input(true, defval = true, title = "Use Martingale")
capital = input(100, defval = 100, minval = 1, maxval = 10000, title = "Capital, %")
rsiperiod = input(7, defval = 7, minval = 2, maxval = 100, title = "RSI Period")
rsilimit = input(25, defval = 25, minval = 1, maxval = 30, title = "RSI limit")
rsibars = input(1, defval = 1, minval = 1, maxval = 20, title = "RSI Bars")
useocf = input(true, defval = true, title = "Use Open Color Filter")
useccf = input(true, defval = true, title = "Use Close Color Filter")
openbars = input(4, defval = 4, minval = 1, maxval = 20, title = "Open Color Bars")
closebars = input(1, defval = 1, minval = 1, maxval = 20, title = "Close Color Bars")
useobf = input(true, defval = true, title = "Use Open Body Filter")
usecbf = input(true, defval = true, title = "Use Close Body Filter")
openbody = input(20, defval = 20, minval = 0, maxval = 1000, title = "Open Body Minimum, %")
closebody = input(50, defval = 50, minval = 0, maxval = 1000, title = "Close Body Minimum, %")
usecnf = input(true, defval = true, title = "Use Close Norma Filter")
fromyear = input(1900, defval = 1900, minval = 1900, maxval = 2100, title = "From Year")
toyear = input(2100, defval = 2100, minval = 1900, maxval = 2100, title = "To Year")
frommonth = input(01, defval = 01, minval = 01, maxval = 12, title = "From Month")
tomonth = input(12, defval = 12, minval = 01, maxval = 12, title = "To Month")
fromday = input(01, defval = 01, minval = 01, maxval = 31, title = "From Day")
today = input(31, defval = 31, minval = 01, maxval = 31, title = "To Day")

//RSI
uprsi = rma(max(change(close), 0), rsiperiod)
dnrsi = rma(-min(change(close), 0), rsiperiod)
rsi = dnrsi == 0 ? 100 : uprsi == 0 ? 0 : 100 - (100 / (1 + uprsi / dnrsi))
uplimit = 100 - rsilimit
dnlimit = rsilimit
rsidn = rsi < dnlimit ? 1 : 0
rsiup = rsi > uplimit ? 1 : 0
rsidnok = sma(rsidn, rsibars) == 1
rsiupok = sma(rsiup, rsibars) == 1

//Body Filter
body = abs(close - open)
abody = sma(body, 10)
openbodyok = body >= abody / 100 * openbody or useobf == false
closebodyok = body >= abody / 100 * closebody or usecbf == false

//Color Filter
bar = close > open ? 1 : close < open ? -1 : 0
gbar = bar == 1 ? 1 : 0
rbar = bar == -1 ? 1 : 0
opengbarok = sma(gbar, openbars) == 1 or useocf == false
openrbarok = sma(rbar, openbars) == 1 or useocf == false
closebarok = (strategy.position_size > 0 and bar == 1) or (strategy.position_size < 0 and bar == -1) or useccf == false

//Norma Filter
norma = (rsi > dnlimit and rsi < uplimit) or usecnf == false

//Signals
up = openrbarok and rsidnok and openbodyok and (strategy.position_size == 0 or close < strategy.position_avg_price)
dn = opengbarok and rsiupok and openbodyok and (strategy.position_size == 0 or close > strategy.position_avg_price)
exit = ((strategy.position_size > 0 and closebarok and norma) or (strategy.position_size < 0 and closebarok and norma)) and closebodyok

//Indicator
plot(rsi, color = blue, linewidth = 3, title = "Double RSI")
plot(uplimit, color = black, title = "Upper Line")
plot(dnlimit, color = black, title = "Lower Line")
colbg = rsi > uplimit ? red : rsi < dnlimit ? lime : na
bgcolor(colbg, transp = 20)

//Trading
profit = exit ? ((strategy.position_size > 0 and close > strategy.position_avg_price) or (strategy.position_size < 0 and close < strategy.position_avg_price)) ? 1 : -1 : profit[1]
mult = usemar ? exit ? profit == -1 ? mult[1] * 2 : 1 : mult[1] : 1
lot = strategy.position_size == 0 ? strategy.equity / close * capital / 100 * mult : lot[1]

if up
    if strategy.position_size < 0
        strategy.close_all()
        
    strategy.entry("Long", strategy.long, needlong == false ? 0 : lot, when=(time > timestamp(fromyear, frommonth, fromday, 00, 00) and time < timestamp(toyear, tomonth, today, 23, 59)))

if dn
    if strategy.position_size > 0
        strategy.close_all()
        
    strategy.entry("Short", strategy.short, needshort == false ? 0 : lot, when=(time > timestamp(fromyear, frommonth, fromday, 00, 00) and time < timestamp(toyear, tomonth, today, 23, 59)))
    
if time > timestamp(toyear, tomonth, today, 23, 59) or exit
    strategy.close_all()
もっと

2019 FMZ - すべての権利は保護されています.