Sumber dimuat naik... memuat...

Strategi Perdagangan Grid Pintar Beradaptasi

Penulis:ChaoZhang, Tarikh: 2024-01-16 14:51:48
Tag:

Ringkasan

Strategi ini adalah strategi perdagangan grid pintar adaptif berdasarkan platform TradingView, yang ditulis dalam Pine Script v4.

Logika Strategi

Ciri Utama

Piramida dan Pengurusan Wang:
- Membolehkan sehingga 14 penambahan dalam arah yang sama (piramid),
- Menggunakan strategi berasaskan tunai untuk menguruskan saiz kedudukan,
- Modal permulaan ditetapkan pada 100 USD untuk tujuan simulasi,
- Satu komisen kecil sebanyak 0.1% dikenakan untuk setiap perdagangan.
Batas Grid:
- Pengguna boleh memilih untuk menggunakan sempadan yang dikira secara automatik atau menetapkan sempadan atas dan bawah grid secara manual,
- Batas automatik boleh diperolehi dari harga High & Low baru-baru ini atau dari Purata Bergerak Sederhana (SMA),
- Pengguna boleh mentakrifkan tempoh melihat kembali untuk pengiraan had dan menyesuaikan penyimpangan untuk memperluaskan atau menyempitkan had.
Garis Grid:
- Strategi ini membolehkan bilangan garis grid yang boleh disesuaikan dalam had, dengan julat yang disyorkan antara 3 dan 15,
- Garis-garis grid adalah sama rata antara batas atas dan bawah.

Logika Strategi

Masukan:
- Skrin meletakkan pesanan beli apabila harga jatuh di bawah garis grid dan tiada pesanan sedia ada dikaitkan dengan garis grid itu.
- Setiap kuantiti pesanan pembelian dikira berdasarkan modal awal dibahagikan dengan bilangan garis grid, disesuaikan dengan harga semasa.
Keluar:
- Perintah jual diaktifkan apabila harga meningkat di atas garis grid, dengan syarat terdapat pesanan terbuka yang sepadan dengan garis grid bawah seterusnya.
Grid penyesuaian:
- Jika ditetapkan kepada had automatik, grid menyesuaikan diri dengan perubahan keadaan pasaran dengan mengira semula had atas dan bawah dan menyesuaikan grid dengan sewajarnya.

Analisis Kelebihan

Strategi ini mengintegrasikan sifat sistematik dan pelaksanaan perdagangan grid yang cekap. Membolehkan piramid dan menggunakan pengurusan wang dapat mengawal risiko dengan berkesan. Grid yang menyesuaikan diri secara automatik sesuai dengan keadaan pasaran yang berbeza. Parameter yang boleh disesuaikan memenuhi gaya perdagangan yang berbeza.

Analisis Risiko

Penembusan harga di luar batas grid boleh menyebabkan kerugian yang teruk. Parameter harus diselaraskan dengan betul atau digabungkan dengan kerugian berhenti untuk mengawal risiko. Juga, perdagangan berlebihan meningkatkan kos transaksi.

Arahan pengoptimuman

Pertimbangkan untuk menggabungkan dengan penapis trend atau mengoptimumkan parameter grid.

Kesimpulan

Strategi ini secara sistematik menjana entri dan keluar semasa menguruskan kedudukan. Melalui penyesuaian parameter ia menyesuaikan diri dengan pilihan yang berbeza. Ia menggabungkan sifat berasaskan peraturan perdagangan grid dengan fleksibiliti perdagangan trend, memudahkan kerumitan operasi sambil mengekalkan ketahanan.

/*backtest
start: 2024-01-08 00:00:00
end: 2024-01-15 00:00:00
period: 5m
basePeriod: 1m
exchanges: [{"eid":"Futures_Binance","currency":"BTC_USDT"}]
*/

