O recurso está a ser carregado... Carregamento...

Caso o valor da taxa de variação seja inferior ou igual ao valor da taxa de variação

Autora:ChaoZhang, Data: 2023-11-22 16:51:27
Tags:

Resumo

A ideia desta estratégia é ser uma estratégia de baixo risco para ações em tendência (ou qualquer outro mercado em tendência), visando a obtenção de um aproveitamento mínimo (por exemplo, no momento da redação do presente relatório, a AAPL tinha apenas ~ 1,36% de aproveitamento, a FB ~ 1,93% de aproveitamento e o SPY era de 0,80% de aproveitamento e tudo manteve-se rentável).

Princípio

A estratégia utiliza a média móvel de 200 dias, uma banda de Bollinger personalizada, uma TSI com média móvel ponderada por 52 períodos e força ADX.

O sinal de compra é dado quando a negociação está acima da média móvel de 200 + 5 velas fecharam acima da Bollinger custom superior + a TSI é positiva + o ADX está acima de 20.

Vantagens

As vantagens desta estratégia são a baixa absorção e o risco mínimo. É adequado para a maioria das ações de tendência com uma operação de baixo risco. De acordo com os dados do teste, o retorno é elevado e a AAPL teve apenas a absorção máxima de 1,36% e a FB teve a absorção máxima de 1,93% durante o período de teste.

Ao combinar vários indicadores técnicos, como Bandas de Bollinger, linhas MA, indicadores TSI e usar o ADX para determinar a força da tendência, ele compra quando a tendência sobe, tentando capturar o potencial de alta de médio a longo prazo das ações de tendência.

A estratégia de stop-loss também prevê a obtenção de lucros através da suspensão de perdas em tempo útil quando o indicador da ETI mudar de direção, controlando efetivamente os riscos.

Análise de riscos

Os principais riscos que esta estratégia enfrenta são dois:

Risco de eventos de cisne negro Alguns eventos de cisne negro podem causar uma queda acentuada das ações e não podem impedir a perda.
Quando o estoque se move de tendência para consolidação, pode haver maiores retrações.

Para o risco 1, podem ser definidos mecanismos de stop loss mais rigorosos, ou podem ser utilizadas paradas de intervenção manual.

Orientações de otimização

A estratégia pode também ser otimizada nos seguintes aspectos:

Adicionar uma estratégia de stop loss para definir pontos de stop loss mais precisos para controlar melhor os riscos.
Otimizar os parâmetros da média móvel para testar a estabilidade de diferentes combinações de parâmetros.
Aumentar os indicadores de impulso para determinar com mais precisão o início e o fim das tendências.
Teste os parâmetros do ciclo de tempo mais longo para se adequarem às operações a longo prazo.

Conclusão

Esta estratégia determina oportunidades de compra usando o ADX para determinar a força da tendência, indicadores TSI para determinar a direção da tendência, Bandas de Bollinger para determinar breakouts e médias móveis para determinar tendências de longo prazo. A verificação de múltiplos indicadores pode controlar efetivamente os riscos. Esta estratégia é adequada para rastreamento de longo prazo de ações de tendência com baixos drawdowns e altos retornos.

/*backtest
start: 2023-01-01 00:00:00
end: 2023-11-21 00:00:00
period: 1d
basePeriod: 1h
exchanges: [{"eid":"Futures_Binance","currency":"BTC_USDT"}]
*/

// This source code is subject to the terms of the Mozilla Public License 2.0 at https://mozilla.org/MPL/2.0/
// © gary_trades
//This script has been designed to be used on trending stocks as a low risk trade with minimal drawdown, utilising 200 Moving Average, Custom Bollinger Band, TSI with weighted moving average and ADX strength. 
//Backtest dates are set to 2010 - 2020 and all other filters (moving average, ADX, TSI , Bollinger Band) are not locked so they can be user amended if desired. 
//Buy signal is given when trading above the 200 moving average + 5 candles have closed above the upper custom Bollinger + the TSI is positive + ADX is above 20.
//As back testing proved that this traded better only in tends then some Sell/Short conditions have been removed and this focueses on  Long orders.
//Only requires 2 additional lines of code to add shorting orders.
//Close for either long or short trades is signaled once the TSI crosses in the opposite direction indicating change in trend strength or if stop loss is trggered.
//Further optimization could be achieved by adding a stop loss.
//NOTE: This only shows the lower indicators however for visualization you can use my script "CUSTOM BOLLINGER WITH SMA", which is the upper indicators in this stratergy.
//------------
//@version=4
strategy(shorttitle="Trend Chaser", title="ADX_TSI_Bol Band Trend Chaser", overlay=false, pyramiding=0,
 currency=currency.USD, default_qty_type=strategy.percent_of_equity, default_qty_value=10,
 initial_capital=10000, commission_value=0.1)
