1. 사각형
2. 고급 양적 거래 전략 RSI 분산 및 이동 평균을 결합

고급 양적 거래 전략 RSI 분산 및 이동 평균을 결합

저자:차오장, 날짜: 2024-06-28 15:02:37
태그:RSIMABBSMAEMASMMAWMAVWMA

---

---

/*backtest
start: 2024-05-28 00:00:00
end: 2024-06-27 00:00:00
period: 1h
basePeriod: 15m
exchanges: [{"eid":"Futures_Binance","currency":"BTC_USDT"}]
*/

//@version=5
strategy("Advanced Gold Scalping Strategy with RSI Divergence", overlay=false)

// Input parameters
rsiLengthInput = input.int(60, minval=1, title="RSI Length", group="RSI Settings")
rsiSourceInput = input.source(ohlc4, "Source", group="RSI Settings")
maTypeInput = input.string("SMMA (RMA)", title="MA Type", options=["SMA", "Bollinger Bands", "EMA", "SMMA (RMA)", "WMA", "VWMA"], group="MA Settings")
maLengthInput = input.int(3, title="MA Length", group="MA Settings")
bbMultInput = input.float(2.0, minval=0.001, maxval=50, title="BB StdDev", group="MA Settings")
showDivergence = input(true, title="Show Divergence", group="RSI Settings")
stopLoss = input.float(11, title="Stop Loss (pips)", group="Trade Settings")
takeProfit = input.float(33, title="Take Profit (pips)", group="Trade Settings")

// RSI and MA calculation
ma(source, length, type) =>
    switch type
        "SMA" => ta.sma(source, length)
        "Bollinger Bands" => ta.sma(source, length)
        "EMA" => ta.ema(source, length)
        "SMMA (RMA)" => ta.rma(source, length)
        "WMA" => ta.wma(source, length)
        "VWMA" => ta.vwma(source, length)

up = ta.rma(math.max(ta.change(rsiSourceInput), 0), rsiLengthInput)
down = ta.rma(-math.min(ta.change(rsiSourceInput), 0), rsiLengthInput)
rsi = down == 0 ? 100 : up == 0 ? 0 : 100 - (100 / (1 + up / down))
rsiMA = ma(rsi, maLengthInput, maTypeInput)
isBB = maTypeInput == "Bollinger Bands"

// Divergence detection
lookbackRight = 5
lookbackLeft = 5
rangeUpper = 60
rangeLower = 5

plFound = na(ta.pivotlow(rsi, lookbackLeft, lookbackRight)) ? false : true
phFound = na(ta.pivothigh(rsi, lookbackLeft, lookbackRight)) ? false : true

_inRange(cond) =>
    bars = ta.barssince(cond == true)
    rangeLower <= bars and bars <= rangeUpper

// Bullish divergence
rsiHL = rsi[lookbackRight] > ta.valuewhen(plFound, rsi[lookbackRight], 1) and _inRange(plFound[1])
priceLL = low[lookbackRight] < ta.valuewhen(plFound, low[lookbackRight], 1)
bullishDivergence = priceLL and rsiHL and plFound

// Bearish divergence
rsiLH = rsi[lookbackRight] < ta.valuewhen(phFound, rsi[lookbackRight], 1) and _inRange(phFound[1])
priceHH = high[lookbackRight] > ta.valuewhen(phFound, high[lookbackRight], 1)
bearishDivergence = priceHH and rsiLH and phFound

// Entry conditions
longCondition = bullishDivergence and rsi < 40
shortCondition = bearishDivergence and rsi > 60

// Convert pips to price for Gold (assuming 1 pip = 0.1 for XAUUSD)
stopLossPrice = stopLoss * 0.1
takeProfitPrice = takeProfit * 0.1

// Execute trades
if (longCondition)
    strategy.entry("Long", strategy.long)
    strategy.exit("TP/SL", "Long", stop=strategy.position_avg_price - stopLossPrice, limit=strategy.position_avg_price + takeProfitPrice)

if (shortCondition)
    strategy.entry("Short", strategy.short)
    strategy.exit("TP/SL", "Short", stop=strategy.position_avg_price + stopLossPrice, limit=strategy.position_avg_price - takeProfitPrice)

// Plotting
plot(rsi, "RSI", color=#7E57C2)
// plot(rsiMA, "RSI-based MA", color=color.yellow)
hline(60, "RSI Upper Band", color=#787B86)
// hline(50, "RSI Middle Band", color=color.new(#787B86, 50))
hline(40, "RSI Lower Band", color=#787B86)
fill(hline(60), hline(40), color=color.rgb(126, 87, 194, 90), title="RSI Background Fill")

// Divergence visualization
plotshape(showDivergence and bullishDivergence ? rsi[lookbackRight] : na, offset=-lookbackRight, title="Bullish Divergence", text="Bull", style=shape.labelup, location=location.absolute, color=color.green, textcolor=color.white)
plotshape(showDivergence and bearishDivergence ? rsi[lookbackRight] : na, offset=-lookbackRight, title="Bearish Divergence", text="Bear", style=shape.labeldown, location=location.absolute, color=color.red, textcolor=color.white)

---

• 볼링거 밴드 및 이동 평균 크로스오버 전략
• 전략에 따른 다기간 이동 평균 크로스오버 트렌드
• 적응적인 이동 평균 크로스오버 전략
• 변동성 필터와 함께 전략을 따르는 다중 이동 평균 크로스오버 트렌드
• MACD와 RSI 결합 자연 거래 전략
• 크롤의 슈퍼트렌드
• SSS
• 상위 윗부분의 윗부분의 윗부분의 윗부분의 윗부분의
• 다층 변동성 대역 거래 전략
• RSI: 피보트, BB, SMA, EMA, SMMA, WMA, VWMA와의 분차

---

• 유리한 배당
• 이득 차트
• 슈퍼트렌드와 EMA를 결합하는 전략을 따르는 동적 트렌드
• 5EMA 동적 스톱-러스 및 트레이크-프로피트 전략을 따르는 경향
• 향상된 동적 볼링거 밴드 거래 전략
• 동적 최적화된 슈퍼트렌드 거래 전략
• 멀티 모멘텀 선형 회귀 크로스오버 전략
• 전략에 따른 다중 이동 평균 크로스오버 트렌드
• 동적 스프레드 시장 제작 전략
• 볼링거 밴드 및 프랙탈 브레이크아웃을 기반으로 한 동적 역전점 전략
• EMA/SMA 다중 지표 포괄적 동향 전략
• 테스트 전략 인터랙션 컨트롤
• 테스트 정책 인터페이스 파라미터
• 볼링거 대역은 볼륨 필터로 리버션 거래 전략을 의미합니다.
• 다중 지표 높은 레버리지 단기 거래 전략
• 전략에 따른 다중 지표 복합 트렌드
• 다중 시간 프레임 피보나치 RSI 골든 크로스 트렌드 양적 거래 전략
• 동적 스톱 로스 및 취득 이중 이동 평균 트렌드 촛불 반응과 전략에 따라
• 기계 학습 기반 이동 평균 크로스오버 양적 거래 전략
• RSI와 스토카스틱 퓨전 크로스 전략