O recurso está a ser carregado... Carregamento...

Estratégia de negociação cruzada rápida QQE baseada no filtro de tendências

Autora:ChaoZhang, Data: 2024-01-25 11:34:58
Tags:

Resumo

A estratégia de negociação de cruzamento QQE rápido baseada no filtro de tendência é uma estratégia de negociação de tendência que usa cruzes QQE rápidas com médias móveis para filtrar a direção da tendência.

RSI sinal cruzando ZERO (XZERO)
RSI sinal atravessando linha RSIatr rápida (XQQE)
O sinal RSI que sai do canal de limiar RSI (COMPRAR/VENDER)

Os alertas (COMPRAR/VENDER) podem ser filtrados opcionalmente pelas médias móveis:

Para o alerta BUY, o Close deve estar acima da MA rápida e da MA rápida (EMA8) > da MA média (EMA20) > da MA lenta (SMA50).
Para o alerta SELL, o fechamento deve estar abaixo da MA rápida e da MA rápida (EMA8) < MA média (EMA20) < MA lenta (SMA50).

e/ou filtro direcional:

Para o alerta BUY, o fechamento deve estar acima do MA lento (SMA50) e o MA direcional (EMA20) deve ser verde.
Para o alerta SELL, o fechamento deve estar abaixo do MA lento (SMA50) e o MA direcional (EMA20) deve ser vermelho.

O XZERO e o XQQE não estão incluídos na filtragem, são utilizados para indicar alertas pendentes de compra/venda, em particular o XZERO.

Esta estratégia deve funcionar em qualquer par de moedas e na maioria dos prazos de gráficos.

Princípio da estratégia

A ideia central desta estratégia é usar o cruzamento direcional do indicador QQE rápido como sinais de negociação e filtrar sinais de negociação ruidosos através da combinação de médias móveis para capturar a direção da tendência.

Em especial, a estratégia utiliza os seguintes indicadores e sinais:

Indicador QQE rápido: Este é um indicador baseado no RSI com suavização adicional para torná-lo mais sensível e rápido. O indicador consiste em três linhas: a linha do meio é a média móvel exponencial do RSI, a linha superior é a linha do meio + ATR rápido * um fator, e a linha inferior é a linha do meio - ATR rápido * um fator. Quando o RSI vai acima da linha superior, é um sinal de venda. Quando o RSI vai abaixo da linha inferior, é um sinal de compra.

Cruzamento de linha zero: Gerar sinais quando a linha média do RSI cruza a linha zero. O cruzamento ascendente é sinal de compra e o cruzamento descendente é sinal de venda. Estes sinais indicam o prelúdio de mudanças de tendência.

Furação do canalO RSI é um indicador de tendência de mercado, que é gerado quando a linha média do RSI entra no canal de limiar definido.

Combinação de média móvelQuando as três linhas são dispostas como: rápida > média > lenta, é uma tendência ascendente. Quando dispostas como rápida < média < lenta, é uma tendência descendente. A combinação é usada para determinar a direção geral da tendência.

Filtro de direção de tendência: Um sinal de compra é gerado apenas quando o preço de fechamento está acima da média móvel lenta e a média móvel média (20 períodos) está para cima (preço mais alto do período > preço mais baixo). Um sinal de venda é gerado apenas quando o preço de fechamento está abaixo da média móvel lenta e a média móvel média (20 períodos) está para baixo. Isso pode filtrar alguns sinais falsos reversos.

Ao combinar o uso de sinais cruzados do indicador QQE rápido e a filtragem de tendências a partir de médias móveis, ele capta pontos de reversão de curto prazo nas principais tendências de período de tempo para formar um sistema de negociação relativamente completo.

Em resumo, esta é uma estratégia que rastreia tendências de médio e longo prazo, usa indicadores rápidos para capturar o momento das reversões de curto prazo para entrada / saída e utiliza a filtragem da média móvel para reduzir o risco de negociação contra a direção e, assim, maximizar os retornos.