//------------
//Custom Bollinger Band
length = input(20, minval=1)
src = input(close, title="Source")
mult = input(0.382, minval=0.001, maxval=50, title="StdDev")
basis = sma(src, length)
dev = mult * stdev(src, length)
upper = basis + dev
lower = basis - dev
offset = input(0, "Offset", type = input.integer, minval = -500, maxval = 500)
plot(basis, "Basis", color=color.gray, offset = offset, display=display.none)
p1 = plot(upper, "Upper", color=color.gray, offset = offset, display=display.none)
p2 = plot(lower, "Lower", color=color.gray, offset = offset, display=display.none)
fill(p1, p2, title = "Background", color=#787B86, transp=85)
//------------
//Moving Average
MAlen = input(200, minval=1, title="Length")
MAout = sma(src, MAlen)
plot(MAout, color=color.black, title="MA", offset=offset, linewidth=2, display=display.none)
//------------
//True Strength WMA
TSlong = input(title="Long Length", type=input.integer, defval=25)
TSshort = input(title="Short Length", type=input.integer, defval=13)
TSsignal = input(title="Signal Length", type=input.integer, defval=52)
double_smooth(src, TSlong, TSshort) =>
    fist_smooth = wma(src, TSlong)
    wma(fist_smooth, TSshort)
price = close     
pc = change(price)
double_smoothed_pc = double_smooth(pc, TSlong, TSshort)
double_smoothed_abs_pc = double_smooth(abs(pc), TSlong, TSshort)
tsi_value = 100 * (double_smoothed_pc / double_smoothed_abs_pc)
tsi2 = wma(tsi_value, TSsignal)
plot(tsi_value, color=color.blue)
plot(wma(tsi_value, TSsignal), color=color.red)
hline(0, title="Zero")
//------------
//ADX
adxlen = input(13, title="ADX Smoothing")
dilen = input(13, title="DI Length")
keyLevel = input(20, title="Keylevel for ADX")
dirmov(len) =>
	up = change(high)
	down = -change(low)
	plusDM = na(up) ? na : (up > down and up > 0 ? up : 0)
    minusDM = na(down) ? na : (down > up and down > 0 ? down : 0)
	truerange = rma(tr, len)
	plus = fixnan(100 * rma(plusDM, len) / truerange)
	minus = fixnan(100 * rma(minusDM, len) / truerange)
	[plus, minus]

adx(dilen, adxlen) =>
	[plus, minus] = dirmov(dilen)
	sum = plus + minus
	adx = 100 * rma(abs(plus - minus) / (sum == 0 ? 1 : sum), adxlen)

sig = adx(dilen, adxlen)

plot(sig, color=color.black, title="ADX", style=plot.style_histogram, transp=40)
plot(20, color=color.green, title="ADX Keyline", linewidth=1)
//------------
//Identify Triggers

//Back Test Range
start = timestamp("America/New_York", 2010, 1, 1, 9,30)
end = timestamp("America/New_York", 2030, 7, 1, 0, 0)

//Custom Bollinger Band
Long1 = close > upper[5] and close[5] > upper [6]
Short1 = close < lower[5] and close[5] < lower [6]

//Moving Average
Long2 = close >= MAout[1]
Short2 = close <= MAout[1]

//True Strength WMA
Long3 = tsi_value > tsi2  
Short3 = tsi_value < tsi2

//ADX
ADXkey = adx(dilen, adxlen) > 20 and adx(dilen, adxlen) < 100

//Buy
Buy = Long1 and Long2 and Long3 and ADXkey
CloseLong = crossunder(tsi_value,tsi2)

//Short
Sell = Short1 and Short2 and Short3 and ADXkey
CloseShort = crossover(tsi_value,tsi2)
//------------
//Entry and Exit
if time >= start and time <= end
    strategy.entry("Long", true, when = Buy)

strategy.close("Long", when = CloseLong)

Mais.