리소스 로딩... 로딩...

멀티 타임프레임 이치모쿠, MACD 및 DMI 결합 전략

저자:차오장, 날짜: 2024-02-02 18:04:28
태그:

전반적인 설명

이 전략은 이치모쿠 클라우드, 이동 평균 컨버전스 디버전스 (MACD) 및 방향 움직임 지수 (DMI) 를 여러 시간 프레임에 걸쳐 결합하여 잠재적 인 구매 및 판매 신호를 식별합니다. 단기 및 중장기 관점에서 시장의 다차원적 인 시각을 취하고자하는 거래자에게 참조를 제공하는 것을 목표로합니다.

전략 논리

이 전략은 15분 (M15) 및 1시간 (H1) 차트에서 일관된 신호를 기반으로 구매 및 판매 조건을 실행하며, 4시간 (H4) 시간 프레임에서 추가 확인이 됩니다.

구매 조건

M15, H1 및 H4 시간 프레임에서 Ichimoku Cloud 이상의 가격
시그널 라인 위에 있는 MACD 라인과 H1에서 0 위에 있는 두 라인
H1에서 DI+ 이상 DI- 및 ADX 최소 25
MACD 라인은 0 이상, DI+는 DI- 이상, ADX는 M15에서 최소 25 이상

판매 조건

M15, H1 및 H4 시간 프레임에서 Ichimoku Cloud 이하의 가격
시그널 라인 아래 MACD 라인 그리고 H1에서 0 아래 두 라인
DI- H1에서 DI+와 ADX 이상 최소 25
MACD 라인은 0 이하, DI-는 DI+ 이상, ADX는 M15에서 최소 25

출입 및 출입

모든 구매 조건이 충족되었을 때 긴 포지션을 입력하여 시간 프레임에 걸쳐 상승 동력을 제안합니다.
모든 판매 조건이 충족되었을 때 짧은 포지션을 입력하여 시간 프레임에 걸쳐 하락 동력을 제안합니다.
반대 조건이 충족되면 포지션이 닫히고, 잠재적인 트렌드 반전 또는 동력 손실을 나타냅니다.

전략 의 장점

정확성을 향상시키기 위해 여러 시간 프레임을 고려합니다.
이치모쿠는 트렌드 방향과 강도를 판단합니다.
MACD 지표 단기 및 중기 추진력
DMI는 구매/판매 압력과 트렌드 활동을 평가합니다.
여러 지표의 신호를 결합합니다.
구매/판매 조건에 대한 사용자 정의 가능한 매개 변수
명확한 추세를 보이는 시장에 널리 적용됩니다.

전략 의 위험

시간 프레임에서 충돌 신호는 나쁜 신호를 일으킬 수 있습니다.
이치모쿠는 잘못 사용되면 오해 할 수 있습니다.
MACD와 DMI는 뒤떨어진 성격을 가지고 있으며, 회전을 놓칠 수 있습니다.
여러 시간 프레임 지표를 모니터링 할 필요가 있습니다.
갑작스러운 사건으로 인한 엄청난 가격 변동에 대한 신중한 처리

최적화 방향

이치모쿠, MACD 및 DMI 매개 변수 조합을 최적화
매일처럼 더 많은 시간 프레임을 테스트
변동성, 이동 평균 등과 같은 더 많은 지표로부터 확인을 추가합니다.
더 많은 역사적 데이터로 구매/판매 조건을 최적화
기계 학습 등으로 동적 매개 변수 최적화

결론

이 전략은 트렌드 방향과 강도를 효과적으로 식별하기 위해 멀티 타임프레임 분석과 여러 지표의 장점을 완전히 활용합니다. 매개 변수 조정 및 특정 시장 조건에 최적화하여 다른 제품에 적응 할 수 있습니다. 그러나 거래자는 여전히 지표의 한계를 의식하고 적절한 위험 통제 조치를 취해야합니다. 전반적으로 전략은 시장을 측정하기위한 비교적 포괄적인 틀을 제공합니다.

/*backtest
start: 2024-01-25 00:00:00
end: 2024-02-01 00:00:00
period: 1h
basePeriod: 15m
exchanges: [{"eid":"Futures_Binance","currency":"BTC_USDT"}]
*/

// This Pine Script™ code is subject to the terms of the Mozilla Public License 2.0 at https://mozilla.org/MPL/2.0/
// © haidinh83

//@version=5
strategy("Ichimoku, MACD, DMI Multiple time frame 21/01/2024", overlay=true)
    // Khung thời gian
timeframe1 = "5"   // M5
timeframe2 = "15"  // M15
timeframe3 = "60"  // H1
timeframe4 = "240" // H4

    // Nhập tham số ADX và DI
lengthDMI = input(14, title="DMI Length")
thresholdADX = input(20, title="ADX Threshold")

// Tính giá trị Ichimoku
ichimoku(tenkanPeriod, kijunPeriod, senkouPeriod) =>
    tenkanSen = (ta.highest(high, tenkanPeriod) + ta.lowest(low, tenkanPeriod)) / 2
    kijunSen = (ta.highest(high, kijunPeriod) + ta.lowest(low, kijunPeriod)) / 2
    senkouSpanA = (tenkanSen + kijunSen) / 2
    senkouSpanB = (ta.highest(high, senkouPeriod) + ta.lowest(low, senkouPeriod)) / 2
    [tenkanSen, kijunSen, senkouSpanA, senkouSpanB]

    // Lấy Ichimoku từng khung thời gian
