O recurso está a ser carregado... Carregamento...
  1. Quadrado
  2. Estratégia de tendência baseada no MOST e no KAMA

Estratégia de tendência baseada no MOST e no KAMA

Autora:ChaoZhang, Data: 2024-02-29 11:04:38
Tags:

img

Esta estratégia combina múltiplas médias móveis, como SMA e EMA, para identificar a direção da tendência de preços, e define linhas de stop loss com base no avanço do preço para projetar uma estratégia de tendência. Quando os preços aumentam, ele segue a faixa superior como um stop loss; quando os preços caem, ele segue o limite inferior como um stop loss. A vantagem da estratégia é que a combinação de múltiplas médias móveis pode suavizar os dados de preços e identificar tendências; O projeto dinâmico de stop loss evita paradas excessivamente sensíveis. O risco da estratégia é que a configuração da linha de stop loss pode ser muito frouxa para parar a perda no tempo.

Princípio da estratégia

Esta estratégia usa o KAMA como base para julgar a direção da tendência, porque o KAMA responde às mudanças de preço de forma mais sensível e pode identificar voltas com antecedência.

A definição da linha de stop-loss da estratégia é baseada no preço em si e na média móvel. Especificamente, a linha de stop-loss ascendente é a média móvel mais uma proporção como buffer; a linha de stop-loss descendente é a média móvel menos uma proporção como buffer. Isso permite uma perda de stop imediata quando os preços se revertem.

As condições de entrada são longas quando os preços atravessam a linha de stop loss ascendente de baixo para cima; curtas quando os preços atravessam a linha de stop loss descendente de cima para baixo.

Análise das vantagens

A maior vantagem desta estratégia é que, ao combinar várias médias móveis, a precisão do julgamento da tendência pode ser melhorada e os sinais falsos podem ser reduzidos. Ao mesmo tempo, a linha de stop loss da estratégia muda dinamicamente com base na média móvel, que pode ajustar em tempo real e responder a eventos repentinos.

Além disso, em comparação com as estratégias de indicador único, esta estratégia combina as vantagens do rastreamento de tendências e estratégias de avanço.

Análise de riscos

O principal risco desta estratégia é que a configuração da linha de stop loss pode ser muito frouxa para parar a perda no tempo. Isso ocorre porque a taxa de retração da linha de stop loss é fixa, se houver uma mudança violenta no mercado, a linha de stop loss não pode ser atualizada no tempo, o que pode levar a perdas maiores.

Além disso, a média móvel em si tem alta histerese e não pode reagir imediatamente às mudanças de preço.

Orientações de otimização

A estratégia pode ser otimizada nos seguintes aspectos:

  1. Ensaiar diferentes definições de parâmetros para os rácios da linha de stop loss para encontrar melhores combinações de parâmetros;

  2. Tentar fazer com que a linha de stop loss mude dinamicamente de acordo com o grau de flutuação do mercado;

  3. Aumentar outros indicadores de avaliação, introduzir mais variáveis na base de stop loss para melhorar a adaptabilidade da estratégia;

  4. Otimizar os parâmetros do ciclo da média móvel para encontrar a melhor configuração do ciclo para suavizar os preços.

Resumo

Em geral, esta estratégia é bastante robusta, combinando várias médias móveis para determinar a direção da tendência e projetando um mecanismo de stop loss dinâmico que visa seguir as tendências. As vantagens são que pode reduzir sinais falsos, controlar riscos através de stop loss; A desvantagem é que a linha de stop loss pode ser definida muito larga para parar a perda rapidamente. O próximo passo para otimizar a estratégia deve se concentrar no design da linha de stop loss para torná-la ajustável dinamicamente de acordo com as mudanças do mercado.

/*backtest
start: 2023-02-22 00:00:00
end: 2024-02-28 00:00:00
period: 1d
basePeriod: 1h
exchanges: [{"eid":"Futures_Binance","currency":"BTC_USDT"}]
*/

//@version=5
strategy('Atlantean Trend Signal BUY SELL Strategy', overlay=true)

ma_length = input.int(title='Moving Average Length', minval=1, defval=3)
percent = input.float(3.3, 'STOP LOSS Percent', step=0.1, minval=0)
src = input(title='Source', defval=close)
mav = input.string(title="Moving Average Type", defval="KAMA", options=["SMA", "EMA", "WMA", "DEMA", "TMA", "VAR", "WWMA", "ZLEMA", "TSF", "HULL", "TILL", "KAMA"])
T3a1 = 0.7
_type = false //input(false, title='Activate Moving Average Screening Mode')
_type1 = false //input(false, title='Activate Moving Average Color Change Screening Mode')
activateScreener = input.bool(false, title="Activate Screener?")
showsignallabels = input(title='Show Signal Labels?', defval=true)

Var_Func(src, ma_length) =>
    valpha = 2 / (ma_length + 1)
    vud1 = src > src[1] ? src - src[1] : 0
    vdd1 = src < src[1] ? src[1] - src : 0
    vUD = math.sum(vud1, 9)
    vDD = math.sum(vdd1, 9)
    vCMO = nz((vUD - vDD) / (vUD + vDD))
    VAR = 0.0
    VAR := nz(valpha * math.abs(vCMO) * src) + (1 - valpha * math.abs(vCMO)) * nz(VAR[1])
    VAR

VAR = Var_Func(src, ma_length)
DEMA = 2 * ta.ema(src, ma_length) - ta.ema(ta.ema(src, ma_length), ma_length)

