O recurso está a ser carregado... Carregamento...

Estratégia de reversão diária da Super Tendência

Autora:ChaoZhang, Data: 2024-02-22 16:22:28
Tags:

Resumo

A Super Trend Daily Reversal Strategy é uma estratégia quantitativa de negociação que usa o indicador Super Trend para determinar as tendências do mercado, combina o avanço do preço e a faixa verdadeira média para calcular o stop loss e usa o indicador de taxa de mudança de preço para filtrar os sinais Super Trend. Esta estratégia é adequada para prazos diários e mais altos e pode ser usada em mercados como criptomoedas e ações.

Estratégia lógica

O indicador de Super Tendência é baseado no Intervalo Verdadeiro Médio (ATR) e pode determinar mais claramente a direção das tendências do mercado.

A estratégia usa o indicador de taxa de mudança de preço (ROC) para filtrar o indicador de Super Tendência para evitar sinais inválidos.

Para o stop loss, a estratégia fornece dois métodos de stop loss: porcentagem fixa de stop loss e stop loss adaptativo baseado em ATR. O stop loss fixo é simples e direto.

As condições de entrada são uma reversão do indicador de Super Tendência e o indicador de taxa de mudança de preço passa o filtro. As condições de saída são que a Super Tendência reverte novamente ou quebra a linha de stop loss. A estratégia adere ao princípio de rastreamento de tendência e só permite uma posição em cada direção.

Análise das vantagens

A maior vantagem desta estratégia é que o indicador Super Trend tem maior clareza e estabilidade para julgar a direção da tendência em comparação com as médias móveis comuns, com menos ruído.

O mecanismo de stop loss adaptativo ATR também permite que a estratégia se adapte a um ambiente de mercado mais amplo.

A partir dos resultados dos testes, esta estratégia tem um desempenho excepcionalmente bom em um mercado de alta.

Análise de riscos

O principal risco enfrentado por esta estratégia é a avaliação errada da inversão da tendência, que pode perder sinais de reversão ou gerar sinais de reversão desnecessários.

Além disso, um stop loss que é definido muito largo também pode levar a perdas maiores.

Para enfrentar estes riscos, o período de cálculo do ATR pode ser adequadamente encurtado ou o multiplicador de stop loss do ATR ajustado.

Orientações de otimização

A estratégia pode ser otimizada nos seguintes aspectos:

Ajustar os parâmetros do indicador Super Trend para otimizar o período ATR e os múltiplos ATR para tornar a linha Super Trend mais suave.
Ajustar os parâmetros do indicador da taxa de variação de preços para otimizar o período e o limiar da taxa de variação para reduzir os falsos sinais.
Tente diferentes mecanismos de stop loss, como trailing stops, ou otimize a amplitude de stop loss de stops fixos.
Adicionar indicadores de julgamento adicionais para determinar os principais suporte/resistência e evitar uma avaliação errada das inversões de tendência.
Ensaiar as definições dos parâmetros e os efeitos sobre diferentes produtos para encontrar a combinação ideal de parâmetros.
Realizar a otimização do backtest para encontrar as melhores configurações de parâmetros.

Conclusão

Em geral, a Super Trend Daily Reversal Strategy é uma estratégia de tendência relativamente estável e confiável. Ele combina o indicador Super Trend e o indicador de taxa de mudança de preço para filtragem, o que pode identificar efetivamente a direção das tendências de médio e longo prazo. O mecanismo de stop loss adaptativo ATR também permite que ele se adapte à maioria dos ambientes de mercado. Através de uma otimização adicional das configurações de parâmetros e indicadores de julgamento adicionados, a estabilidade e rentabilidade desta estratégia podem ser melhoradas.

/*backtest
start: 2024-01-22 00:00:00
end: 2024-02-21 00:00:00
period: 1h
basePeriod: 15m
exchanges: [{"eid":"Futures_Binance","currency":"BTC_USDT"}]
*/

//@version=4
strategy("Super Trend Daily BF 🚀", overlay=true, precision=2, initial_capital=10000, default_qty_type=strategy.percent_of_equity, default_qty_value=100, commission_type=strategy.commission.percent, commission_value=0.075)

/////////////// Time Frame ///////////////
_1 = input(false,  "════════ Test Period ═══════")
testStartYear = input(2017, "Backtest Start Year") 
testStartMonth = input(1, "Backtest Start Month")
testStartDay = input(1, "Backtest Start Day")
testPeriodStart = timestamp(testStartYear,testStartMonth,testStartDay, 0, 0)

