O recurso está a ser carregado... Carregamento...
  1. Quadrado
  2. O valor da posição em risco deve ser calculado em função do valor da posição em risco.

O valor da posição em risco deve ser calculado em função do valor da posição em risco.

Autora:ChaoZhang, Data: 2025-01-17 15:00:37
Tags:EMATRATR

Multi-EMA Trend Following Strategy with Dynamic Volatility Filter

Resumo

Esta estratégia é um sistema de negociação inteligente que combina tendência seguindo com a filtragem de volatilidade. Identifica tendências de mercado usando Média Móvel Exponencial (EMA), determina o tempo de entrada através de True Range (TR) e filtros de volatilidade dinâmica, e gerencia o risco usando um mecanismo dinâmico de stop-loss / take-profit baseado em volatilidade. A estratégia suporta dois modos de negociação: Scalp e Swing, que podem ser alternados de forma flexível com base em diferentes ambientes de mercado e estilos de negociação.

Princípios de estratégia

A lógica básica inclui os seguintes componentes-chave: 1. Identificação de tendências: utiliza a EMA de 50 períodos como filtro de tendências, tomando apenas posições longas acima da EMA e posições curtas abaixo da EMA. 2. Filtragem de volatilidade: Calcula a EMA de True Range (TR) e usa um coeficiente de filtragem ajustável (padrão 1.5) para filtrar o ruído do mercado. Condições de entrada: Combina a análise de três velas consecutivas, exigindo que o movimento do preço mostre características de continuidade e aceleração. 4. Stop-Loss/Take-Profit: definido com base na TR atual no modo de couro cabeludo e com base em altas/baixas anteriores no modo swing, alcançando uma gestão de risco dinâmica.

Vantagens da estratégia

  1. Forte adaptabilidade: adapta-se a diferentes ambientes de mercado através da combinação de filtragem dinâmica da volatilidade e de acompanhamento da tendência.
  2. Gerenciamento abrangente do risco: fornece mecanismos dinâmicos de stop-loss/take-profit para ambos os modos de negociação, permitindo uma seleção flexível com base nas características do mercado.
  3. Boa regulabilidade dos parâmetros: os parâmetros-chave, tais como o coeficiente de filtragem e o período de tendência, podem ser otimizados de acordo com as características dos instrumentos de negociação.
  4. Excelente visualização: fornece marcadores claros de sinal de compra / venda e exibições de nível de stop-loss / take-profit para fácil monitoramento comercial.

Riscos estratégicos

  1. Risco de reversão da tendência: podem ocorrer paradas consecutivas em pontos de virada da tendência.
  2. Risco de Falsa Breakout: Pode desencadear sinais falsos durante aumentos repentinos da volatilidade.
  3. Sensibilidade dos parâmetros: configurações inadequadas do coeficiente de filtragem podem levar a um número demasiado elevado ou demasiado reduzido de sinais.
  4. Impacto do deslizamento: Pode enfrentar deslizamentos significativos em mercados rápidos, afetando o desempenho da estratégia.

Orientações para a otimização da estratégia

  1. Adicionar Filtragem de Força da Tendência: Pode introduzir indicadores como o ADX para avaliar a força da tendência e melhorar a eficácia da tendência.
  2. Otimizar Stop-Loss/Take-Profit: Pode considerar a introdução de trailing stops para proteger mais lucros.
  3. Melhorar o modo swing: pode acrescentar mais condições específicas para a negociação swing para melhorar a capacidade de detenção a médio e longo prazo.
  4. Adicionar análise de volume: combinar as alterações de volume para confirmar a validade do rompimento.

Resumo

Esta estratégia constrói um sistema de negociação completo, combinando organicamente a tendência, a filtragem de volatilidade e o gerenciamento de risco dinâmico. Seus pontos fortes estão em sua adaptabilidade, risco controlável, ao mesmo tempo em que fornece um potencial de otimização significativo. Através de configurações adequadas de parâmetros e seleção apropriada do modo de negociação, a estratégia pode manter um desempenho estável em diferentes ambientes de mercado.

/*backtest
start: 2024-12-17 00:00:00
end: 2025-01-15 08:00:00
period: 2h
basePeriod: 2h
exchanges: [{"eid":"Futures_Binance","currency":"BTC_USDT","balance":49999}]
*/

// This Pine Script™ code is subject to the terms of the Mozilla Public License 2.0 at https://mozilla.org/MPL/2.0/
// © Creativ3mindz

//@version=5
strategy("Scalp Slayer (I)", overlay=true)

// Input Parameters
filterNumber = input.float(1.5, "Filter Number", minval=1.0, maxval=10.0, tooltip="Higher = More aggressive Filter, Lower = Less aggressive")
emaTrendPeriod = input.int(50, "EMA Trend Period", minval=1, tooltip="Period for the EMA used for trend filtering")
lookbackPeriod = input.int(20, "Lookback Period for Highs/Lows", minval=1, tooltip="Period for determining recent highs/lows")
colorTP = input.color(title='Take Profit Color', defval=color.orange)
colorSL = input.color(title='Stop Loss Color', defval=color.red)

// Inputs for visibility
showBuyLabels = input.bool(true, title="Show Buy Labels")
showSellLabels = input.bool(true, title="Show Sell Labels")

// Alert Options
alertOnCondition = input.bool(true, title="Alert on Condition Met", tooltip="Enable to alert when condition is met")

// Trade Mode Toggle
tradeMode = input.bool(false, title="Trade Mode (ON = Swing, OFF = Scalp)", tooltip="Swing-mode you can use your own TP/SL.")

