O recurso está a ser carregado... Carregamento...

Estratégia de negociação de canal de média móvel dupla

Autora:ChaoZhang, Data: 2024-02-29 14:54:25
Tags:

Resumo

A estratégia de negociação de canal de média móvel dupla é uma estratégia de negociação de tendência que rastreia cruzes entre médias móveis duplas. A estratégia usa a média móvel exponencial (EMA) e a média móvel ponderada (WMA) como indicadores de sinal de negociação. Quando a EMA de curto prazo cruza acima da WMA de longo prazo, a estratégia fica longa.

Estratégia lógica

Os sinais de negociação desta estratégia vêm da cruz de ouro e da cruz da morte entre a EMA de curto prazo de 10 períodos e a WMA de longo prazo de 20 períodos. Quando a EMA de curto prazo cruza acima da WMA de longo prazo, isso indica que o mercado está se revertendo, portanto, indo longo. Quando a EMA de curto prazo cruza abaixo da WMA de longo prazo, isso indica que o mercado está se revertendo, portanto, indo curto.

Após determinar a direção da negociação, a estratégia define o stop loss abaixo ou acima do preço de entrada por 1 período ATR, com dois lucros - o primeiro take profit é definido em 1 ATR acima ou abaixo do preço de entrada, e o segundo take profit é definido em 2 ATRs acima ou abaixo do preço de entrada. Quando o primeiro take profit é acionado, 50% da posição será fechada. A posição restante continuará correndo em direção ao segundo take profit ou com um stop loss final.

A lógica de stop loss de rastreamento - será ativada quando o preço mais alto ou o preço mais baixo atingir o primeiro nível de lucro.

Vantagem

A estratégia utiliza o recurso de redução de ruído de suavização dupla das médias móveis para filtrar efetivamente as flutuações aleatórias no mercado e identificar sinais de tendência de médio a longo prazo, evitando assim ser pego em whipssaws.

Riscos

As próprias médias móveis apresentam maior atraso, o que representa o risco de sinais perdidos.

A configuração do stop loss é um componente importante da estratégia. Se o stop loss for muito pequeno, ele é propenso a ser atingido pelo ruído do mercado.

Além disso, quando o mercado flutua violentamente, o trailing stop pode não funcionar muito bem na proteção.

Orientações de otimização

Teste EMAs e WMAs com parâmetros diferentes para encontrar a combinação ideal de parâmetros.
O valor da posição em risco deve ser calculado de acordo com o método de classificação da posição em risco.
Ensaiar os efeitos da parada parcial e da parada completa.
Introduzir outros indicadores de filtragem de sinais para ajudar a EMA e a WMA, de modo a melhorar a qualidade do sinal.

Resumo

Em geral, a estratégia de negociação de canal de média móvel dupla é relativamente robusta e tem um bom desempenho nos mercados de tendência. Ao otimizar parâmetros, mecanismos de stop loss e melhorar a qualidade do sinal, o desempenho comercial real desta estratégia pode ser ainda melhorado.

/*backtest
start: 2024-01-29 00:00:00
end: 2024-02-28 00:00:00
period: 3h
basePeriod: 15m
exchanges: [{"eid":"Futures_Binance","currency":"BTC_USDT"}]
*/

// This source code is subject to the terms of the Mozilla Public License 2.0 at https://mozilla.org/MPL/2.0/
// © gpadihar

//@version=4
strategy("SL1 Pips after TP1 (MA)", commission_type=strategy.commission.cash_per_order, overlay=true)

// Strategy
Buy  = input(true)
Sell = input(true)

// Date Range
start_year    = input(title='Start year'   ,defval=2020)
start_month   = input(title='Start month'  ,defval=1)
start_day     = input(title='Start day'    ,defval=1)
start_hour    = input(title='Start hour'   ,defval=0)
start_minute  = input(title='Start minute' ,defval=0)
end_time      = input(title='set end time?',defval=false)
end_year      = input(title='end year'     ,defval=3019)
end_month     = input(title='end month'    ,defval=12)
end_day       = input(title='end day'      ,defval=31)
end_hour      = input(title='end hour'     ,defval=23)
end_minute    = input(title='end minute'   ,defval=59)