//@version=4
strategy("(IK) Grid Script", overlay=true, pyramiding=14, close_entries_rule="ANY", default_qty_type=strategy.cash, initial_capital=100.0, currency="USD", commission_type=strategy.commission.percent, commission_value=0.1)
i_autoBounds    = input(group="Grid Bounds", title="Use Auto Bounds?", defval=true, type=input.bool)                             // calculate upper and lower bound of the grid automatically? This will theorhetically be less profitable, but will certainly require less attention
i_boundSrc      = input(group="Grid Bounds", title="(Auto) Bound Source", defval="Hi & Low", options=["Hi & Low", "Average"])     // should bounds of the auto grid be calculated from recent High & Low, or from a Simple Moving Average
i_boundLookback = input(group="Grid Bounds", title="(Auto) Bound Lookback", defval=250, type=input.integer, maxval=500, minval=0) // when calculating auto grid bounds, how far back should we look for a High & Low, or what should the length be of our sma
i_boundDev      = input(group="Grid Bounds", title="(Auto) Bound Deviation", defval=0.10, type=input.float, maxval=1, minval=-1)  // if sourcing auto bounds from High & Low, this percentage will (positive) widen or (negative) narrow the bound limits. If sourcing from Average, this is the deviation (up and down) from the sma, and CANNOT be negative.
i_upperBound    = input(group="Grid Bounds", title="(Manual) Upper Boundry", defval=0.285, type=input.float)                      // for manual grid bounds only. The upperbound price of your grid
i_lowerBound    = input(group="Grid Bounds", title="(Manual) Lower Boundry", defval=0.225, type=input.float)                      // for manual grid bounds only. The lowerbound price of your grid.
i_gridQty       = input(group="Grid Lines",  title="Grid Line Quantity", defval=8, maxval=15, minval=3, type=input.integer)       // how many grid lines are in your grid

f_getGridBounds(_bs, _bl, _bd, _up) =>
    if _bs == "Hi & Low"
        _up ? highest(close, _bl) * (1 + _bd) : lowest(close, _bl)  * (1 - _bd)
    else
        avg = sma(close, _bl)
        _up ? avg * (1 + _bd) : avg * (1 - _bd)

f_buildGrid(_lb, _gw, _gq) =>
    gridArr = array.new_float(0)
    for i=0 to _gq-1
        array.push(gridArr, _lb+(_gw*i))
    gridArr

f_getNearGridLines(_gridArr, _price) =>
    arr = array.new_int(3)
    for i = 0 to array.size(_gridArr)-1
        if array.get(_gridArr, i) > _price
            array.set(arr, 0, i == array.size(_gridArr)-1 ? i : i+1)
            array.set(arr, 1, i == 0 ? i : i-1)
            break
    arr

var upperBound      = i_autoBounds ? f_getGridBounds(i_boundSrc, i_boundLookback, i_boundDev, true) : i_upperBound  // upperbound of our grid
var lowerBound      = i_autoBounds ? f_getGridBounds(i_boundSrc, i_boundLookback, i_boundDev, false) : i_lowerBound // lowerbound of our grid
var gridWidth       = (upperBound - lowerBound)/(i_gridQty-1)                                                       // space between lines in our grid
var gridLineArr     = f_buildGrid(lowerBound, gridWidth, i_gridQty)                                                 // an array of prices that correspond to our grid lines
var orderArr        = array.new_bool(i_gridQty, false)                                                              // a boolean array that indicates if there is an open order corresponding to each grid line

var closeLineArr    = f_getNearGridLines(gridLineArr, close)                                                        // for plotting purposes - an array of 2 indices that correspond to grid lines near price
var nearTopGridLine = array.get(closeLineArr, 0)                                                                    // for plotting purposes - the index (in our grid line array) of the closest grid line above current price
var nearBotGridLine = array.get(closeLineArr, 1)                                                                    // for plotting purposes - the index (in our grid line array) of the closest grid line below current price
strategy.initial_capital = 50000
for i = 0 to (array.size(gridLineArr) - 1)
    if close < array.get(gridLineArr, i) and not array.get(orderArr, i) and i < (array.size(gridLineArr) - 1)
        buyId = i
        array.set(orderArr, buyId, true)
        strategy.entry(id=tostring(buyId), long=true, qty=(strategy.initial_capital/(i_gridQty-1))/close, comment="#"+tostring(buyId))
    if close > array.get(gridLineArr, i) and i != 0
        if array.get(orderArr, i-1)
            sellId = i-1
            array.set(orderArr, sellId, false)
            strategy.close(id=tostring(sellId), comment="#"+tostring(sellId))

if i_autoBounds
    upperBound  := f_getGridBounds(i_boundSrc, i_boundLookback, i_boundDev, true)
    lowerBound  := f_getGridBounds(i_boundSrc, i_boundLookback, i_boundDev, false)
    gridWidth   := (upperBound - lowerBound)/(i_gridQty-1)
    gridLineArr := f_buildGrid(lowerBound, gridWidth, i_gridQty)

closeLineArr    := f_getNearGridLines(gridLineArr, close)
nearTopGridLine := array.get(closeLineArr, 0)
nearBotGridLine := array.get(closeLineArr, 1)

Lebih lanjut

2019 FMZ - Semua hak dilindungi