Vantagens da estratégia

Utiliza indicador QQE rápido e sensível para captar rapidamente sinais de reversão
Aplica múltiplas médias móveis para determinar a direção do grande ciclo e evitar negociações contra tendências
Inclui vários sinais cruzados que podem ser utilizados em combinação para aumentar as oportunidades de lucro
Parâmetros ajustáveis que podem ser otimizados para diferentes produtos e prazos
Utiliza os sinais de ruptura do próprio canal do indicador em vez de desenhar canais separados, evitando dependência de parâmetros
Pode capturar movimentos de reversão de curto prazo muito bem em grandes ciclos de tendência
Conceitos simples e claros, fáceis de compreender e implementar

Riscos da Estratégia

Há também alguns riscos potenciais com esta estratégia:

Os indicadores rápidos tendem a produzir sinais falsos que não podem ser totalmente filtrados pelas médias móveis, existindo o risco de seguir uma direcção errada.
Quando ocorre uma grande inversão de tendência do ciclo, tendem a formar-se sinais comerciais inversos que representam riscos
Nenhuma consideração de fatores de gestão de fundos, riscos de negociação excessiva e perdas
Não há stop loss no local, os riscos de expansão das perdas é grande
Risco de adequação dos dados dos testes anteriores, ainda não verificado o desempenho real

As medidas e soluções incluem:

Ajustar os parâmetros da média móvel, usar mais comprimentos de ciclo para determinar tendências
Adicionar outros indicadores como MACD, bias etc para filtragem de combinação
Adicionar estratégias de stop loss para controlar o tamanho das perdas de uma única operação
Testes com dinheiro real, otimização de parâmetros

Orientações de otimização

A estratégia pode ser melhorada:

Otimizar os parâmetros de linha rápida e lenta do indicador QQE para encontrar a combinação ideal de parâmetros
Teste mais combinações de médias móveis para encontrar o desempenho de filtragem ideal
Adicionar outros indicadores como o MACD para filtragem de sinal auxiliar
Aplicar estratégias de gestão de fundos para otimizar o dimensionamento das posições
Estabelecer uma estratégia de stop loss para controlar o risco de queda por transação
Otimizar parâmetros com base em diferentes produtos
Determinar a tendência em prazos ainda mais longos para evitar ser enganado por reversões de curto prazo

Com a otimização de parâmetros, a combinação de mais indicadores e auxiliados por práticas viáveis de gestão de dinheiro e risco, o desempenho desta estratégia pode ser melhorado para negociação real.

Conclusão

Em geral, a estratégia de negociação crossover QQE rápida baseada no filtro de tendências é uma escolha muito considerável. Sua força reside em capturar rapidamente oportunidades de negociação de reversão, usando múltiplas médias móveis para determinar as principais tendências e evitar negociações contra elas tanto quanto possível. Com otimização de parâmetros de indicadores e critérios de filtragem, juntamente com uma gestão rigorosa do dinheiro, essa estratégia pode gerar retornos de investimento relativamente constantes.

É claro que os riscos não podem ser ignorados. Testes de dinheiro real e ajustes de otimização contínuos são necessários para garantir a praticidade e confiabilidade da estratégia. Em conclusão, vale a pena para os investidores estudarem e rastrearem a prática a longo prazo. Acredita-se que com o avanço das tecnologias de negociação algorítmica, esse tipo de estratégias baseadas em indicadores rápidos e filtragem de tendências verão melhorias e proliferação.

/*backtest
start: 2024-01-17 00:00:00
end: 2024-01-24 00:00:00
period: 5m
basePeriod: 1m
exchanges: [{"eid":"Futures_Binance","currency":"BTC_USDT"}]
*/

