Sumber dimuat naik... memuat...

Dokumen MyLanguage

Penulis:Kebaikan, Dicipta: 2018-12-14 17:33:09, Dikemas kini: 2019-04-10 09:11:27

[TOC]

Penerangan asas
- Kontrak
  
  Kontrak niaga hadapan komoditi, kontrak cryptocurrency
  
  Kontrak niaga hadapan komoditi/mata wang kripto
```
this_week   OKEX futures contract for current week
next_week   OKEX futures contract for next week
quarter     OKEX futures contract for quarter

XBTUSD      BITMEX Perpetual Contract

rb888       Rebar main contract
MA000       Methanol Index Contract
rb1901      Rebar contract
…and so on.
```
  Apabila menetapkan kontrak, anda boleh memilih rb1901/rb1905 Data pasaran adalah rb1901, kontrak perdagangan pesanan adalah rb1905
- Variabel
  
  Peubah adalah ruang yang dibuka dalam memori komputer untuk menyimpan data.
  
  Mengisytiharkan pembolehubah pertama
```
// Assign 1 to the variable a
a:=1;
```
  Dalam M Language, perbezaan mudah dibuat dari volume data:
  1. Data bernilai tunggal: hanya satu nilai, seperti 0, 1, 'abc
  2. Data urutan: Urutan data yang terdiri daripada satu set data bernilai tunggal, seperti Close (harga penutupan), di mana Close mengandungi harga penutupan n kitaran [ 10.1, 10.2, 10.3, 10.4, 10. 5... ]
  Membezakan dari jenis pembolehubah
  1. Jenis rentetan: mesti menggunakan bungkusan, jenis rentetan tidak dibenarkan digunakan secara langsung, anda perlu memadankan output fungsi ke pandangan
```
INFO(CLSOE>OPEN,'OK!');
```
  1. Jenis nilai: termasuk bilangan bulat, nombor koma terapung (desimal)
```
// integer
int:=2;

// decimal
float:=3.1;
```
  1. Jenis Boolean, menggunakan 1 (untuk benar) atau 0 (untuk palsu): 1, 0, benar atau palsu, contohnya: A:=1>0; selepas pelaksanaan kod ini, nilai A adalah 1
```
// The current period closing price is greater than -999, you will find that the return value of each cycle is 1, representing true, because the closing price is almost impossible to be negative
Is_true:=Close>-999;
```
  1. Peralihan global
```
VARIABLE:VALUE1:10;     // Declare a global variable with a value of 10 and execute only once.
```
  - Peraturan penamaan
    
    Dalam kebanyakan sistem, penamaan pembolehubah tidak membenarkan penggunaan sistem kata-kata terpelihara (nama pembolehubah terbina dalam, nama fungsi), seperti Close yang terkenal, C. Di samping itu, nombor tulen tidak dibenarkan, atau nombor bermula dengan, dan tidak boleh terlalu panjang, sistem yang berbeza, dan had panjang yang berbeza adalah berbeza. Sebenarnya, anda tidak perlu mengelirukan kecekapan sistem arus perdana untuk analisis bahasa Inggeris. Saya percaya bahawa M Language sangat mesra dengan penutur bahasa Inggeris. Saya mengesyorkan anda menggunakan konvensyen penamaan berikut:
    
    Bahasa Inggeris + digariskan
```
// output
Move_avg_5:=MA(C,5);
```
    Jika anda lebih suka bahasa Inggeris, sila biarkan orang memahami makna pembolehubah anda sebanyak mungkin. Jangan menggunakan kaedah penamaan seperti: A1, AAA, BBB... Percayalah, selepas beberapa hari, apabila anda mengkaji semula kod penunjuk anda, anda akan sangat sakit kerana kekurangan memori. Begitu juga, apabila anda mengeksport kod kepada orang lain, pemikiran pembaca mesti telah runtuh.
    
    Kemudian, dari sekarang, memeluk M Language sebanyak yang anda boleh! Saya berharap ia akan menjadi alat yang kuat untuk analisis dan membuat keputusan anda.
- Jenis data
  
  Jenis data adalah konsep asas. dalam pengaturcaraan, apabila kita menetapkan data eksplisit kepada pembolehubah, pembolehubah menjadi jenis data itu sendiri.
  - 1. Jenis nilai:
```
1、2、3、1.1234、2.23456 ……
```
  - 1. Jenis rentetan (str):
```
'1' 、'2' 、'3' ，string type must be wrapped with ''
```
  - 1. Data urutan:
```
a collection of data consisting of a series of single-valued data
```
  - 1. Jenis Boolean (Boolean):
    Gunakan 1 untuk benar dan 0 untuk palsu
    
    Contoh
```
// Declare a variable of a numeric type
var_int := 1;
// Declare a variable of sequence data
var_arr := Close;
// String type can not be declared separately, you need to combine functions
INFO(C>O, 'rising line');
```
- Pengendali
  
  Operasi dan pengiraan yang digunakan untuk melaksanakan kod penunjuk, yang merupakan simbol operasi penyertaan.
  - Pengendali Tugas
    
    Digunakan untuk menetapkan nilai kepada pembolehubah
    - 1. :
      titik dua, mewakili penugasan dan output kepada rajah (deputi rajah)
```
Close1:Close;      // Assign Close to the variable Close1 and output it to the diagram
```
    - 1. :=
      kolon sama, mewakili tugasan, tetapi tidak output ke diagram (diagram utama, subgraph...) dan tidak dipaparkan dalam jadual bar status.
```
Close2:=Close;     // Assign Close to the variable Close2
```
    - 1. ^^
      ^, dua ^ simbol mewakili penugasan, menetapkan nilai kepada pembolehubah dan output mereka ke dalam rajah (rajah utama).
```
lastPrice^^C;
```
    - 1. ..
      ..., dua titik, Simbol mewakili penugasan, menetapkan nilai kepada pembolehubah dan memaparkannya dalam jadual bar status, tetapi tidak mengeluarkan ke dalam rajah (rajah utama, sub-rajah...).
```
openPrice..O
```
  - Operator hubungan
    
    Operator relasional adalah operator binokular yang digunakan dalam ungkapan bersyarat. Digunakan untuk menentukan hubungan antara dua data
    
    Nilai pulangan: Jenis Boolean, tidak benar (1), mesti salah (0)
    - 1. Lebih besar daripada >
```
// Assign the result of 2 > 1 to the rv1 variable, at this time rv1=1
Rv1:=2>1;
```
    - 1. Kurang daripada <
