Sumber dimuat naik... memuat...
  1. Persegi
  2. RSI dan strategi persilangan stochastic

RSI dan strategi persilangan stochastic

Penulis:ChaoZhang
Tag:RSISTOCHSMAEMAWMASMMA

img

Ringkasan

Prinsip Strategi

  1. Analisis RSI:

    • Set membeli (37) dan menjual (49) ambang.
    • RSI meningkat dan di bawah ambang beli dianggap sebagai salah satu isyarat bullish.
    • RSI jatuh dan melebihi ambang jual dianggap sebagai salah satu isyarat penurunan.

  2. RSI yang dihaluskan:

    • Menggunakan purata bergerak kepada RSI, dengan pilihan untuk SMA, EMA, WMA, SMMA, atau VMMA.

  3. Analisis Osilator Stochastic:

    • Menggunakan tetapan Stochastic standard (14,3,3).
    • Set overbought (80) dan oversold (20) ambang.

    • Isyarat Jual: RSI jatuh dan di atas ambang jual, Stochastic %K di atas garisan overbought dengan silang kematian, RSI melintasi di bawah RSI yang dihaluskan dan di atas garisan jual RSI + MA.

Kelebihan Strategi

  1. Penggabungan Multi-Indikator: Dengan menggabungkan RSI, Stochastic, dan Moving Averages, strategi dapat menganalisis momentum pasaran dari pelbagai sudut, mengurangkan isyarat palsu.

  2. Kebolehsesuaian Dinamik: Menggunakan isyarat silang dari RSI dan Stochastic membolehkan penyesuaian yang lebih baik kepada persekitaran pasaran yang berbeza.

  4. Fleksibiliti: Strategi ini membolehkan pengguna menyesuaikan pelbagai parameter, seperti panjang RSI dan ambang beli / jual, yang boleh diselaraskan mengikut pasaran yang berbeza dan pilihan peribadi.

  5. Maklumat Balik Visual: Strategi ini menyediakan fungsi carta yang kaya, membantu peniaga memahami keadaan pasaran dan proses penjanaan isyarat secara intuitif.

Risiko Strategi

  1. Overtrading: pelbagai keadaan boleh membawa kepada penjanaan isyarat yang kerap, meningkatkan kos dagangan.

  3. Sensitiviti Parameter: Strategi bergantung pada pelbagai parameter yang boleh diselaraskan; tetapan parameter yang tidak betul boleh menyebabkan prestasi strategi yang buruk.

  4. Kebergantungan Lingkungan Pasaran: Di pasaran dengan trend yang tidak jelas atau keadaan yang terhad kepada julat, strategi boleh menghasilkan banyak isyarat palsu.

Arahan Pengoptimuman Strategi

  1. Penyesuaian Parameter Dinamik: Memperkenalkan mekanisme penyesuaian untuk menyesuaikan parameter RSI dan Stochastic secara automatik berdasarkan turun naik pasaran.

  3. Memperkenalkan Analisis Volume: Mengintegrasikan penunjuk jumlah ke dalam proses membuat keputusan untuk meningkatkan kebolehpercayaan isyarat.

  4. Mengoptimumkan Strategi Keluar: Membangunkan mekanisme mengambil keuntungan dan menghentikan kerugian yang lebih halus, seperti menggunakan hentian penghujung atau hentian dinamik berasaskan ATR.

  5. Penyelarasan Kerangka Masa: Semak isyarat merentasi pelbagai kerangka masa untuk mengurangkan isyarat palsu dan meningkatkan ketepatan.

  6. Integrasi Pembelajaran Mesin: Gunakan algoritma pembelajaran mesin untuk mengoptimumkan pemilihan parameter dan proses penjanaan isyarat.

Kesimpulan

/*backtest
start: 2024-05-21 00:00:00
end: 2024-06-20 00:00:00
period: 2h
basePeriod: 15m
exchanges: [{"eid":"Futures_Binance","currency":"BTC_USDT"}]
*/

//@version=5
strategy("-VrilyaSS-RSI&SToch-Cross+2xRSI+2xStoch-Lines+RSI-SMA-Cross-V4-", overlay=true)

// RSI settings
rsiLength = input.int(14, title="RSI Length")
rsiSource = input.source(ohlc4, title="RSI Source")
rsiBuyLine = input.int(37, title="RSI Buy Line", minval=0, maxval=100)
rsiSellLine = input.int(49, title="RSI Sell Line", minval=0, maxval=100)
rsi = ta.rsi(rsiSource, rsiLength)

