O recurso está a ser carregado... Carregamento...

Negociação de momento com estratégia de cruzamento de média móvel dupla

Autora:ChaoZhang, Data: 2024-04-01 11:53:14
Tags:

Resumo

Esta estratégia emprega as médias móveis exponenciais (EMA) de 8 períodos e 21 períodos para identificar mudanças nas tendências do mercado. Um sinal de compra é gerado quando a EMA de curto prazo cruza acima da EMA de longo prazo de baixo, enquanto um sinal de venda é gerado quando a EMA de curto prazo cruza abaixo da EMA de longo prazo de cima. A estratégia também incorpora três baixas altas consecutivas (HLs) e três baixas altas consecutivas (LHs) como confirmação adicional das inversões de tendência. Além disso, os níveis de stop-loss e take-profit são definidos para gerenciar o risco e bloquear os lucros.

Princípios de estratégia

Calcular as EMAs de 8 e 21 períodos para identificar a direção principal da tendência.
Identificar três mínimos superiores consecutivos e três máximos inferiores consecutivos como sinais iniciais de reversões potenciais da tendência.
Gerenciar um sinal de compra quando a EMA de 8 períodos cruzar acima da EMA de 21 períodos e ocorrer uma ruptura HL; gerar um sinal de venda quando a EMA de 8 períodos cruzar abaixo da EMA de 21 períodos e ocorrer uma ruptura LH.
Estabelecer o nível de stop-loss em 5% do preço de entrada e o nível de take-profit em 16% do preço de entrada para gerir o risco e bloquear os lucros.
Fechar a posição e abrir uma posição inversa quando um sinal oposto aparecer.

Vantagens da estratégia

Combina EMAs e padrões de ação de preços (HLs e LHs) para confirmar tendências, aumentando a confiabilidade do sinal.
Estabelece níveis claros de stop-loss e take-profit, ajudando a gerir o risco e a bloquear os lucros.
Aplicável a vários prazos e mercados diferentes, oferecendo um certo nível de versatilidade.
Lógica clara, fácil de entender e implementar.

Riscos estratégicos

Em mercados instáveis, os cruzamento frequentes podem levar a múltiplos sinais falsos, resultando em perdas.
Os níveis fixos de stop-loss e take-profit podem não se adaptar bem às diferentes condições de mercado, levando a custos de oportunidade potenciais ou a perdas maiores.
A estratégia baseia-se em dados históricos e pode não se adaptar bem a eventos súbitos ou alterações fundamentais.

Orientações para a otimização da estratégia

Introduzir mecanismos adaptativos de stop-loss e take-profit, tais como o ajustamento dos níveis com base na volatilidade (por exemplo, ATR), para melhor adaptar-se às diferentes condições de mercado.
Incorporar outros indicadores ou fatores, como volume, índice de força relativa (RSI), etc., para filtrar ainda mais os sinais e melhorar a confiabilidade.
Otimizar os parâmetros (por exemplo, períodos de EMA, percentagens de stop-loss e take-profit) para encontrar a combinação de melhor desempenho para mercados ou instrumentos específicos.
Considerar a introdução de medidas de gestão do risco, tais como o dimensionamento das posições, para controlar a exposição ao risco das operações individuais.

Resumo

Esta estratégia utiliza o cruzamento de EMAs de 8 períodos e 21 períodos, combinados com padrões de preços HL e LH, para identificar inversões de tendência e gerar sinais de negociação. Regras claras de stop-loss e take-profit ajudam a gerenciar o risco e bloquear os lucros. No entanto, a estratégia pode gerar sinais falsos em mercados agitados e níveis fixos de stop-loss e take-profit podem não se adaptar bem a diferentes condições de mercado. Para melhorar ainda mais, considere a introdução de stop-loss e take-profit adaptativos, incorporando outros indicadores, otimizando parâmetros e introduzindo medidas de gerenciamento de risco.

/*backtest
start: 2023-03-26 00:00:00
end: 2024-03-31 00:00:00
period: 1d
basePeriod: 1h
exchanges: [{"eid":"Futures_Binance","currency":"BTC_USDT"}]
*/

//@version=5
strategy('Trend Following 8&21EMA with strategy tester [ukiuro7]', overlay=true, process_orders_on_close=true, calc_on_every_tick=true, initial_capital = 10000)

//INPUTS
lh3On = true
hl3On = true
emaOn = input(title='105ema / 30min', defval=true) 
assistantOn = input(title='Assistant', defval=true)
textOn = input(title='Text', defval=true)

showRiskReward = input.bool(true, title='Show Risk/Reward Area', group="TP/SL")
stopPerc = input.float(5.0, step=0.1, minval=0.1, title='Stop-Loss %:',group="TP/SL") / 100
tpPerc = input.float(16.0, step=0.1, minval=0.1, title='Take-Profit %:',group="TP/SL") / 100

backtestFilter = input(false, title='Backtest Entries to Date Range',group="Backtest Date Range")
i_startTime = input(defval=timestamp('01 Jan 2022 00:00'), inline="b_1", title='Start',group="Backtest Date Range")
i_endTime = input(defval=timestamp('01 Jan 2029 00:00'), inline="b_1", title='End',group="Backtest Date Range")
inDateRange = true