```
// returns false, which is 0, because 2 is greater than 1. :-)
rv3:=2<1;
```
    - 1. Lebih besar daripada atau sama dengan >=
```
x:=Close;
// Assign the result of the operation with a closing price greater than or equal to ¥ 10 to the variable rv2
// Note that since “close” is a sequence of data, when the close>=10 operation is performed, the essence is that each cycle is performed, so each cycle will have a return value of 1, 0.
rv2:=Close>=10;
```
    - 1. Kurang daripada atau sama dengan <=
```
Omitted here
```
    - 1. Sama dengan =
```
A:=O=C;     // Determine if the opening price is equal to the closing price.
```
    - 1. Tidak sama dengan <>
```
1<>2       // Judgment weather 1 is equal to 2 or not, the return value is 1 (true)
```
  - Operator Logik
```
Return value: Boolean type, not true (1), must be false (0)
```
    1. Logik dan &&, boleh menggunakan and sebaliknya, dan sisi kiri dan kanan sambungan mesti benar pada masa yang sama.
```
// determine whether cond_a, cond_b, cond_c is true at the same time,
cond_a:=2>1;
cond_b:=4>3;
cond_c:=6>5;
cond_a && cond_b and cond_c;    // return value 1, true
```
    1. Logika atau, boleh menggunakan or sebaliknya, or menghubungkan sebelah kiri dan kanan, selagi satu sisi adalah benar, keseluruhan adalah benar (kembali benar)
```
cond_a:=1>2;
cond_b:=4>3;
cond_c:=5>6;
cond_a || cond_b or cond_c;    // return value 1, true
```
  - Operator aritmetik
```
Return value: numeric type
```
    Ia adalah penyelesaian simbol pengendali aritmatika asas, yang merupakan simbol yang digunakan untuk memproses empat operasi aritmatika.
    - Plus +
```
A:=1+1;      // return 2
```
    - Kurangkan -
```
A:=2-1;      // return 1
```
    - Kalikan *
```
A:=2*2;      // return 4
```
    - Bahagikan dengan /
```
A:=4/2;      // return 2
```
- Fungsi
  - Fungsi
    
    Dalam dunia pengaturcaraan, fungsi sebenarnya adalah sekeping kod yang melaksanakan fungsi tertentu dan boleh dipanggil oleh kod lain.
```
function(param1,param2,……)
```
    - Komposisi:
      
      Nama fungsi (parameter 1, parameter 2,...), mungkin tidak ada parameter, mungkin terdapat beberapa parameter, seperti MA(x, n); mewakili purata bergerak mudah dalaman x mengembalikan n kitaran, di mana MA() adalah fungsi, x dan n adalah parameter fungsi.
      
      Apabila menggunakan fungsi, kita perlu memahami definisi asas fungsi, iaitu apa data yang boleh diperoleh dengan memanggil fungsi. Secara umum, fungsi mempunyai parameter. Apabila kita menghantar parameter, kita perlu memastikan bahawa jenis data yang dihantar sesuai. Pada peringkat semasa, fungsi petunjuk kod kebanyakan IDE sangat tidak sempurna. Mereka tidak menunjukkan jenis data tertentu untuk parameter yang diberikan, yang memberi kita beberapa masalah.
```
Return a simple moving average
usage：
AVG:=MA(X,N): N's simple moving average of X, algorithm (X1+X2+X3+...+Xn)/N,N supports variables
```
      Ini adalah penjelasan yang sangat tidak mesra untuk pemula. Seterusnya, kita menganalisis fungsi secara menyeluruh dan cuba mencari cara untuk cepat belajar dan menggunakan fungsi.
  - Nilai pulangan
    
    Untuk mempelajari fungsi dengan cepat, kita perlu memahami konsep yang dipanggil return value. Return, seperti namanya, adalah return, nilai mewakili nilai konkrit, data yang boleh diperoleh.
```
// Because it will be used in the following code, use the variable return_value to receive and save the return value of function()
// retrun_value := function(param1,param2);
// for example：
AVG:=MA(C,10); // AVG is retrun_value , “function” function is: MA function, param1 parameter: C is the closing price sequence data, param2 parameter: 10.
```
  - Parameter
    
    Kedua, konsep penting kedua fungsi adalah parameter, lulus dalam parameter yang berbeza, anda boleh mendapatkan nilai pulangan yang berbeza.
```
// variable ma5 receives 5 day closing price moving average
ma5:=MA(C,5);
// variable ma10 receives 10 day closing price moving average
ma10:=MA(C,10);
```
    Parameter pertama X dari pembolehubah di atas ma5, ma10 adalah C (harga penutupan), sebenarnya C juga merupakan fungsi (mengembalikan urutan harga penutupan sejak pembukaan), tetapi ia tidak mempunyai parameter. Parameter kedua 5, 10,Ini digunakan untuk memberitahu fungsi MA (), kita ingin mendapatkan purata bergerak harga penutupan selama berapa hari, melalui parameter, fungsi menjadi lebih fleksibel.
  - Bagaimana untuk belajar
    - 1. Pertama, anda perlu memahami fungsi fungsi, yang merupakan data fungsi ini boleh memberi kita.
    - 1. Memahami jenis nilai balik, selepas semua, kita menggunakan fungsi untuk mendapatkan nilai balik.
    - 1. Kita perlu memahami jenis data parameter, MA (x, n), jika anda tidak tahu jenis data parameter x, n, anda tidak boleh mendapatkan nilai pulangan dengan betul.
    Dalam pengenalan fungsi berikut, gunakan, ikuti tiga prinsip di atas.
- Peningkatan bahasa
  - Pengaturcaraan campuran antara bahasa M dan bahasa JavaScript
```
%%
// here you can call any API function of FMZ Quant.
scope.TEST = function(obj) {
    return obj.val * 100;
}
%% 
```
  Harga penutupan: C; Harga penutupan diperbesar 100 kali: TEST©; Harga penutupan sebelumnya diperbesar 100 kali: TEST(REF(C, 1)); // Tikus bergerak ke garis backtest K dan nilai pembolehubah dipaparkan.