[tenkanM5, kijunM5, spanAM5, spanBM5] = request.security(syminfo.tickerid, timeframe1, ichimoku(9, 26, 52))
[tenkanM15, kijunM15, spanAM15, spanBM15] = request.security(syminfo.tickerid, timeframe2, ichimoku(9, 26, 52))
[tenkanH1, kijunH1, spanAH1, spanBH1] = request.security(syminfo.tickerid, timeframe3, ichimoku(9, 26, 52))
[tenkanH4, kijunH4, spanAH4, spanBH4] = request.security(syminfo.tickerid, timeframe4, ichimoku(9, 26, 52))

    // Tính giá trị MACD và Signal Line cho từng khung thời gian
[macdM5, signalM5, _] = request.security(syminfo.tickerid, timeframe1, ta.macd(close, 12, 26, 9))
[macdM15, signalM15, _] = request.security(syminfo.tickerid, timeframe2, ta.macd(close, 12, 26, 9))
[macdH1, signalH1, _] = request.security(syminfo.tickerid, timeframe3, ta.macd(close, 12, 26, 9))
[macdH4, signalH4, _] = request.security(syminfo.tickerid, timeframe4, ta.macd(close, 12, 26, 9))

  // Tính giá trị DMI cho từng khung thời gian
calcDMI(len) =>
    up = ta.change(high)
    down = -ta.change(low)
    plusDM = na(up) ? na : (up > down and up > 0 ? up : 0)
    minusDM = na(down) ? na : (down > up and down > 0 ? down : 0)
    trur = ta.rma(ta.tr, len)
    plus = fixnan(100 * ta.rma(plusDM, len) / trur)
    minus = fixnan(100 * ta.rma(minusDM, len) / trur)
    adx = 100 * ta.rma(math.abs(plus - minus) / (plus + minus == 0 ? 1 : plus + minus), len)
    [plus, minus, adx]  // Đảm bảo mỗi phần của hàm nằm trên một dòng riêng biệt


[plusM5, minusM5, adxM5] = request.security(syminfo.tickerid, timeframe1, calcDMI(lengthDMI))
[plusM15, minusM15, adxM15] = request.security(syminfo.tickerid, timeframe2, calcDMI(lengthDMI))
[plusH1, minusH1, adxH1] = request.security(syminfo.tickerid, timeframe3, calcDMI(lengthDMI))
[plusH4, minusH4, adxH4] = request.security(syminfo.tickerid, timeframe4, calcDMI(lengthDMI))



// Điều kiện mua cho H1
buyConditionH1 = (close > spanAM15) and (close > spanAH1) and (close > spanAH4) and 
                 (macdH1 > signalH1) and (macdH1 > 0) and (signalH1 > 0) and 
                 (plusH1 > minusH1) and (adxH1 >= 25)

// Điều kiện mua cho M15
buyConditionM15 = (close > spanAM15) and (close > spanAH1) and (close > spanAH4) and 
                  (macdM15 > 0) and (plusM15 > minusM15) and (adxM15 >= 25)

// Điều kiện mua tổng hợp
buyCondition = buyConditionH1 and buyConditionM15

// Điều kiện bán cho H1
sellConditionH1 = (close < spanAM15) and (close < spanAH1) and (close < spanAH4) and 
                  (macdH1 < signalH1) and (macdH1 < 0) and (signalH1 < 0) and 
                  (minusH1 > plusH1) and (adxH1 >= 25)

// Điều kiện bán cho M15
sellConditionM15 = (close < spanAM15) and (close < spanAH1) and (close < spanAH4) and 
                   (macdM15 < 0) and (minusM15 > plusM15) and (adxM15 >= 25)

// Điều kiện bán tổng hợp
sellCondition = sellConditionH1 and sellConditionM15

// Thực hiện giao dịch nếu điều kiện bán hoặc mua được đáp ứng
if buyCondition
    strategy.entry("Buy", strategy.long)

if sellCondition
    strategy.entry("Sell", strategy.short)


    // Vẽ và tô màu giữa Senkou Span A và B cho mỗi khung thời gian
p1 = plot(spanAM15, color=color.blue, title="Span A M15")
p2 = plot(spanBM15, color=color.blue, title="Span B M15")
fill(p1, p2, color=color.new(color.blue, 90), title="M15 Cloud")

p3 = plot(spanAH1, color=color.purple, title="Span A H1")
p4 = plot(spanBH1, color=color.purple, title="Span B H1")
fill(p3, p4, color=color.new(color.purple, 90), title="H1 Cloud")

p5 = plot(spanAH4, color=color.orange, title="Span A H4")
p6 = plot(spanBH4, color=color.orange, title="Span B H4")
fill(p5, p6, color=color.new(color.orange, 90), title="H4 Cloud")

    // Tô màu nền và hiển thị cảnh báo
 
bgcolor(buyCondition ? color.new(color.green, 45) : sellCondition ? color.new(color.red, 45) : na)
alertcondition(buyCondition, title="Mua Signal", message="Điều kiện mua đã được đáp ứng")
alertcondition(sellCondition, title="Bán Signal", message="Điều kiện bán đã được đáp ứng")

더 많은

2019 FMZ - 모든 권리 보호