//@version=2
//
// Title:   [STRATEGY][UL]QQE Cross v1.1
// Author:  JustUncleL
// Date:    22-Oct-2016
// Version: v1.1
//
// Description:
//  A trend following trading Strategy that uses fast QQE crosses with Moving Averages
//  for trend direction filtering. QQE or Qualitative Quantitative Estimation is based 
//  on the relative strength index, but uses a smoothing technique as an additional 
//  transformation. Three crosses can be selected (all selected by default): 
//    - RSI signal crossing ZERO (XZERO)
//    - RSI signal crossing Fast RSIatr line (XQQE)
//    - RSI signal exiting the RSI Threshhold Channel (BUY/SELL)
//  The (BUY/SELL) alerts can be optionally filtered by the Moving averages:
//    - For BUY alert the Close must be above the fast MA and 
//        fast MA (EMA8) > medium MA (EMA20) > slow MA (SMA50).
//    - For SELL alert the Close must be below the fast MA and
//        fast MA (EMA8) < medium MA (EMA20) < slow MA (SMA50).
//  and/or directional filter:
//    - For BUY alert the Close must be above the slow MA (SMA50) and the
//      directional MA (EMA20) must be green.
//    - For SELL alert the Close must be below the slow MA (SMA50) and the
//      directional MA (EMA20) must be red.
//. The XZERO and XQQE are not included in the filtering, they are used to indicate
//  pending BUY/SELL alerts, particularly the XZERO. 
//
//  This Strategy should work on any currency pair and most chart timeframes.
//  *** USE AT YOUR OWN RISK ***
//  
// 
//
// Mofidifications:
//  1.1 - Added Target Profit option, cleaned up the risk management code.
//        Changed Trade Close to EMA20 direction change instead of opposite BUY/SELL
//        signal, which will be earlier, this means stop loss setting should not be
//        required when an AutoTrader is available.
//        Modified code to prevent potential repaint issues.
//  1.0 - original
//
// References:
//  Some Code borrowed from:
//  - "Scalp Jockey - MTF MA Cross Visual Strategizer by JayRogers"
//  - "QQE MT4 by glaz"
//  - "Strategy Code Example by JayRogers"  
//  Inspiration from:
//  - http://www.forexstrategiesresources.com/binary-options-strategies-ii/189-aurora-binary-trading/
//  - http://www.forexstrategiesresources.com/metatrader-4-trading-systems-v/652-qqe-smoothed-trading/
//  - http://dewinforex.com/forex-indicators/qqe-indicator-not-quite-grail-but-accurately-defines-trend-and-flat.html
//

strategy(title='[STRATEGY][UL]QQE Cross v1.1', pyramiding=0, overlay=true )


// - INPUTS START
// Fast MA - type, source, length
type1   = input(defval="EMA", title="Fast MA Type: SMA, EMA, WMA, VWMA, SMMA, DEMA, TEMA, HullMA, ZEMA ( case sensitive )")
len1    = input(defval=8, title="Fast - Length", minval=1)
// Medium Fast MA - type, source, length
type2   = input(defval="EMA", title="Medium Fast MA Type: SMA, EMA, WMA, VWMA, SMMA, DEMA, TEMA, HullMA, ZEMA ( case sensitive )")
len2    = input(defval=20, title="Medium Fast - Length", minval=1)
// Slow MA - type, source, length
type3   = input(defval="SMA", title="Slow MA Type: SMA, EMA, WMA, VWMA, SMMA, DEMA, TEMA, HullMA, LSMA, ZEMA ( case sensitive )")
len3    = input(defval=50, title="Slow Length", minval=1)
//
// QQE rsi Length, Smoothing, fast ATR factor, source
RSILen  = input(6,title='RSI Length')
SF      = input(3,title='RSI Smoothing Factor')
QQE     = input(2.618,title='Fast QQE Factor')
threshhold = input(10, title="RSI Threshhold")
//
sQQEx   = input(false,title="Show QQE Signal crosses")
sQQEz   = input(false,title="Show QQE Zero crosses")
//
filter  = input(false,title="Use Moving Average Filter")
dfilter = input(true, title="Use Trend Directional Filter" )
RSIsrc  = input(close,title="Source")
srcclose= RSIsrc

// - INPUTS END