```
- scope object

  scope object, you can add attributes and assign anonymous functions to attributes. An anonymous function referenced by this attributes can be called in the M language code section.

- scope.getRefs(obj) function

  In the JavaScript code block, call the scope.getRefs(obj) function, which returns the data of the incoming obj object.

 The following %%%% of the symbolic package's JavaScript code will get the incoming C closing price when the TEST(C) function is called in the M language code.
  The scope.getRefs function returns all closing prices for this K-line data. Since the throw "stop" interrupt routine is used, the variable “arr” contains only the closing price of the first Bar of k-line. You can try to delete throw "stop" and it will execute the last return of the JavaScript code, returning all the closing price data.
  ```
    %%
    scope.TEST = function(obj){
        var arr = scope.getRefs(obj)
        Log("arr:", arr)
        throw "stop"
        return
    }
    %%
    TEST(C);
  ```

- scope.bars

  In the JavaScript code block, access all K line bars.

  The TEST function returns a value, 1 is the falling k-line and 0 is the rising line.
  
  ```
    %%
    scope.TEST = function(){
        var bars = scope.bars
        return bars[bars.length - 1].Open > bars[bars.length - 1].Close ? 1 : 0    // can only return values
    }
    %%
    arr:TEST;                                                                      
  ```

  ```
    # Note:
    # TEST Received anonymous function, the return value must be a numeric value
    # If the anonymous function has no parameters, write VAR:=TEST directly when calling TEST; write VAR:=TEST(); will report an error.
    # TEST in #scope.TEST must be uppercase.
  ```

- scope.bar

  In the JavaScript code block, access the current bar.

  Calculate the average of “opening high but closing low” of k-line’s prices.

  ```
    %%
    scope.TEST = function(){
        var bar = scope.bar
        var ret = (bar.Open + bar.Close + bar.High + bar.Low) / 4
        return ret
    }
    %%
    avg^^TEST;
  ```

- scope.depth

  Access the market depth data (order book)

  ```
    %%
    scope.TEST = function(){
        Log(scope.depth)
        throw "stop"             // Throw an exception after printing the depth data, pause.
    }
    %%
    TEST;
  ```

- scope.symbol

  Get the current trading pair name string

  ```
    %%
    scope.TEST = function(){
        Log(scope.symbol)
        throw "stop"
    }
    %%
    TEST;
  ```

- scope.barPos

  Get the K line Bar location.

  ```
    %%
    scope.TEST = function(){
        Log(scope.barPos)
        throw "stop"
    }
    %%
    TEST;
  ```

- scope.get\_locals('name')

  This function is used to get the variables in the M language code part

  ```
    V:10;
    %%
    scope.TEST = function(obj){
        return scope.get_locals('V')
    }
    %%
    GET_V:TEST(C);
  ```

  ```
    # Note:
    # If a variable does not calculate data when the period is insufficient, this time the scope.get_locals function is called in the JavaScript code.
    # When get this variable, it will give an error: line:XX - undefined locals a variable name undefined
  ```
```
- Rujukan berbilang kitaran
  - Gunakan: #EXPORT Formula Nama... #END untuk membuat formula. Jika anda hanya mahu mendapatkan data untuk tempoh yang berbeza, anda juga boleh menulis formula kosong tanpa pengiraan formula.
    
    Rumus kosong ialah:
```
#EXPORT TEST 
NOP;
#END           // End
```
  - Penggunaan: #IMPORT [MIN, tempoh, nama formula] AS nilai pembolehubah, formula rujukan, mendapatkan data tempoh yang ditetapkan (harga penutupan, harga pembukaan, dan lain-lain, yang diperoleh dengan nilai pembolehubah).
    
    Contoh kod:
```
// this code demonstrates how to reference formulas of different cycles in the same code
// #EXPORT extends the syntax, ending with #END as a formula, you can declare multiple
#EXPORT TEST 
Mean 1:EMA(C, 20);
Mean 2:EMA(C, 10);
#END // End

#IMPORT [MIN,15,TEST] AS VAR15 // Reference formula, K line cycle is 15 minutes
#IMPORT [MIN,30,TEST] AS VAR30 // Reference formula, K line cycle is 30 minutes
CROSSUP(VAR15.Mean1, VAR30.Mean1),BPK;
CROSSDOWN(VAR15.Mean2, VAR30.Mean2),SPK;
The highest price of 15 mins:VAR15.HIGH;
The highest price of 30 mins:VAR30.HIGH;
AUTOFILTER;
```
- Penerangan mod
  - 1, Satu model penapisan isyarat kedudukan pembukaan dan satu kedudukan penutupan
    
    Dalam model, dengan menulis fungsi AUTOFILTER untuk mengawal dan merealisasikan penapisan isyarat satu pembukaan dan satu penutupan.
    
    Model penapisan menyokong arahan: BK, BP, BPK, SK, SP, SPK, CLOSEOUT, tidak menyokong BK (5) dan arahan lain dengan lot
    
    E.g：
```
MA1:MA(CLOSE,5);
MA2:MA(CLOSE,10);
CROSSUP(C,MA1),BK;
CROSSUP(MA1,MA2),BK;
C>BKPRICE+10||C<BKPRICE-5,SP;
AUTOFILTER;
```
  - 2, menambah atau mengurangkan model kedudukan
    
    Fungsi AUTOFILTER tidak ditulis dalam model, yang membolehkan isyarat kedudukan pembukaan berterusan atau isyarat kedudukan penutupan berterusan, yang boleh digunakan untuk meningkatkan atau mengurangkan kedudukan.
    
    Perintah yang disokong: BK(N), BP(N), SK(N), SP(N), CLOSEOUT, BPK(N), SPK(N, tidak menyokong kedudukan terbuka dan dekat tanpa lot. (1) Pengelompokan arahan sokongan. (2) Apabila beberapa syarat arahan dipenuhi pada masa yang sama, isyarat dijalankan dalam urutan di mana pernyataan syarat ditulis. Contohnya:
```
MA1:MA(CLOSE,5);
MA2:MA(CLOSE,10);
CROSSUP(C,MA1),BK(1);
CROSSUP(MA1,MA2),BK(1);
C>BKPRICE+10||C<BKPRICE-5,SP(BKVOL);
```
  - 3, satu K-garis dengan satu model isyarat
    
    Satu garis K dengan satu model isyarat boleh dibahagikan kepada model harga penutupan dan model harga arahan.
    
    1)Model harga penutupan
    
    Garis K melalui isyarat pengiraan untuk meletakkan pesanan (pengiraan juga dilakukan semasa pembentukan garis K. Pada masa ini, isyarat tidak pasti, dan isyarat yang muncul apabila garis k tidak selesai akan diabaikan, dan tiada pesanan akan diletakkan)
    
    Arah isyarat adalah konsisten dengan arah kedudukan tunggu, dan tidak ada keadaan isyarat hilang.