// Calculations
tr = high - low
ema = filterNumber * ta.ema(tr, 50)
trendEma = ta.ema(close, emaTrendPeriod)  // Calculate the EMA for the trend filter

// Highest and lowest high/low within lookback period for swing logic
swingHigh = ta.highest(high, lookbackPeriod)
swingLow = ta.lowest(low, lookbackPeriod)

// Variables to track the entry prices and SL/TP levels
var float entryPriceLong = na
var float entryPriceShort = na
var float targetPriceLong = na
var float targetPriceShort = na
var float stopLossLong = na
var float stopLossShort = na
var bool tradeActive = false

// Buy and Sell Conditions with Trend Filter
buyCondition = close > trendEma and  // Buy only if above the trend EMA
      close[2] > open[2] and close[1] > open[1] and close > open and 
      (math.abs(close[2] - open[2]) > math.abs(close[1] - open[1])) and 
      (math.abs(close - open) > math.abs(close[1] - open[1])) and 
      close > close[1] and close[1] > close[2] and tr > ema

sellCondition = close < trendEma and  // Sell only if below the trend EMA
       close[2] < open[2] and close[1] < open[1] and close < open and 
       (math.abs(close[2] - open[2]) > math.abs(close[1] - open[1])) and 
       (math.abs(close - open) > math.abs(close[1] - open[1])) and 
       close < close[1] and close[1] < close[2] and tr > ema

// Entry Rules
if (buyCondition and not tradeActive)
    entryPriceLong := close  // Track entry price for long position
    stopLossLong := tradeMode ? ta.lowest(low, lookbackPeriod) : swingLow  // Scalping: recent low, Swing: lowest low of lookback period
    targetPriceLong := tradeMode ? close + tr : swingHigh  // Scalping: close + ATR, Swing: highest high of lookback period
    tradeActive := true

if (sellCondition and not tradeActive)
    entryPriceShort := close  // Track entry price for short position
    stopLossShort := tradeMode ? ta.highest(high, lookbackPeriod) : swingHigh  // Scalping: recent high, Swing: highest high of lookback period
    targetPriceShort := tradeMode ? close - tr : swingLow  // Scalping: close - ATR, Swing: lowest low of lookback period
    tradeActive := true

// Take Profit and Stop Loss Logic
signalBuyTPPrint = (not na(entryPriceLong) and close >= targetPriceLong)
signalSellTPPrint = (not na(entryPriceShort) and close <= targetPriceShort)

signalBuySLPrint = (not na(entryPriceLong) and close <= stopLossLong)
signalSellSLPrint = (not na(entryPriceShort) and close >= stopLossShort)

if (signalBuyTPPrint or signalBuySLPrint)
    entryPriceLong := na  // Reset entry price for long position
    targetPriceLong := na  // Reset target price for long position
    stopLossLong := na  // Reset stop-loss for long position
    tradeActive := false

if (signalSellTPPrint or signalSellSLPrint)
    entryPriceShort := na  // Reset entry price for short position
    targetPriceShort := na  // Reset target price for short position
    stopLossShort := na  // Reset stop-loss for short position
    tradeActive := false

// Plot Buy and Sell Labels with Visibility Conditions
plotshape(showBuyLabels and buyCondition, "Buy", shape.labelup, location=location.belowbar, color=color.green, text="BUY", textcolor=color.white, size=size.tiny)
plotshape(showSellLabels and sellCondition, "Sell", shape.labeldown, location=location.abovebar, color=color.red, text="SELL", textcolor=color.white, size=size.tiny)

// Plot Take Profit Flags
plotshape(showBuyLabels and signalBuyTPPrint, title="Take Profit (buys)", text="TP", style=shape.flag, location=location.abovebar, color=colorTP, textcolor=color.white, size=size.tiny)
plotshape(showSellLabels and signalSellTPPrint, title="Take Profit (sells)", text="TP", style=shape.flag, location=location.belowbar, color=colorTP, textcolor=color.white, size=size.tiny)

// Plot Stop Loss "X" Marker
plotshape(showBuyLabels and signalBuySLPrint, title="Stop Loss (buys)", text="X", style=shape.xcross, location=location.belowbar, color=colorSL, textcolor=color.white, size=size.tiny)
plotshape(showSellLabels and signalSellSLPrint, title="Stop Loss (sells)", text="X", style=shape.xcross, location=location.abovebar, color=colorSL, textcolor=color.white, size=size.tiny)

// Alerts

alertcondition(buyCondition and alertOnCondition, title="Buy Alert", message='{"content": "Buy {{ticker}} at {{close}}"}')
alertcondition(sellCondition and alertOnCondition, title="Sell Alert", message='{"content": "Sell {{ticker}} at {{close}}"}')
alertcondition(signalBuyTPPrint and alertOnCondition, title="Buy TP Alert", message='{"content": "Buy TP {{ticker}} at {{close}}"}')
alertcondition(signalSellTPPrint and alertOnCondition, title="Sell TP Alert", message='{"content": "Sell TP {{ticker}} at {{close}}"}')
alertcondition(signalBuySLPrint and alertOnCondition, title="Buy SL Alert", message='{"content": "Buy SL {{ticker}} at {{close}}"}')
alertcondition(signalSellSLPrint and alertOnCondition, title="Sell SL Alert", message='{"content": "Sell SL {{ticker}} at {{close}}"}')

if buyCondition
    strategy.entry("Enter Long", strategy.long)
else if sellCondition
    strategy.entry("Enter Short", strategy.short)
Relacionados
Mais.

2019 FMZ - Todos os direitos reservados