// - FUNCTIONS

// Returns MA input selection variant, default to SMA if blank or typo.
variant(type, src, len) =>
    v1 = sma(src, len)                                                  // Simple
    v2 = ema(src, len)                                                  // Exponential
    v3 = wma(src, len)                                                  // Weighted
    v4 = vwma(src, len)                                                 // Volume Weighted
    v5 = na(v5[1]) ? sma(src, len) : (v5[1] * (len - 1) + src) / len    // Smoothed
    v6 = 2 * v2 - ema(v2, len)                                          // Double Exponential
    v7 = 3 * (v2 - ema(v2, len)) + ema(ema(v2, len), len)               // Triple Exponential
    v8 = wma(2 * wma(src, len / 2) - wma(src, len), round(sqrt(len)))   // Hull
    ema1 = ema(src, len)
    ema2 = ema(ema1, len)
    v10 = ema1+(ema1-ema2)                                              // Zero Lag Exponential
    // return variant, defaults to SMA if input invalid.
    type=="EMA"?v2 : type=="WMA"?v3 : type=="VWMA"?v4 : type=="SMMA"?v5 : type=="DEMA"?v6 : type=="TEMA"?v7 : type=="HullMA"?v8 : type=="ZEMA"?v10 : v1

// - FUNCTIONS END

// - Fast ATR QQE
//
Wilders_Period = RSILen * 2 - 1
//
Rsi = rsi(RSIsrc,RSILen)
RSIndex = ema(Rsi, SF)
AtrRsi = abs(RSIndex[1] - RSIndex)
MaAtrRsi = ema(AtrRsi, Wilders_Period)
DeltaFastAtrRsi = ema(MaAtrRsi,Wilders_Period) * QQE
//
newshortband=  RSIndex + DeltaFastAtrRsi
newlongband= RSIndex - DeltaFastAtrRsi
longband=RSIndex[1] > longband[1] and RSIndex > longband[1] ? max(longband[1],newlongband) : newlongband
shortband=RSIndex[1] < shortband[1] and  RSIndex < shortband[1] ? min(shortband[1],newshortband) : newshortband
trend=cross(RSIndex, shortband[1])? 1 : cross(longband[1], RSIndex) ? -1 : nz(trend[1],1)
FastAtrRsiTL = trend==1 ? longband : shortband


// - SERIES VARIABLES
// MA's
ma_fast    = variant(type1, srcclose, len1)
ma_medium  = variant(type2, srcclose, len2)
ma_slow    = variant(type3, srcclose, len3)
// Get Direction From Medium Moving Average
direction = rising(ma_medium,3) ? 1 : falling(ma_medium,3) ? -1 : 0
//
// Find all the QQE Crosses
QQExshort = sQQEx and crossover(FastAtrRsiTL, RSIndex)
QQExlong  = sQQEx and crossunder(FastAtrRsiTL, RSIndex)
// Zero cross
QQEzlong = sQQEz and crossover(RSIndex,50)
QQEzshort  = sQQEz and crossunder(RSIndex,50)
//  
// Thresh Hold channel Crosses give the BUY/SELL alerts.
QQEclong = RSIndex>(50+threshhold) ? na(QQEclong[1]) ? 1 : QQEclong[1]+1 : 0
QQEcshort = RSIndex<(50-threshhold) ? na(QQEcshort[1]) ? 1 : QQEcshort[1]+1 : 0

//
// Check Filtering.
QQEflong = (not filter or (srcclose>ma_fast and ma_medium>ma_slow and ma_fast>ma_medium)) and 
  (not dfilter or (direction>0 and srcclose>ma_slow))
QQEfshort = (not filter or (srcclose<ma_fast and ma_medium<ma_slow and ma_fast<ma_medium)) and
  (not dfilter or (direction<0 and srcclose<ma_slow))
//
// Get final BUY / SELL alert determination
buy = QQEclong>0 and QQEflong ? na(buy[1]) ? 1 : buy[1]+1 : 0
sell= QQEcshort>0 and QQEfshort ? na(sell[1]) ? 1 : sell[1]+1 : 0