```
E.g：
MA1:MA(CLOSE,5);
MA2:MA(CLOSE,10);
CROSSUP(MA1,MA2),BPK;//5 cycle moving average line up cross 10 cycle moving average line to buy long.
CROSSDOWN(MA1,MA2),SPK;//5 cycle moving average line down cross 10 cycle moving average line to sell short.
AUTOFILTER;
```
    2)Model harga arahan
    
    Tidak kira sama ada garis k selesai atau tidak, isyarat dikira dan pesanan dibuat dalam masa nyata, iaitu pesanan dibuat sebelum garis K selesai;
    
    Apabila garis K berakhir, ia akan diperiksa. jika arah kedudukan tidak sepadan dengan arah isyarat di hujung garis k, kedudukan akan disegerakan secara automatik.
    
    E.g：
```
MA1:MA(CLOSE,5);
MA2:MA(CLOSE,10);
CROSSUP(MA1,MA2),BPK;//5 cycle moving average line up cross 10 cycle moving average line to buy long.
CROSSDOWN(MA1,MA2),SPK;//5 cycle moving average line down cross 10 cycle moving average line to sell short.
AUTOFILTER;
```
  - 4、Satu K-line dengan model isyarat berbilang
    
    Model ini menggunakan multsig atau multsig_min untuk mengawal dan melaksanakan beberapa isyarat dari satu K-line.
    
    Tidak kira sama ada garis k selesai, mengira isyarat dan meletakkan pesanan masa nyata.
    
    Isyarat tidak akan dikaji semula, tidak ada keadaan signal hilang, dan arah isyarat adalah konsisten dengan arah kedudukan.
    
    Pelaksanaan berulang dalam garis K jika pelbagai syarat isyarat dipenuhi
```
E.g:
MA1:MA(CLOSE,5);
MA2:MA(CLOSE,10);
CROSSUP(MA1,MA2),BK;
C>BKPRICE+10||C<BKPRICE-5,SP;
AUTOFILTER;
MULTSIG(0,0,2,0);
```
    Tambahan: 1, Menggabungkan dan mengurangkan model kedudukan, dua kaedah satu isyarat k-garis: perintah penempatan harga penutupan dan pesanan penempatan harga arahan semuanya disokong.
    
    2、Model kedudukan penjumlahan dan pengurangan,juga menyokong isyarat k-garis tunggal untuk meletakkan pesanan.
    
    Menambah dan mengurangkan model kedudukan, menulis fungsi multsig atau multsig_min, merealisasikan beberapa kali penambahan dan pengurangan kedudukan pada satu garis k, atau mengurangkan kedudukan beberapa kali.
- Paparan Carta
  - Rajah utama penunjuk tambahan
    
    Gunakan pengendali ^^ untuk menetapkan penunjuk yang akan dipaparkan pada imej utama semasa menetapkan nilai kepada pembolehubah.
```
MA60^^MA(C, 60);  // Calculate the moving average indicator with a parameter of 60
```
  - Sub-diagram penunjuk tambahan
    
    Gunakan operator : untuk menetapkan penunjuk yang akan dipaparkan pada rajah sekunder semasa menetapkan nilai kepada pembolehubah.
```
ATR:MA(MAX(MAX((HIGH-LOW),ABS(REF(CLOSE,1)-HIGH)),ABS(REF(CLOSE,1)-LOW)),26);    // Assign a value to the ATR variable, The ":" symbol is followed by the formula for calculating the ATR
```
    Jika anda tidak mahu memaparkan pada utama atau sub-diagram Gunakan operator ...
```
MA60..MA(C, 60);  // Calculate the moving average indicator with a parameter of 60
```
    Anda boleh menggunakan DOT dan COLORRED untuk menetapkan jenis baris, warna, dan lain-lain selaras dengan tabiat pengguna yang biasa dengan bahasa M.
- Masalah Umum
  
  Memperkenalkan masalah yang biasa ditemui dalam penyediaan penunjuk, biasanya perkara-perkara yang memerlukan perhatian semasa menulis penunjuk. (Dilanjutkan)
  - Perhatikan hujung ;.
  - Perhatikan bahawa kata kunci sistem tidak boleh dinyatakan sebagai pembolehubah.
  - Perhatikan bahawa rentetan menggunakan petikan tunggal, contohnya: pembukaan hanya satu petikan.
  - Komen
    
    Anotasi
    - // The content of the comment(cara input boleh diketik dalam kedua-dua bahasa Inggeris dan Cina), yang bermaksud bahawa kod tidak disusun semasa proses pelaksanaan, iaitu, ia tidak melaksanakan // kandungan di belakangnya.
    - { Comment content }Blok komen.
```
A:=MA(C,10);
{The previous line of code is the calculation of the moving average.}
```
    - (* Comment content *)Blok komen.
```
A:=MA(C,10);
(*The previous line of code is the calculation of the moving average.*)
```
  - Kaedah input
    
    Apabila menulis kod, ia sering menyebabkan ralat simbol kerana kaedah input bertukar antara Cina dan Inggeris. Jenis biasa adalah seperti berikut: colon:, terminator; koma, kurung (), dan lain-lain, watak-watak yang berbeza ini dalam bahasa Cina dan Inggeris perlu memberi perhatian.
  - Logik terdedah kepada kesilapan
    1. Sekurang-kurangnya tidak kurang daripada tidak kurang daripada: Operator hubungan yang sepadan>=
    2. Paling banyak tidak lebih: Operator hubungan yang sepadan<=

Rujukan data baris K

Terbuka

Dapatkan harga pembukaan carta K-line

Harga Pembukaan

Fungsi: OPEN,dikurangkan sebagai O

Parameter: Tiada

Penjelasan: Kembalikan harga permulaan kitaran

Data urutan

OPEN obtained the opening price of the K-line chart.

Note:
1、can be shorthand as O.

example 1：
OO:=O;           //Define OO as the opening price; pay attention to the difference between O and 0.
example 2：
NN:=BARSLAST(DATE<>REF(DATE,1));
OO:=REF(O,NN);   //Get the opening price of the day
example 3：
MA5:=MA(O,5);    //Define the 5-period moving average of the opening price (O is OPEN shorthand).

Tinggi

Dapatkan harga tertinggi carta K-line

Harga tertinggi

Fungsi:HIGH,dikurangkan sebagai H

Parameter: Tiada

Penjelasan: pulangkan harga tertinggi kitaran

Data urutan

HIGH Get the highest price of the K-line chart.

Note：
1、can be shorthand as H.

example 1：
HH:=H;         //Define HH as the highest price.
example 2：
HH:=HHV(H,5);  //Take the maximum value of the highest price within 5 cycles.
example 3：
REF(H,1);      //Take the highest price of the previous K line

