1. 사각형
2. 허스트 미래 경계선 전략

허스트 미래 경계선 전략

저자:차오장, 날짜: 2024-04-29 13:58:06
태그:SMA

---

---

/*backtest
start: 2024-04-27 00:00:00
end: 2024-04-28 00:00:00
period: 10m
basePeriod: 1m
exchanges: [{"eid":"Futures_Binance","currency":"BTC_USDT"}]
*/

// This source code is subject to the terms of the Mozilla Public License 2.0 at https://mozilla.org/MPL/2.0/
// © BarefootJoey

//@version=5
strategy("Hurst Future Lines of Demarcation Strategy", overlay=true)

// FLD Settings
source      = input(ohlc4, 'Source')
smoothFLD   = input.bool(false, 'Smooth FLD')
FLDtransp   = input(33, 'FLD transparency')
FLDsmooth   = input.int(5, "FLD Smoothing", minval=1, tooltip="Number of trading days to smooth the FLD")   
FLD_out = ta.sma(source , smoothFLD ? FLDsmooth : 1)

close_buy_in_1 = input.string('Price', 'Input Close Trigger 1', options=['Price', 'Signal', 'Trade', 'Trend', 'None'])
close_buy_in_2 = input.string('Trade', 'Input Close Trigger 2', options=['Price', 'Signal', 'Trade', 'Trend', 'None'])

// Quarter Cycle (Default: 20 day) Length Pivot Cycle
col_q = input.color(#da00ff, "Quarter Cycle Color")
cyc_q = input.int(5, "Signal Cycle Length")
plot(FLD_out, color=color.new(col_q, FLDtransp), title='Signal FLD', offset = math.round(cyc_q/2) )

// Trade Cycle (Default: 20 day) Length Pivot Cycle
col = input.color(#ff9800, "Trade Cycle Color")
cyc = input.int(20, "Trade Cycle Length")
plot(FLD_out, color=color.new(col, FLDtransp), title='Trade FLD', offset = math.round(cyc/2) )

// Double Cycle (Default: 80 day) Length Pivot Cycle
col_d = input.color(color.aqua, "Double Cycle Color")
cyc_d = input.int(80, "Trend Cycle Length")
plot(FLD_out, color=color.new(col_d, FLDtransp), title='Trend FLD', offset = math.round(cyc_d/2) )

// Strategy Plots
price = source
signal = FLD_out[math.round(cyc_q/2)]
trade = FLD_out[math.round(cyc/2)]
trend = FLD_out[math.round(cyc_d/2)]

// Trend State
var state = 0
if signal > trade and trade > trend 
    state := 1 // (A)
    state
if state == 1 and price < signal
    state := 2 // (B)
    state
if signal < trade and trade > trend 
    state := 3 // (C)
    state
if state == 3 and price < signal 
    state := 4 // (D)
    state
if signal < trade and trade < trend 
    state := 5 // (E)
    state
if state == 5 and price < signal
    state := 6 // (F)
    state
if signal > trade and trade < trend
    state := 7 // (G)
    state
if state == 7 and price < signal
    state := 8 // (H)
    state
state := state

// Strategy Definitions
close_buy_out_1 = close_buy_in_1 == 'Price' ? price : close_buy_in_1 == 'Signal' ? signal : close_buy_in_1 == 'Trade' ? trade : close_buy_in_1 == 'Trend' ? trend : na
close_buy_out_2 = close_buy_in_2 == 'Price' ? price : close_buy_in_2 == 'Signal' ? signal : close_buy_in_2 == 'Trade' ? trade : close_buy_in_2 == 'Trend' ? trend : na
buy = ta.crossover(price, signal) and state == 1
close_buy = strategy.position_size>0 and ta.crossunder(close_buy_out_1, close_buy_out_2)
sell = ta.crossunder(price, signal) and state == 6
close_sell = strategy.position_size<0 and ta.crossover(close_buy_out_1, close_buy_out_2)

// FLD Interaction State Background
interaction_color = state == 1 ? color.green : // A
  state == 2 ? color.aqua : // B
  state == 3 ? color.blue : // C
  state == 4 ? color.purple : // D
  state == 5 ? color.white : // E
  state == 6 ? color.red :// F
  state == 7 ? color.orange : // G
  state == 8 ? color.yellow : na // H

bgcolor(color.new(interaction_color, 90), title= "A-H Background")

bar_color = strategy.position_size>0 ? #00ff0a : strategy.position_size<0 ? #FF0000 : na
barcolor(bar_color)

if buy
    strategy.entry("Buy", strategy.long)
if close_buy
    strategy.close("Buy", qty_percent=100)

if sell
    strategy.entry("Sell", strategy.short)
if close_sell
    strategy.close("Sell", qty_percent=100)

// EoS made w/ ❤ by @BarefootJoey ✌💗📈

---

• 보린저 밴드 및 RSI 통합을 통해 향상된 평균 역전 전략
• 멀티테크니컬 인디케이터 크로스 트렌드 추적 전략: RSI와 스토카스틱 RSI 시너지 거래 시스템
• 지능형 파동 트렌드 달러 비용 평균화 주기적 거래 전략
• MACD-RSI 크로스오버 트렌드
• 다중 SMA 구역의 파업과 동적 수익 잠금 양적 거래 전략
• 동적 파동 트렌드 추적 전략
• 부피 확증과 함께 구조의 해체 다 조건 지능형 거래 전략
• 다중 지표 동적 스톱 로스 동력 트렌드 거래 전략
• 거래 전략에 따른 다중 이동 평균 트렌드
• 멀티 필터 트렌드 돌파구 스마트 이동 평균 거래 전략
• 다중 지표 추세 옵션 거래 EMA 크로스 전략

---

• Z-Score 트렌드 전략
• MA99 터치 및 동적 스톱 로스 전략
• 돈치안 브레이크업 거래 전략
• 이치모쿠 선두 스판 B 브레이크업 전략
• EMA의 긴 입장은 위험 관리 전략과 교차합니다
• MACD와 RSI 결합된 장기 거래 전략
• 이중 이동평균 거래 전략
• VWAP 거래 전략
• 다중 지표 조합 전략 (CCI, DMI, MACD, ADX)
• RSI2 전략 내일 반전 승률 역시험
• OBV 및 MA 크로스오버 신호에 기반한 전략을 따르는 경향
• GBS TOP Bottom 확정된 전략
• 전략에 따른 다중 지표 트렌드
• 스크리즈 백테스트 트랜스포머 v2.0
• 피보나치 트렌드 역전 전략
• HTF 지그자그 경로 전략
• 웨이브 트렌드 크로스 레이지 베어 전략
• CCI, DMI, MACD 하이브리드 장기 단기 전략
• AlphaTradingBot 거래 전략
• 베가스 슈퍼 트렌드 강화 전략