O recurso está a ser carregado... Carregamento...

3EMA com estratégia de RSI estocástica

Autora:ChaoZhang, Data: 2023-11-15 10:47:20
Tags:

Resumo

Esta é uma estratégia de tendência que combina vários indicadores. Ele usa três EMAs com períodos diferentes, RSI estocástico e ATR para identificar a direção da tendência e estabelecer posições.

Princípio

A estratégia utiliza três linhas EMA - 8-, 14- e 50-period EMAs, representando as tendências de preços em diferentes prazos.

O indicador RSI estocástico incorpora cálculos RSI e estocásticos para identificar condições de sobrecompra/supervenda.

A estratégia usa 3 vezes o ATR como distância de stop loss e 2 vezes o ATR como distância de take profit para bloquear os lucros e controlar o risco.

Vantagens

As EMAs filtram o ruído nos dados de preços e identificam a direcção da tendência
O RSI estocástico identifica oportunidades de reversão
O ATR monitora dinamicamente o stop loss/take profit com base na volatilidade do mercado

Riscos

Indicadores múltiplos podem gerar sinais conflitantes
Os rácios de stop loss/take profit fixos não podem adaptar-se às condições de mercado em evolução
Ativos financeiros de curto prazo

A otimização pode ser feita ajustando os períodos de EMA para otimizar a sensibilidade.

Reforço

Ajustar os períodos de EMA para otimizar a sensibilidade
Fazer com que as relações ATR sejam ajustáveis
Adicionar outros indicadores para evitar sinais falsos

Conclusão

A estratégia considera tendência, níveis de sobrecompra / sobrevenda e faixa de volatilidade para identificar o tempo de entrada. As EMAs e o RSI estocástico combinados identificam efetivamente tendências, enquanto o ATR dinâmico de stop loss / take profit ajuda no controle de riscos. Com ajuste e otimizações de parâmetros, a estratégia pode se tornar um sistema de tendência confiável.

/*backtest
start: 2023-10-15 00:00:00
end: 2023-11-14 00:00:00
period: 1h
basePeriod: 15m
exchanges: [{"eid":"Futures_Binance","currency":"BTC_USDT"}]
*/

// This source code is subject to the terms of the Mozilla Public License 2.0 at https://mozilla.org/MPL/2.0/
// © FreddieChopin
 
//@version=4
strategy("3 x EMA + Stochastic RSI + ATR", overlay = true, default_qty_type = strategy.percent_of_equity, default_qty_value = 100)
 
// 3x EMA
ema1Length = input(8, "EMA1 Length", minval = 1)
ema2Length = input(14, "EMA2 Length", minval = 1)
ema3Length = input(50, "EMA3 Length", minval = 1)
ema1 = ema(close, ema1Length)
ema2 = ema(close, ema2Length)
ema3 = ema(close, ema3Length)
 
plot(ema1, color = color.green)
plot(ema2, color = color.orange)
plot(ema3, color = color.red)
 
// Stochastic RSI
smoothK = input(3, "K", minval=1)
smoothD = input(3, "D", minval=1)
lengthRSI = input(14, "RSI Length", minval=1)
lengthStoch = input(14, "Stochastic Length", minval=1)
src = input(close, title="RSI Source")
rsi1 = rsi(src, lengthRSI)
k = sma(stoch(rsi1, rsi1, rsi1, lengthStoch), smoothK)
d = sma(k, smoothD)
 
// ATR
atrPeriod = input(14, "ATR Period")
takeProfitMultiplier= input(2.0, "Take-profit Multiplier")
stopLossMultiplier= input(3.0, "Stop-loss Multiplier")
atrSeries = atr(atrPeriod)[1]
 
longCondition = ema1 > ema2 and ema2 > ema3 and crossover(k, d)
strategy.entry("long", strategy.long, when = longCondition)
 
float stopLoss = na
float takeProfit = na
 
if (strategy.position_size > 0)
    if (na(stopLoss[1]))
        stopLoss := strategy.position_avg_price - atrSeries * stopLossMultiplier
    else
        stopLoss := stopLoss[1]
    if (na(takeProfit[1]))
        takeProfit := strategy.position_avg_price + atrSeries * takeProfitMultiplier
    else
        takeProfit := takeProfit[1]
 
    strategy.exit("take profit / stop loss", limit = takeProfit, stop = stopLoss)
 
plot(stopLoss, color = color.red, linewidth = 2, style = plot.style_linebr)
plot(takeProfit, color = color.green, linewidth = 2, style = plot.style_linebr)

Mais.