rendah

Dapatkan harga terendah carta K-line

Harga Terendah

Fungsi: LOW,dikurangkan sebagai L

Parameter: Tiada

Penjelasan: Kembalikan harga terendah kitaran.

Data urutan

LOW gets the lowest price of the K-line chart.

Note：
1、can be shorthand as L.

example 1：
LL:=L;            //Define LL as the lowest price.
example 2：
LL:=LLV(L,5);     //Get the minimum value of the lowest price in 5 cycles.
example 3：
REF(L,1);         //Get the lowest price of the previous K line

TAMPAT

Dapatkan harga penutupan carta K-line

Harga Penutupan

Fungsi: CLOSE, singkatan sebagai C

Parameter: Tiada

Penjelasan: Kembalikan harga penutupan kitaran

Data urutan

CLOSE Get the closing price of the K-line chart.

Note：
1、When the k-line in the market is not finished, get the latest price.
2、Can be shorthand as C.

example 1：
A:=CLOSE;          //Define the variable A as the closing price (A is the latest price when the k line is not finished).
example 2：
MA5:=MA(C,5);      //Define the 5-period moving average of the closing price (C is short for CLOSE).
example 3：
A:=REF(C,1);       //Get the closing price of the previous k line.

VOL

Dapatkan jumlah carta garis K

Volume Dagangan

Fungsi:VOL,dikurangkan sebagai V

Parameter: Tiada

Penjelasan: Kembalikan jumlah kitaran ini.

Data urutan

VOL gets the volume of the K-line chart.

Note：
Can be shorthand as V.
The return value of this function on the root TICK is the cumulative value of all TICK transactions for the day.

example 1：
VV:=V;       //Define VV as volume
example 2：
REF(V,1);    //indicates the volume of the previous cycle
example 3：
V>=REF(V,1); //The volume is greater than the volume of the previous cycle, indicating that the volume increases (V is short for VOL).

REF

Rujukan ke hadapan

Reference the value of X before N cycles.

Note：
1、When N is a valid value, but the current number of k lines is less than N, a null value is returned;
2、When N is 0, the current X value is returned;
3、When N is null, it returns a null value.
4、N can be a variable

example 1:
REF(CLOSE,5); indicates the closing price of the 5th cycle before the current cycle
example 2：
AA:=IFELSE(BARSBK>=1,REF(C,BARSBK),C);//Take the closing price of the K line of latest buying long of the open position signal
//1) When the k-line BARSBK of the BK signal returns a null value, the k-line REF(C, BARSBK) of the BK signal is returned.
Null value；
//2）When the BK signal is sent, the k-line BARSBK returns a null value, and if the BARSBK>=1 is not satisfied, then send the closing price of the k-line.
//3）The k-line BARSBK after the BK signal is sent returns the number of cycles of the K-line of the open position from the current K-line, REF(C, BARSBK)
Returns the closing price of the opening k line.
//4）Example: 1, 2, 3 three k lines, 1 K line is the opening position signal K line, then return the closing price of this k line, 2, 3
K line returns the closing price of the 1 K line.

Unit

Ambil unit transaksi kontrak data

Take the trading unit of the data contract.
usage：
UNIT takes the trading unit of the data loading contract.

Masa Depan Komoditi

Nilai UNIT berkaitan dengan kontrak

rb contract - 1 hand, 10 (tons)

Cryptocurrency Spot

Nilai UNIT ialah 1

Masa hadapan mata wang kripto Nilai UNIT berkaitan dengan mata wang kontrak

OKEX Futures: 1 BTC contract represents $100, and 1 contract in other currencies represents $10

MINPRICE

Perubahan harga minimum untuk kontrak data

Take the minimum price change of the data contract.
usage:
MINPRICE; Take the minimum price change for loading data contracts.

MINPRICE1

Perubahan minimum dalam kontrak perdagangan

Take the minimum price change of the trading contract.
usage：
MINPRICE1; Take the minimum price change of the trading contract.

Fungsi Masa

BARPOS

Take the position of the K line

BARPOS，returns the number of cycles from the first K line to the current cycle.

Note：
1、BARPOS returns the number of existing K lines in the local area, starting from the data existing on the local machine.
2、The return value of the first K line already on the local machine is 1.

example 1：LLV(L,BARPOS);//Find the minimum value of the local existing data.

example 2：IFELSE(BARPOS=1,H,0);//The current K line is the highest value of the first K line already in the local machine, otherwise it is 0.

Tempoh

Nilai tempoh adalah bilangan minit.
```
1, 3, 5, 15, 30, 60, 1440
```
Tarikh

Tarikh

Fungsi:TANGGAL

Parameter: Tiada

Penjelasan: Dapatkan tarikh kitaran dari 1900

Data urutan

Masa

Ambil masa garis K

TIME，take the K line time.

Note：
1、The function returns in real time on the real-market, and returns the start time of the K line after the K line is finished.
2、The function returns the exchange data reception time, which is the exchange time.
3、The TIME function returns a six-digit form when used in the second period, ie: HHMMSS, which is displayed in four-digit form on other periods, namely: HHMM.
4、The TIME function can only be loaded in the period below the daily period. The return value of the function is always 1500 in the period above the daily period (Included the daily period).
5、use the TIME function to close the position of the tail operation needs attention
（1） The time set by the end of the closing position is recommended to be set to the actual time that can be taken in the K line return value (eg, the RB index is 5 minutes, the last K line return time is 1455, and the tail closing position is set to TIME> =1458, CLOSEOUT; the signal that the tail is closed can not appear in the effect test)
（2）	Using the TIME function as the condition for closing the position at the end of the market, it is recommended to open position condition also to make the corresponding time limit (such as setting the closing condition of the tail to TIME>=1458, CLOSEOUT; then the corresponding opening conditions are required Add condition TIME<1458; avoid opening the position again after closing the position)

example 1:
C>O&&TIME<1450,BK;
C<O&&TIME<1450,SK;
TIME>=1450,SP;
TIME>=1450,BP;
AUTOFILTER;
//Close the position after 14:50.
example 2：
ISLASTSK=0&&C>O&&TIME>=0915,SK;

Tahun

YEAR，the year is obtained.

Note：
YEAR ranges from 1970—2033。

example 1：
N:=BARSLAST(YEAR<>REF(YEAR,1))+1;
HH:=REF(HHV(H,N),N);
LL:=REF(LLV(L,N),N);
OO:=REF(VALUEWHEN(N=1,O),N);
CC:=REF(C,N);//take the highest price, the lowest price, the opening price, and the closing price of the previous year.
example 2：
NN:=IFELSE(YEAR>=2000 AND MONTH>=1,0,1);