// Smoothed RSI (Gleitender Durchschnitt von RSI)
smaLength = input.int(14, title="MA Length for RSI")
smaSource = input.source(ohlc4, title="MA Source for RSI")
maTypeRSI = input.string(title="MA Type for RSI", defval="SMA", options=["SMA", "EMA", "WMA", "SMMA (RMA)", "VMMA"])
f_get_ma_rsi(source, length, type) =>
    switch type
        "SMA" => ta.sma(source, length)
        "EMA" => ta.ema(source, length)
        "WMA" => ta.wma(source, length)
        "SMMA (RMA)" => ta.rma(source, length) // Smoothed Moving Average (Simple Moving Average)
        "VMMA" => ta.vwma(source, length) // Volume Weighted Moving Average (VMMA)
smoothedRsi = f_get_ma_rsi(ta.rsi(smaSource, rsiLength), smaLength, maTypeRSI)
rsiSmaBuyLine = input.int(40, title="RSI + MA Buy Line", minval=0, maxval=100)
rsiSmaSellLine = input.int(60, title="RSI + MA Sell Line", minval=0, maxval=100)

// Stochastic settings
kLength = input.int(14, title="Stochastic K Length")
kSmoothing = input.int(3, title="Stochastic K Smoothing")
dSmoothing = input.int(3, title="Stochastic D Smoothing")
stochBuyLine = input.int(20, title="Stochastic Buy Line", minval=0, maxval=100)
stochSellLine = input.int(80, title="Stochastic Sell Line", minval=0, maxval=100)
stochK = ta.sma(ta.stoch(close, high, low, kLength), kSmoothing)
stochD = ta.sma(stochK, dSmoothing)

// Stochastic Crosses
bullishCross = ta.crossover(stochK, stochD)
bearishCross = ta.crossunder(stochK, stochD)

// RSI Direction and Crosses
rsiUp = ta.change(rsi) > 0
rsiDown = ta.change(rsi) < 0
rsiCrossAboveSMA = ta.crossover(rsi, smoothedRsi) and rsi < rsiSmaBuyLine
rsiCrossBelowSMA = ta.crossunder(rsi, smoothedRsi) and rsi > rsiSmaSellLine

// Buy Signal (RSI geht hoch und ist unter der Buy-Line, Stochastic unter Buy-Line mit bullischem Cross, und RSI kreuzt über SMA unterhalb der RSI+SMA Buy Line)
buySignal = rsiUp and rsi < rsiBuyLine and bullishCross and stochK < stochBuyLine and rsiCrossAboveSMA

// Sell Signal (RSI geht runter und ist über der Sell-Line, Stochastic über Sell-Line mit bärischem Cross, und RSI kreuzt unter SMA oberhalb der RSI+SMA Sell Line)
sellSignal = rsiDown and rsi > rsiSellLine and bearishCross and stochK > stochSellLine and rsiCrossBelowSMA

// Plot RSI, Smoothed RSI, and Stochastic for reference with default visibility off
plot(rsi, title="RSI", color=color.yellow, linewidth=2, display=display.none)
plot(smoothedRsi, title="Smoothed RSI", color=color.blue, linewidth=2, display=display.none)
hline(rsiBuyLine, "RSI Buy Line", color=color.green, linewidth=2, linestyle=hline.style_solid, display=display.none)
hline(rsiSellLine, "RSI Sell Line", color=color.red, linewidth=2, linestyle=hline.style_solid, display=display.none)
hline(rsiSmaBuyLine, "RSI + MA Buy Line", color=color.purple, linewidth=2, linestyle=hline.style_solid, display=display.none)
hline(rsiSmaSellLine, "RSI + MA Sell Line", color=color.orange, linewidth=2, linestyle=hline.style_solid, display=display.none)
plot(stochK, title="Stochastic %K", color=color.aqua, linewidth=2, display=display.none)
plot(stochD, title="Stochastic %D", color=color.red, linewidth=3, display=display.none)
hline(stochBuyLine, "Stochastic Buy Line", color=color.green, linewidth=2, linestyle=hline.style_solid, display=display.none)
hline(stochSellLine, "Stochastic Sell Line", color=color.red, linewidth=2, linestyle=hline.style_solid, display=display.none)

// Alert conditions
alertcondition(buySignal, title="Buy Signal", message="Buy Signal: RSI and Stochastic conditions met.")
alertcondition(sellSignal, title="Sell Signal", message="Sell Signal: RSI and Stochastic conditions met.")

// Plot buy and sell signals for visual reference
plotshape(series=buySignal, location=location.belowbar, color=color.new(color.green, 0), style=shape.labelup, text="BUY", textcolor=color.black, size=size.tiny)
plotshape(series=sellSignal, location=location.abovebar, color=color.new(color.red, 0), style=shape.labeldown, text="SELL", textcolor=color.black, size=size.tiny)

// Strategy orders
if (buySignal)
    strategy.entry("Buy", strategy.long)
if (sellSignal)
    strategy.entry("Sell", strategy.short)
Berkaitan
Lebih lanjut

2019 FMZ - Semua hak dilindungi