testStopYear = input(2019, "Backtest Stop Year")
testStopMonth = input(12, "Backtest Stop Month")
testStopDay = input(31, "Backtest Stop Day")
testPeriodStop = timestamp(testStopYear,testStopMonth,testStopDay, 0, 0)

testPeriod() => true

///////////// Super Trend /////////////
_2 = input(false,  "══════ Super Trend ══════")
length = input(title="ATR Period", type=input.integer, defval=3)
mult = input(title="ATR Multiplier", type=input.float, step=0.1, defval=1.3)

atr = mult * atr(length)

longStop = hl2 - atr
longStopPrev = nz(longStop[1], longStop)
longStop :=  close[1] > longStopPrev ? max(longStop, longStopPrev) : longStop

shortStop = hl2 + atr
shortStopPrev = nz(shortStop[1], shortStop)
shortStop := close[1] < shortStopPrev ? min(shortStop, shortStopPrev) : shortStop

dir = 1
dir := nz(dir[1], dir)
dir := dir == -1 and close > shortStopPrev ? 1 : dir == 1 and close < longStopPrev ? -1 : dir

///////////// Rate Of Change ///////////// 
_3 = input(false,  "══════ Rate of Change ══════")
source = close
roclength = input(30, "ROC Length",  minval=1)
pcntChange = input(6, "ROC % Change", minval=1)
roc = 100 * (source - source[roclength]) / source[roclength]
emaroc = ema(roc, roclength / 2)
isMoving() => emaroc > (pcntChange / 2) or emaroc < (0 - (pcntChange / 2))

///////////////  Strategy  /////////////// 
long = dir == 1 and dir[1] == -1 and isMoving()
short = dir == -1 and dir[1] == 1 and isMoving()

last_long = 0.0
last_short = 0.0
last_long := long ? time : nz(last_long[1])
last_short := short ? time : nz(last_short[1])

long_signal = crossover(last_long, last_short)
short_signal = crossover(last_short, last_long)

last_open_long_signal = 0.0
last_open_short_signal = 0.0
last_open_long_signal := long_signal ? open : nz(last_open_long_signal[1])
last_open_short_signal := short_signal ? open : nz(last_open_short_signal[1])

last_long_signal = 0.0
last_short_signal = 0.0
last_long_signal := long_signal ? time : nz(last_long_signal[1])
last_short_signal := short_signal ? time : nz(last_short_signal[1])

in_long_signal = last_long_signal > last_short_signal
in_short_signal = last_short_signal > last_long_signal

last_high = 0.0
last_low = 0.0
last_high := not in_long_signal ? na : in_long_signal and (na(last_high[1]) or high > nz(last_high[1])) ? high : nz(last_high[1])
last_low := not in_short_signal ? na : in_short_signal and (na(last_low[1]) or low < nz(last_low[1])) ? low : nz(last_low[1])

since_longEntry = barssince(last_open_long_signal != last_open_long_signal[1]) 
since_shortEntry = barssince(last_open_short_signal != last_open_short_signal[1]) 

/////////////// Dynamic ATR Stop Losses ///////////////
_4 = input(false,  "════════ Stop Loss ═══════")
SL_type = input("Fixed", options=["Fixed", "ATR Derived"], title="Stop Loss Type")
sl_inp = input(6.0, title='Fixed Stop Loss %') / 100
atrLkb = input(20, minval=1, title='ATR Stop Period')
atrMult = input(1.5, step=0.25, title='ATR Stop Multiplier') 
atr1 = atr(atrLkb)

longStop1 = 0.0
longStop1 :=  short_signal ? na : long_signal ? close - (atr1 * atrMult) : longStop1[1]
shortStop1 = 0.0
shortStop1 := long_signal ? na : short_signal ? close + (atr1 * atrMult) : shortStop1[1]

slLong = in_long_signal ? strategy.position_avg_price * (1 - sl_inp) : na
slShort = strategy.position_avg_price * (1 + sl_inp)
long_sl = in_long_signal ? slLong : na
short_sl = in_short_signal ? slShort : na

/////////////// Execution ///////////////
if testPeriod()
    strategy.entry("L", strategy.long, when=long)
    strategy.entry("S", strategy.short, when=short)
    strategy.exit("L SL", "L", stop = SL_type == "Fixed" ? long_sl : longStop1, when=since_longEntry > 0)
    strategy.exit("S SL", "S", stop = SL_type == "Fixed" ? short_sl : shortStop1, when=since_shortEntry > 0)

/////////////// Plotting /////////////// 
bgcolor(long_signal ? color.lime : short_signal ? color.red : na, transp=30)
bgcolor(isMoving() ? dir == 1 ? color.lime : color.red : color.white , transp=80)

Mais.