Bulan

Mengembalikan bulan kitaran

MONTH, returns the month of a cycle.

Note：
MONTH has a value range of 1-12.

example 1：
VALUEWHEN(MONTH=3&&DAY=1,C);//The closing price is taken when the K-line date is March 1.
example 2：
C>=VALUEWHEN(MONTH<REF(MONTH,1),O),SP;

Hari

Dapatkan bilangan hari dalam kitaran

DAY, returns the number of days in a cycle.

Note：
The DAY value ranges from 1-31.

example 1：
DAY=3&&TIME=0915，BK;//From the date of 3 days, the time is 9:15, buy long.
example 2：
N:=BARSLAST(DATE<>REF(DATE,1))+1;
CC:=IFELSE(DAY=1,VALUEWHEN(N=1,O),0);//When the date is 1, the opening price is taken, otherwise the value is 0.

JAM

HOUR，Returns the number of hours in a cycle.

Note：
HOUR ranges from 0 to 23

example 1：
NX:=BARSLAST(CROSS(HOUR=9,0.5));
DRAWLINE3(CROSSDOWN(HOUR=14,0.5),REF(H,NX),NX,CROSSDOWN(HOUR=14,0.5),REF(H,1),1,0),COLORGREEN;
//Connect 9:00 to the latest k-line high point before the market close.
example 2：
HOUR=10;//The return value is 1 on the K line at 10:00, and the return value on the remaining K lines is 0.

minit

MINUTE, Returns the number of minutes in a cycle.

Note：
1：MINUTE has a value range of 0-59
2：This function can only be loaded on the minute period, returning the number of minutes since the current K line.
example 1：
MINUTE=0；//The return value on the minute K line at the beginning of an hour is 1, and the remaining K lines return a value of 0.
example 2：
TIME>1400&&MINUTE=50,SP;//close position at 14:50.

Hari minggu

Dapatkan bilangan minggu

WEEKDAY, get the number of weeks.

Note：
1：WEEKDAY has a value range of 0-6.
2：The value displayed by the function on the weekly cycle is always 5, and the number of weeks on the day of the end of the K line is returned on the monthly cycle.

example 1：
N:=BARSLAST(MONTH<>REF(MONTH,1))+1;
COUNT(WEEKDAY=5,N)=3&&TIME>=1450,BP;
COUNT(WEEKDAY=5,N)=3&&TIME>=1450,SP;
AUTOFILTER;//each month delivery date is automatically closed all position at the end of that day.
example 2：
C>VALUEWHEN(WEEKDAY<REF(WEEKDAY,1),O)+10,BK;
AUTOFILTER;

Fungsi Penghakiman Logik

BARSTATUS

Mengembalikan status kedudukan kitaran semasa

BARSTATUS returns the position status of the current cycle.

Note：
The function returns 1 to indicate that the current cycle is the first cycle, return 2 to indicate the last cycle, and return 0 to indicate that the current cycle is in the middle position.

example:
A:=IFELSE(BARSTATUS=1,H,0); //If the current K line is the first cycle, the variable A returns the highest value of the K line, otherwise it takes 0.

Antara

BETWEEN(X,Y,Z) indicates whether X is between Y and Z, and returns 1 (Yes), otherwise returns 0 (No).

Note：
1、If X=Y, X=Z, or X=Y and Y=Z, the function returns a value of 1 (Yse).

example 1：
BETWEEN(CLOSE,MA5,MA10); //indicates that the closing price is between the 5-day moving average and the 10-day moving average.

Silang

Fungsi silang

CROSS(A,B) means that A passes B from the bottom to up, and returns 1 (Yes), otherwise it returns 0 (No).

Note：
1、The conditions for crossing must satisfy A<=B of pervious k line, and it is confirmed as crossing when the current k-line satisfies A>B.

example 1：
CROSS(CLOSE,MA(CLOSE,5)); //means the crossing line from below through the 5-period moving average

Perpindahan

Memintas ke bawah

CROSSDOWN(A,B)：indicates that when A down crossing B from above, it returns 1 (Yes), otherwise it returns 0 (No).

Note：
1、CROSSDOWN (A, B) is equivalent to CROSS (B, A), CROSSDOWN (A, B) is written to better understand

example 1：
MA5:=MA(C,5);
MA10:=MA(C,10);
CROSSDOWN(MA5,MA10),SK; //MA5 down cross MA10, sell short
//CROSSDOWN(MA5,MA10),SK; and CROSSDOWN(MA5,MA10)=1, SK; express the same meaning

CROSSUP

Melalui

CROSSUP(A,B) When A passes up from bottom to B, it returns 1 (Yes), otherwise it returns 0 (No)

Note：
1、CROSSUP (A, B) is equivalent to CROSS (A, B), CROSSUP (A, B) is written to better understand.

example 1：
MA5:=MA(C,5);
MA10:=MA(C,10);
CROSSUP(MA5,MA10),BK;//MA5 cross up MA10, buy long.
//CROSSUP(MA5,MA10),BK; and CROSSUP(MA5,MA10)=1, BK; express the same meaning

Semua

Menentukan sama ada ia masih memenuhi keperluan

EVERY(COND,N)，judge whether the COND condition is always satisfied in the N period. If it is, the function returns a value of 1; if it is not, the function returns a value of 0;

Note：
1、N contains the current k line.
2、If N is a valid value, but there are not many K lines in front of it, or N is a null value, the condition is not satisfied, and the function returns 0.
3、N can be a variable

example 1：
EVERY(CLOSE>OPEN,5);//indicates that it has been a positive line for 5 cycles.
example 2：
MA5:=MA(C,5);//Define a 5-cycle moving average
MA10:=MA(C,10);//Define the 10-cycle moving average
EVERY(MA5>MA10,4),BK;//MA5 is greater than MA10 in 4 cycles, then buy long.
//EVERY(MA5>MA10,4),BK; and EVERY(MA5>MA10,4)=1, BK; express the same meaning

wujud

Tentukan sama ada terdapat kepuasan

EXIST(COND,N) determines whether there are conditions for satisfying COND in N cycles

Note:
1、N contains the current k line.
2、N can be a variable.
3、If N is a valid value, but there are not many K lines in front of it, calculate according to the actual number of cycles.