// - SERIES VARIABLES END

// - PLOTTING
// Ma's
plot(ma_fast, title="MA Fast", color=olive, linewidth=2, transp=20)
plot(ma_medium, title="MA Medium Fast", color=direction<0?red:green, linewidth=3, transp=0)
plot(ma_slow, title="MA Slow", color=blue, linewidth=2, transp=20)
// QQE crosses
plotshape(QQExlong and buy!=1, title="QQE Cross Over", style=shape.triangleup, location=location.belowbar, text="XQQE", color=blue, transp=20, size=size.tiny)
plotshape(QQExshort and sell!=1, title="QQE Cross Under", style=shape.triangledown, location=location.abovebar, text="XQQE", color=black, transp=20, size=size.tiny)
// Signal crosses zero line
plotshape(QQEzlong and buy!=1 and not QQExlong, title="QQE Zero Cross Over", style=shape.triangleup, location=location.belowbar, text="XZERO", color=aqua, transp=20, size=size.tiny)
plotshape(QQEzshort and sell!=1 and not QQExshort, title="QQE Zero Cross Under", style=shape.triangledown, location=location.abovebar, text="XZERO", color=fuchsia, transp=20, size=size.tiny)

// - PLOTTING END

// Create alert for cross, shunt back 1 if source is not 'open', this should prevent repaint issue.
//shunt = RSIsrc == open ? 0 : 1
shunt = 0
c_alert = (buy[shunt]==1 or sell[shunt]==1)
//alertcondition(c_alert, title="QQECROSS Alert", message="QQECROSS Alert")
// show only when alert condition is met and bar closed.
plotshape(c_alert,title= "Alert Indicator Closed", location=location.bottom, color=sell[shunt]==1?red:green, transp=0, style=shape.circle)


//  Strategy: (Thanks to JayRogers)
// === STRATEGY RELATED INPUTS ===
//tradeInvert     = input(defval = false, title = "Invert Trade Direction?")
// the risk management inputs
inpTakeProfit   = input(defval = 0, title = "Take Profit Points", minval = 0)
inpStopLoss     = input(defval = 0, title = "Stop Loss Points", minval = 0)
inpTrailStop    = input(defval = 100, title = "Trailing Stop Loss Points", minval = 0)
inpTrailOffset  = input(defval = 0, title = "Trailing Stop Loss Offset Points", minval = 0)

// === RISK MANAGEMENT VALUE PREP ===
// if an input is less than 1, assuming not wanted so we assign 'na' value to disable it.
useTakeProfit   = inpTakeProfit  >= 1 ? inpTakeProfit  : na
useStopLoss     = inpStopLoss    >= 1 ? inpStopLoss    : na
useTrailStop    = inpTrailStop   >= 1 ? inpTrailStop   : na
useTrailOffset  = inpTrailOffset >= 1 ? inpTrailOffset : na

// === STRATEGY - LONG POSITION EXECUTION ===
strategy.entry(id = "Buy", long = true, when = buy[shunt]==1 )// use function or simple condition to decide when to get in
strategy.close(id = "Buy", when = direction[shunt]!=direction[shunt+1])// ...and when to get out

// === STRATEGY - SHORT POSITION EXECUTION ===
strategy.entry(id = "Sell", long = false, when = sell[shunt]==1)
strategy.close(id = "Sell", when = direction[shunt]!=direction[shunt+1])

// === STRATEGY RISK MANAGEMENT EXECUTION ===
// finally, make use of all the earlier values we got prepped
strategy.exit("Exit Buy", from_entry = "Buy", profit = useTakeProfit, loss = useStopLoss, trail_points = useTrailStop, trail_offset = useTrailOffset)
strategy.exit("Exit Sell", from_entry = "Sell", profit = useTakeProfit, loss = useStopLoss, trail_points = useTrailStop, trail_offset = useTrailOffset)

//eof

Mais.