// MA
ema_period = input(title='EMA period',defval=10)
wma_period = input(title='WMA period',defval=20)
ema        = ema(close,ema_period)
wma        = wma(close,wma_period)

// Entry Condition
buy =
 crossover(ema,wma) and
 nz(strategy.position_size) == 0 and Buy and
 time > timestamp(start_year, start_month, start_day, start_hour, start_minute) and
 (end_time?(time < timestamp(end_year, end_month, end_day, end_hour, end_minute)):true)
 
sell =
 crossunder(ema,wma) and
 nz(strategy.position_size) == 0 and Sell and
 time > timestamp(start_year, start_month, start_day, start_hour, start_minute) and
 (end_time?(time < timestamp(end_year, end_month, end_day, end_hour, end_minute)):true)

// Pips
pip = input(20)*10*syminfo.mintick

// Trading parameters //
var bool  LS  = na
var bool  SS  = na
var float EP  = na
var float TVL = na
var float TVS = na
var float TSL = na
var float TSS = na
var float TP1 = na
var float TP2 = na
var float SL1 = na
var float SL2 = na

if buy or sell and strategy.position_size == 0
    EP  := close
    SL1 := EP - pip     * (sell?-1:1)
    SL2 := EP - pip     * (sell?-1:1)
    TP1 := EP + pip     * (sell?-1:1)
    TP2 := EP + pip * 2 * (sell?-1:1) 
   
// current trade direction    
LS := buy  or strategy.position_size > 0
SS := sell or strategy.position_size < 0

// adjust trade parameters and trailing stop calculations
TVL := max(TP1,open) - pip[1]
TVS := min(TP1,open) + pip[1]
TSL := open[1] > TSL[1] ? max(TVL,TSL[1]):TVL 
TSS := open[1] < TSS[1] ? min(TVS,TSS[1]):TVS

if LS and high > TP1
    if open <= TP1
        SL2:=min(EP,TSL)
    
if SS and low < TP1
    if open >= TP1
        SL2:=max(EP,TSS)

// Closing conditions
close_long  = LS and open < SL2
close_short = SS and open > SL2

// Buy
strategy.entry("buy"  , strategy.long, when=buy and not SS)
strategy.exit ("exit1", from_entry="buy", stop=SL1, limit=TP1, qty_percent=50)
strategy.exit ("exit2", from_entry="buy", stop=SL2, limit=TP2)

// Sell
strategy.entry("sell" , strategy.short, when=sell and not LS)
strategy.exit ("exit3", from_entry="sell", stop=SL1, limit=TP1, qty_percent=50)
strategy.exit ("exit4", from_entry="sell", stop=SL2, limit=TP2)

// Plots
a=plot(strategy.position_size >  0 ? SL1 : na, color=#dc143c, style=plot.style_linebr)
b=plot(strategy.position_size <  0 ? SL1 : na, color=#dc143c, style=plot.style_linebr) 
c=plot(strategy.position_size >  0 ? TP1 : na, color=#00ced1, style=plot.style_linebr) 
d=plot(strategy.position_size <  0 ? TP1 : na, color=#00ced1, style=plot.style_linebr) 
e=plot(strategy.position_size >  0 ? TP2 : na, color=#00ced1, style=plot.style_linebr) 
f=plot(strategy.position_size <  0 ? TP2 : na, color=#00ced1, style=plot.style_linebr) 
g=plot(strategy.position_size >= 0 ? na  : EP, color=#ffffff, style=plot.style_linebr) 
h=plot(strategy.position_size <= 0 ? na  : EP, color=#ffffff, style=plot.style_linebr) 

plot(ema,title="ema",color=#fff176)
plot(wma,title="wma",color=#00ced1)

Mais.