example 1：
EXIST(CLOSE>REF(HIGH,1),10);indicates whether there is a maximum price in the 10 cycles that is greater than the previous period, if it exist, return 1, and if it does not exist, returns 0.
example 2：
N:=BARSLAST(DATE<>REF(DATE,1))+1;
EXIST(C>MA(C,5),N);//Indicates whether there is a k line that meets the closing price greater than the 5-period moving average. If it exist, return 1, and if it does not exist, return 0.

Jika

Fungsi bersyarat

IF(COND,A,B) Returns A if the COND condition is true, otherwise returns B

Note：
1、COND is a judgment condition; A and B can be conditions or numerical values.
2、the function supports the variable loop to reference the previous period of its own variable, that is, support the following writing method Y: IF (CON, X, REF (Y, 1));
example 1：
IF(ISUP,H,L);// k line is the rising line, take the highest price, otherwise take the lowest price
example 2：
A:=IF(MA5>MA10,CROSS(DIFF,DEA),IF(CROSS(D,K),2,0));//When MA5>MA10, take whether DIFF is cross up the DEA, otherwise (MA5 Not greater than MA10), when K, D is down crossing, let A be assigned a value of 2. If the above conditions are not met, A is assigned a value of 0.
A=1,BPK;//When MA5>MA10, use DIFF cross up DEA as the buying long condition
A=2,SPK;//When MA5 is not greater than MA10, K D down crossing are used as selling short conditions

IFELSE

Fungsi bersyarat

IFELSE(COND,A,B) Returns A if the COND condition is true, otherwise returns B

Note：
1、COND is a judgment condition; A and B can be conditions or numerical values.
2、the function supports the variable loop to refer to the previous period of its own variable, that is, supports the following writing method Y: IFELSE (CON, X, REF (Y, 1));
example 1：
IFELSE(ISUP,H,L);//k line is the rising line, take the highest price, otherwise take the lowest price
example 2：
A:=IFELSE(MA5>MA10,CROSS(DIFF,DEA),IFELSE(CROSS(D,K),2,0)); //When MA5>MA10, whether DIFF up cross DEA, otherwise (MA5 Not greater than MA10), when K, D down cross, let A be assigned a value of 2. If the above conditions are not met, A is assigned a value of 0.
A=1,BPK;//When MA5>MA10, use DIFF up cross DEA as the buying long condition
A=2,SPK;//When MA5 is not greater than MA10, K, D down cross are used as selling short conditions

Kontrak

cuaca kontrak yang kini kontrak yang ditetapkan

weather ISCONTRACT(CODE) is currently the specified contract.

Usage：ISCONTRACT(CODE); is the current contract returns 1, not the current contract returns 0.

Note：
1、When judging whether it is a specified contract, CODE can be the transaction code of the contract.

example:
ISCONTRACT('MA888');
ISCONTRACT('rb1901');
ISCONTRACT('this_week');    // cryptocurrency OKEX Futures Contract
ISCONTRACT('XBTUSD');       // cryptocurrency BITMEX Futures Contract

Sokongan untuk ungkapan biasa

Menentukan kontrak

ISCONTRACT('this_week');                     // Determine if the current contract is OKEX futures this_week (week) contract

Menghakimi nama bursa

ISCONTRACT('@Futures_(CTP|BitMEX)');         // Determine whether the current exchange object is a commodity futures or a cryptocurrency BITMEX futures exchange
ISCONTRACT('@(OKEX|Bitfinex|Futures_CTP)');  // To determine the exchange, you need to add @ character at the beginning

Ke bawah

Garis K jatuh

ISDOWN determines whether the cycle is falling

Note：
1、ISDOWN is equivalent to C<O

example：
ISDOWN=1&&C<REF(C,1),SK;//When the current k line is finished and the closing price is lower than the closing price of the previous period, then selling short
//ISDOWN=1&&C<REF(C,1),SK; is equivalent to ISDOWN&&C<REF(C,1),SK;

ISEQUAL

Harga pembukaan sama dengan harga penutupan

ISEQUAL determines if the cycle is "The opening price equal to closing price"

Note：
1、ISEQUAL is equivalent to C=O

example 1：
EVERY(ISEQUAL=1,2),CLOSEOUT; //continue for 2 k lines are “The opening price equal to closing price

, kemudian tutup semua kedudukan.