message_long_entry = input.string(title='Alert Msg: LONG Entry', defval ='', group='Alert Message')
message_short_entry = input.string(title='Alert Msg: SHORT Entry', defval='', group='Alert Message')
message_long_exit = input.string(title='Alert Msg: LONG SL/TP', defval='', group='Alert Message')
message_short_exit = input.string(title='Alert Msg: SHORT SL/TP', defval='', group='Alert Message')  

//CALCS
threeHigherLows() =>
    low[0] >= low[1] and low[1] >= low[2]

threeLowerHighs() =>
    high[2] >= high[1] and high[1] >= high[0]

breakHigher() =>
    padding = timeframe.isintraday ? .02 : .1
    high >= high[1] + padding

breakLower() =>
    padding = timeframe.isintraday ? .02 : .1
    low <= low[1] - padding

lh3 = threeLowerHighs() and lh3On
lh3bh = lh3[1] and breakHigher() and lh3On

hl3 = threeHigherLows() and hl3On
hl3bl = hl3[1] and breakLower() and hl3On

ema8 = ta.ema(close, 8)
ema21 = ta.ema(close, 21)

//VARS
var float longStop = na, var float longTp = na
var float shortStop = na, var float shortTp = na

//CONDS
isUptrend = ema8 >= ema21
isDowntrend = ema8 <= ema21
trendChanging = ta.cross(ema8, ema21)

buySignal = lh3bh and lh3[2] and lh3[3] and isUptrend and timeframe.isintraday
sellSignal = hl3bl and hl3[2] and hl3[3] and isDowntrend and timeframe.isintraday

goingDown = hl3 and isDowntrend and timeframe.isintraday
goingUp = lh3 and isUptrend and timeframe.isintraday

projectXBuy = trendChanging and isUptrend
projectXSell = trendChanging and isDowntrend

longCond = trendChanging and isUptrend and assistantOn
shortCond = trendChanging and isDowntrend and assistantOn

//STRATEGY
if shortCond and strategy.position_size > 0 and barstate.isconfirmed
    strategy.close('Long', comment='CLOSE LONG', alert_message=message_long_exit)

if longCond and strategy.position_size < 0 and barstate.isconfirmed
    strategy.close('Short', comment='CLOSE SHORT', alert_message=message_short_exit) 

if longCond and strategy.position_size <= 0 and barstate.isconfirmed and inDateRange
    longStop := close * (1 - stopPerc)
    longTp := close * (1 + tpPerc)
    strategy.entry('Long', strategy.long, comment='LONG', alert_message=message_long_entry)
    strategy.exit('Long Exit', 'Long', comment_loss="SL LONG", comment_profit = "TP LONG", stop=longStop, limit=longTp, alert_message=message_long_exit)

if shortCond and strategy.position_size >= 0 and barstate.isconfirmed and inDateRange
    shortStop := close * (1 + stopPerc)
    shortTp := close * (1 - tpPerc)
    strategy.entry('Short', strategy.short, comment='SHORT', alert_message=message_short_entry)
    strategy.exit('Short Exit', 'Short', comment_loss="SL SHORT", comment_profit="TP SHORT", stop=shortStop, limit=shortTp, alert_message=message_short_exit)

//PLOTS
plotshape(longCond, style=shape.triangleup, location=location.belowbar, color=color.new(color.green, 0), size=size.small, text='Buy')
plotshape(shortCond, style=shape.triangledown, location=location.abovebar, color=color.new(color.red, 0), size=size.small, text='Sell')
plotchar(trendChanging and isUptrend and close < open and assistantOn, char='!', location=location.abovebar, color=color.new(color.green, 0), size=size.small)

aa = plot(ema8, linewidth=3, color=color.new(color.green, 0), editable=true)
bb = plot(ema21, linewidth=3, color=color.new(color.red, 0), editable=true)
fill(aa, bb, color=isUptrend ? color.new(color.green,90) : color.new(color.red,90))
buyZone = isUptrend and lh3 and high < ema21 and timeframe.isintraday
sellZone = isDowntrend and hl3 and low > ema21 and timeframe.isintraday

L1 = plot(showRiskReward and strategy.position_size > 0 ? strategy.position_avg_price : na, color=color.new(color.green, 0), linewidth=1, style=plot.style_linebr, title='Long Entry Price')
L2 = plot(showRiskReward and strategy.position_size > 0 ? longTp : na, color=color.new(color.green, 0), linewidth=1, style=plot.style_linebr, title='Long TP Price')
L3 = plot(showRiskReward and strategy.position_size > 0 ? longStop : na, color=color.new(color.red, 0), linewidth=1, style=plot.style_linebr, title='Long Stop Price')

S1 = plot(showRiskReward and strategy.position_size < 0 ? strategy.position_avg_price : na, color=color.new(color.teal, 0), linewidth=1, style=plot.style_linebr, title='Short Entry Price')
S2 = plot(showRiskReward and strategy.position_size < 0 ? shortTp : na, color=color.new(color.teal, 0), linewidth=1, style=plot.style_linebr, title='Short TP Price')
S3 = plot(showRiskReward and strategy.position_size < 0 ? shortStop : na, color=color.new(color.maroon, 0), linewidth=1, style=plot.style_linebr, title='Short Stop Price')

fill(L1, L2, color=color.new(color.green, 90))
fill(L1, L3, color=color.new(color.red, 90))
fill(S1, S2, color=color.new(color.teal, 90))
fill(S1, S3, color=color.new(color.maroon, 90))

bgcolor(inDateRange == false ? color.new(color.red,90) : na, title="Backtest Off-Range")

Mais.