A estratégia de curto intervalo dentro do dia identifica oscilações de curto intervalo e curto intervalo dentro do dia para seguir uma tendência longa.
Utilize o NR7 para identificar o dia de intervalo mais estreito entre os últimos 7 dias.
Usar dentro do dia para determinar se a alta do dia anterior é inferior à alta do dia atual e a baixa do dia anterior é superior à baixa do dia atual.
Quando NR7 e dentro do dia ocorrem juntos, com preço de fechamento superior ao preço de abertura, vá longo.
Sair quando o fechamento do dia seguinte for superior ao aberto.
A estratégia utiliza tanto o estreitamento do preço quanto os sinais dentro do dia para identificar os estágios de acumulação.
Além disso, a abordagem de longo prazo evita armadilhas de consolidação e transacções desnecessárias.
Considera os sinais de estreitamento e dentro do dia
A direcção da SMA determina a existência da tendência
A filtragem multi-condição melhora a precisão do sinal
Só a longo prazo evita armadilhas de consolidação
Parâmetros de backtest otimizáveis, flexíveis
Ajuste de SMA necessário para otimizar os sinais
A entrada pode demorar muito, foca no momento da fuga.
Incapaz de lucrar com tendências de baixa
Prevenir uma nova expansão dos intervalos
A estratégia de breakout dentro do dia examina a estrutura do mercado e gera sinais de alta probabilidade. Com ajuste de parâmetros, é altamente adaptável.
/*backtest
start: 2023-09-11 00:00:00
end: 2023-09-14 00:00:00
period: 10m
basePeriod: 1m
exchanges: [{"eid":"Futures_Binance","currency":"BTC_USDT"}]
*/
//@version=2
strategy("NR7ID: Narrow Range + Inside Day, Long Only Strategy (by ChartArt)", shorttitle="CA_-_NR7ID_Strat", overlay=true) // max_bars_back=5000
// ChartArt's Narrow Range + Inside Day Strategy (Long Only)
//
// Version 1.0
// Idea by ChartArt on Oktober 16, 2016.
//
// This long only strategy determines when there is both
// a NR7 (narrow range 7, a trading day in which the range
// is narrower than any of the previous six days), plus a
// inside day (high of the current day is lower than the high
// of the previous day and the low of the current day is higher
// than the low of the previous day) both on the same trading day
// and enters a long trade when the close is larger than the
// open and the slope of the simple moving average is upwards, too.
//
// The strategy exits the long trade next time the close is
// larger than the open in any of the next trading days.
//
// In addition the NR7ID can be colored (if close large open
// colored in green, else in red) and the SMA can be drawn
// with a color based on the direction of the SMA slope.
//
// List of my work:
// https://www.tradingview.com/u/ChartArt/
//
// __ __ ___ __ ___
// / ` |__| /\ |__) | /\ |__) |
// \__, | | /~~\ | \ | /~~\ | \ |
//
//
// NR7 Identifier
show_NR7=input(true, type=bool,title="Show Narrow Range 7 (NR7) ?")
range=(high-low)
nr7=(range < range[1]) and (range < range[2]) and (range < range[3]) and (range < range[4]) and (range < range[5]) and (range < range[6])
plotchar(show_NR7?nr7:na, char="7", location=location.abovebar, color=blue)
// Inside Day Identifier
show_insidebar = input(true, type=bool,title="Show Inside Day (I) ?")
insidebar = (high < high[1] and low > low[1])
plotchar(show_insidebar?insidebar:na, char="i", location=location.abovebar, color=blue)
// NR7 + Inside Day Identifier
show_NR7ID = input(true, type=bool,title="Show NR7ID (NR7 + Inside Day) colors ?")
NR7ID = nr7 and insidebar
NR7ID_color = NR7ID and open < close ? green : NR7ID and open > close ? red : gray
barcolor(show_NR7ID?NR7ID_color:na)
// Simple Moving Average
show_ma = input(true, type=bool,title="Show SMA ?")
ma_length = input(14,title="SMA Length")
ma = sma(close,ma_length)
ma_change = change(ma) > 0
ma_change_color = change(ma) > 0 ? green : change(ma) < 0 ? red : blue
plot(show_ma?ma:na,color=ma_change_color,linewidth=3)
// (not enabled) Short Strategy: NR7 + Inside Day + close is smaller than open + change of SMA is downwards
//strategy.entry("sell", strategy.short, when = NR7ID and open > close and ma_change == false, comment="Short")
//strategy.close("sell", when = open > close )
// Long Strategy: NR7 + Inside Day + close is larger than open + change of SMA is upwards
strategy.entry("long", strategy.long, when = NR7ID and open < close and ma_change == true, comment="Long")
strategy.close("long", when = open < close )