```

ISLASTBAR

Tentukan sama ada kitaran adalah K garis terakhir

ISLASTBAR determines if the cycle is the last k line

example 1：
VALUEWHEN(ISLASTBAR=1,REF(H,1));//The current k-line is the last k-line, taking the highest price of the previous cycle.

ISNULL

Tentukan sifar

ISNULL determine whether it is null or not

Usage：ISNULL(N);if N is null, the function returns 1; if N is non-null, the function returns 0.

Example: MA5:=IFELSE(ISNULL(MA(C,5))=1, C,MA(C,5));//Define a five-period moving average. When the number of K-lines is less than five, return the current K-line closing price.

ISUP

Garis menaik

ISUP determines whether the cycle is rising

Note：
1、ISUP is equivalent to C>O

example：
ISUP=1&&C>REF(C,1),BK;   //If the current k line is a rising k line and the closing price is greater than the closing price of the previous period, then buying long.
                         //ISUP=1&&C>REF(C,1),BK; and ISUP&&C>REF(C,1),BK;
                         //Express the same meaning

Terakhir

Tentukan Fungsi

LAST(COND,N1,N2) Determines whether the COND condition has been met for the past N1 to N2 cycles.

Note：
1、If N1 and N2 differ by only one cycle (eg, N1=3, N2=2), the function judges whether the condition is satisfied on the cycle closest to the current K line (ie, whether the K line in the past N2 cycles is meeting the conditions)
2、When N1/N2 is a valid value, but the current k-line number is less than N1/N2, or N1/N2 null, means is not true, and the function returns 0.
3、N1 and N2 cannot be variables.

example 1：
LAST(CLOSE>OPEN,10,5); // indicates that it has been a rising line from the 10th cycle to the 5th cycle in the past.
example 2：
MA5:=MA(C,5);
LAST(C>MA5,4,3);//determine whether the K line from the current k-line 3 cycles satisfies “C greater than MA5”.

LONGCROCE

Mempertahankan Fungsi Salib

LONGCROSS(A,B,N) indicates that A is less than B in N cycles, and this cycle A up cross B from bottom to top.

Note：
1、When N is a valid value, but the current k-line number is less than N, the LONGCROSS function returns a null value.
2、N does not support variables.

example 1：
LONGCROSS(CLOSE,MA(CLOSE,10),20); //indicates that the closing price continues below the 10-day moving average for 20 cycles and then up cross the 10-day moving average from bottom to top.

Tidak

bukan-

NOT(X)：Take a non. Returns 1 when X=0, otherwise returns 0.
example 1：
NOT(ISLASTBK); If the previous signal is not a BK signal, the NOT (ISLASTBK) returns a value of 1; the previous signal is a BK signal, and the NOT (ISLASTBK) returns a value of 0.
example 2：
NOT(BARSBK>=1)=1;//The BK signal is sent to the current K line to satisfy the condition.
//NOT(BARSBK>=1)=1 is equivalent to NOT (BARSBK>=1).

NULL

Kembalikan null

Return null
usage：
MA5:=MA(C,5);
MA10:=MA(C,10);
A:=IFELSE(MA5>MA10,MA5,NULL),COLORRED;//When MA5>MA10, draw the five-day moving average MA5, when MA5>MA10 is not satisfied, return null value, no drawing line.

Nilai apabila

Nilai

VALUEWHEN(COND,X) Takes the current value of X when the COND condition is true. If the COND condition is not true, take the value of X when the COND condition is established last time.

Note：
X can be either a numerical value or a condition.

example 1
VALUEWHEN(HIGH>REF(HHV(HIGH,5),1),HIGH);indicates that the current highest price is greater than the maximum value of the highest price of the first five cycles and returns the current highest price.
example 2：
VALUEWHEN(DATE<>REF(DATE,1),O);indicates the opening price of the first k-line of the day
example 3：
VALUEWHEN(DATE<>REF(DATE,1),L>REF(H,1));//indicates whether the current lowest price on the first k line of the day is greater than the highest price of the last K line yesterday. Returns 1, indicating that there is a price gap on that day. Returns 0, indicating that there are no price gap on that day.

Fungsi pelaksanaan gelung

LOOP2

Fungsi keadaan gelung

LOOP2(COND,A,B); loop condition function Returns A if the COND condition is true, otherwise returns B

Note：
1、COND is a judgment condition; A and B can be conditions or numerical values.
2、the function supports variable loop reference to the previous period of its own variable, that is, support the following writing method Y: = LOOP2 (CON, X, REF (Y, 1));

example 1：
X:=LOOP2(ISUP,H,REF(X,1));//k line is the rising line, take the highest price of the current K line, otherwise take the highest price of the pervious K line that is a rising k line; if it has not appeared before, X returns null

example 2:
BB:=LOOP2(BARSBK=1,LOOP2(L>LV(L,4),L,LV(L,4)),LOOP2(L>REF(BB,1),L,REF(BB,1)));//When holding long position, the lowest price in the first 4 cycles of opening position k line is the starting stop loss point BB, if the lowest price of the subsequent K line is higher than the previous lowest price, taking the current lowest price as stop loss point, otherwise take the previous lowest point to be the stop loss point.
SS:=LOOP2(BARSSK=1,LOOP2(H<HV(H,4),H,HV(H,4)),LOOP2(H<REF(SS,1),H,REF(SS,1)));// When holding short position, the highest price in the first 4 cycles of opening position k line is the starting stop loss point SS, if the highest price is lower than the previous highest price, taking the current highest price as stop loss point, Otherwise take the previous high point as stop lose points
H>HV(H,20),BK;
L<LV(L,20),SK;
C<BB,SP;
C>SS,BP;
AUTOFILTER;

Fungsi Statistik Kewangan

BARSCOUNT

Bilangan kitaran yang pertama tempoh yang sah untuk yang semasa

BARSCOUNT(COND) The number of cycles that the first valid period to the current one

Note：
1、The return value is the number of cycles from which the COND is calculated from the first valid period and up to now.
2、The return value of BARSCOUNT(COND) on the current k line on the condition that the condition is first established is 0.

example：
BARSCOUNT(MA(C,4));//The calculation MA(C,4) has the first return value to the current number of cycles.

BARSLAST

Syarat terakhir yang disahkan benar

BARSLAST(COND)：The last condition COND was established to the current number of cycles

Note：
1、The return value of BARSLAST(COND) on the current k line is 0.

example 1：
BARSLAST(OPEN>CLOSE); //The number of cycles from the previous falling k line to the present
Example 2：
N:=BARSLAST(DATE<>REF(DATE,1))+1;//minute period, the number of k line on the current day.
//Because the condition is established, the return value of BARSLAST(COND) on the current k line is 0, so "+1" is the k-line number of current day.

BARSSINCE

Keadaan pertama ditetapkan kepada bilangan kitaran semasa

BARSSINCE(COND) The first condition is established to the current number of cycles.

Note：
1、the return value is the first time the COND is established to the current number of cycles
2、The return value of BARSSINCE (COND) on the current k-line of the condition established for the first time is 0.

example ：
BARSSINCE(CLOSE>OPEN);
//Statistics of the number of cycles from the K line that satisfies the condition of the first line to the present.

BARSSINCEN

Statistik Syarat pertama dalam tempoh N ialah menetapkan

Halaman seterusnya

Lebih lanjut

2019 FMZ - Semua hak dilindungi

Dokumen MyLanguage

Penerangan asas

Kontrak

Variabel

Peraturan penamaan

Jenis data

Pengendali

Pengendali Tugas

Operator hubungan

Operator Logik

Operator aritmetik

Fungsi

Fungsi

Nilai pulangan

Parameter

Bagaimana untuk belajar

Peningkatan bahasa

Rujukan berbilang kitaran

Penerangan mod

1, Satu model penapisan isyarat kedudukan pembukaan dan satu kedudukan penutupan

2, menambah atau mengurangkan model kedudukan

3, satu K-garis dengan satu model isyarat

4、Satu K-line dengan model isyarat berbilang

Paparan Carta

Rajah utama penunjuk tambahan

Sub-diagram penunjuk tambahan

Masalah Umum

Komen

Kaedah input

Logik terdedah kepada kesilapan

Rujukan data baris K

Terbuka

Tinggi

rendah

TAMPAT

VOL

REF

Unit

MINPRICE

MINPRICE1

Fungsi Masa

BARPOS

Tempoh

Tarikh

Masa

Tahun

Bulan

Hari

JAM

minit

Hari minggu

Fungsi Penghakiman Logik

BARSTATUS

Antara

Silang

Perpindahan

CROSSUP

Semua

wujud

Jika

IFELSE

Kontrak

Ke bawah

ISEQUAL

ISLASTBAR

ISNULL

ISUP

Terakhir

LONGCROCE

Tidak

NULL

Nilai apabila

Fungsi pelaksanaan gelung

LOOP2

Fungsi Statistik Kewangan

BARSCOUNT

BARSLAST

BARSSINCE

BARSSINCEN