Wwma_Func(src, ma_length) =>
    wwalpha = 1 / ma_length
    WWMA = 0.0
    WWMA := wwalpha * src + (1 - wwalpha) * nz(WWMA[1])
    WWMA

WWMA = Wwma_Func(src, ma_length)

// KAMA Calculation
Kama_Func(src, ma_length) =>
    xvnoise = math.abs(src - src[1])
    nfastend = 0.666
    nslowend = 0.0645
    nsignal = math.abs(src - src[ma_length])
    nnoise = math.sum(xvnoise, ma_length)
    nefratio = nnoise != 0 ? nsignal / nnoise : 0
    nsmooth = math.pow(nefratio * (nfastend - nslowend) + nslowend, 2)
    nAMA = 0.0
    nAMA := nz(nAMA[1]) + nsmooth * (src - nz(nAMA[1]))
    nAMA

Zlema_Func(src, ma_length) =>
    zxLag = ma_length / 2 == math.round(ma_length / 2) ? ma_length / 2 : (ma_length - 1) / 2
    zxEMAData = src + src - src[zxLag]
    ZLEMA = ta.ema(zxEMAData, ma_length)
    ZLEMA

ZLEMA = Zlema_Func(src, ma_length)

Tsf_Func(src, ma_length) =>
    lrc = ta.linreg(src, ma_length, 0)
    lrc1 = ta.linreg(src, ma_length, 1)
    lrs = lrc - lrc1
    TSF = ta.linreg(src, ma_length, 0) + lrs
    TSF

TSF = Tsf_Func(src, ma_length)

HMA = ta.wma(2 * ta.wma(src, ma_length / 2) - ta.wma(src, ma_length), math.round(math.sqrt(ma_length)))

T3e1 = ta.ema(src, ma_length)
T3e2 = ta.ema(T3e1, ma_length)
T3e3 = ta.ema(T3e2, ma_length)
T3e4 = ta.ema(T3e3, ma_length)
T3e5 = ta.ema(T3e4, ma_length)
T3e6 = ta.ema(T3e5, ma_length)
T3c1 = -T3a1 * T3a1 * T3a1
T3c2 = 3 * T3a1 * T3a1 + 3 * T3a1 * T3a1 * T3a1
T3c3 = -6 * T3a1 * T3a1 - 3 * T3a1 - 3 * T3a1 * T3a1 * T3a1
T3c4 = 1 + 3 * T3a1 + T3a1 * T3a1 * T3a1 + 3 * T3a1 * T3a1
T3 = T3c1 * T3e6 + T3c2 * T3e5 + T3c3 * T3e4 + T3c4 * T3e3

getMA(src, ma_length) =>
    ma = 0.0
    ma := switch mav
        'SMA' => ta.sma(src, ma_length)
        'EMA' => ta.ema(src, ma_length)
        'WMA' => ta.wma(src, ma_length)
        'DEMA' => DEMA
        'TMA' => ta.sma(ta.sma(src, math.ceil(ma_length / 2)), math.floor(ma_length / 2) + 1)
        'VAR' => VAR
        'WWMA' => WWMA
        'ZLEMA' => ZLEMA
        'TSF' => TSF
        'HULL' => HMA
        'TILL' => T3
        'KAMA' => Kama_Func(src, ma_length)
    ma
ALL = getMA(src, ma_length)
exMov = ALL
fark = exMov * percent * 0.01
longStop = exMov - fark
longStopPrev = nz(longStop[1], longStop)
longStop := exMov > longStopPrev ? math.max(longStop, longStopPrev) : longStop
shortStop = exMov + fark
shortStopPrev = nz(shortStop[1], shortStop)
shortStop := exMov < shortStopPrev ? math.min(shortStop, shortStopPrev) : shortStop
dir = 1
dir := nz(dir[1], dir)
dir := dir == -1 and exMov > shortStopPrev ? 1 : dir == 1 and exMov < longStopPrev ? -1 : dir
MOST = dir == 1 ? longStop : shortStop
cro = _type and _type1 ? ta.crossover(exMov, exMov[1]) : _type ? ta.crossover(close, exMov) : ta.crossover(exMov, MOST)
cru = _type and _type1 ? ta.crossunder(exMov, exMov[1]) : _type ? ta.crossunder(close, exMov) : ta.crossunder(exMov, MOST)
direction = 0
direction := cro ? 1 : cru ? -1 : direction[1]
col1 = exMov > exMov[1]
col3 = exMov < exMov[1]
colorM = col1 and _type and _type1 ? color.rgb(14, 241, 52) : col3 and _type and _type1 ? color.red : color.new(#00bcd4, 0)
if (cro)
    strategy.entry('LONG', strategy.long)
if (cru)
    strategy.close('LONG')

plot(_type ? na : MOST, color=color.new(color.maroon, 0), linewidth=3, title='MOST')
plot(exMov, color=colorM, linewidth=2, title='exMov')
plotshape(cro and showsignallabels, title='BUY', text='BUY', location=location.belowbar, style=shape.labelup, size=size.tiny, color=color.new(#00bcd4, 0), textcolor=color.new(color.white, 0))
plotshape(cru and showsignallabels, title='SELL', text='SELL', location=location.abovebar, style=shape.labeldown, size=size.tiny, color=color.new(#e91e63, 0), textcolor=color.new(color.white, 0))
Mais.

2019 FMZ - Todos os direitos reservados