FMZ PINE اسکرپٹ Doc

const تار اقدار کے لی: [val1، val2،...]) اختیارات کی ایک فہرست میں سے منتخب کرنے کے لئے.

• tooltip(const string) اس تار کو جو صارف کو دکھایا جائے گا جب وہ ٹول ٹپ آئیکن پر ہوور کرے گا۔
• inline(const string) ایک لائن میں ایک ہی دلیل کا استعمال کرتے ہوئے تمام ان پٹ کالوں کو یکجا کرتا ہے۔ دلیل کے طور پر استعمال ہونے والی تار کو ظاہر نہیں کیا جاتا ہے۔ یہ صرف اسی لائن سے تعلق رکھنے والے ان پٹ کی نشاندہی کرنے کے لئے استعمال ہوتا ہے۔
• group(const string) ایک ہی گروپ دلیل سٹرنگ کا استعمال کرتے ہوئے تمام ان پٹ کے اوپر ہیڈر بناتا ہے۔ اس سٹرنگ کو ہیڈر کے متن کے طور پر بھی استعمال کیا جاتا ہے۔
• confirm(const bool) اگر درست ہے تو ، صارف سے چارٹ میں اشارے کو شامل کرنے سے پہلے ان پٹ ویلیو کی تصدیق کرنے کے لئے کہا جائے گا۔ ڈیفالٹ ویلیو غلط ہے۔

تبصرےان پٹ.ٹائم فریم فنکشن کا نتیجہ ہمیشہ متغیر کو تفویض کیا جانا چاہئے ، مندرجہ بالا مثالیں دیکھیں۔

یہ بھی ملاحظہ کریں input.bool input.int input.float input.string input.source input.color input

input.integer

دستیاب نہیں.

input.resolution

دستیاب نہیں.

ٹی اے

ta.alma

آرنو لیگو حرکت پذیر اوسط۔ یہ حرکت پذیر اوسط کے لئے وزن کے طور پر گوسین تقسیم کا استعمال کرتا ہے۔

ta.alma(series, length, offset, sigma) 

ta.alma(series, length, offset, sigma, floor) 

مثال

plot(ta.alma(close, 9, 0.85, 6))

// same on pine, but much less efficient
pine_alma(series, windowsize, offset, sigma) =>
    m = offset * (windowsize - 1)
    //m = math.floor(offset * (windowsize - 1)) // Used as m when math.floor=true
    s = windowsize / sigma
    norm = 0.0
    sum = 0.0
    for i = 0 to windowsize - 1
        weight = math.exp(-1 * math.pow(i - m, 2) / (2 * math.pow(s, 2)))
        norm := norm + weight
        sum := sum + series[windowsize - i - 1] * weight
    sum / norm
plot(pine_alma(close, 9, 0.85, 6))

واپسیآرنڈو لیگوکس منتقل اوسط.

دلائل

• series(سیریز int/float) عمل کرنے کے لئے اقدار کی سیریز.
• length(سیریز int) سلاخوں کی تعداد (لمبائی)
• offset(سادہ انٹ / فلوٹ) ہموار (1 کے قریب) اور ردعمل (0 کے قریب) کے درمیان تجارت کو کنٹرول کرتا ہے.
• sigma(سادہ int/float) ALMA کی ہموارتا کو تبدیل کرتا ہے۔ بڑا سگما زیادہ ہموار ALMA ہوتا ہے۔
• floor(سادہ بول) ایک اختیاری دلیل۔ ALMA کے حساب سے پہلے آفسیٹ حساب کتاب کو فرش کیا جاتا ہے یا نہیں کی وضاحت کرتا ہے۔ ڈیفالٹ ویلیو غلط ہے۔

یہ بھی ملاحظہ کریں ta.sma ta.ema ta.rma ta.wma ta.vwma ta.swma

ta.sma

اسما فنکشن چلتی اوسط لوٹاتا ہے، یعنی x کی آخری y اقدار کا مجموعہ، y سے تقسیم۔

ta.sma(source, length) 

مثال

plot(ta.sma(close, 15))

// same on pine, but much less efficient
pine_sma(x, y) =>
    sum = 0.0
    for i = 0 to y - 1
        sum := sum + x[i] / y
    sum
plot(pine_sma(close, 15))

واپسیکے سادہ چلتی اوسطsourceکے لئےlengthسلاخوں کے پیچھے.

دلائل

• source(سیریز int/float) عمل کرنے کے لئے اقدار کی سیریز.
• length(سیریز int) سلاخوں کی تعداد (لمبائی)

یہ بھی ملاحظہ کریں ta.ema ta.rma ta.wma ta.vwma ta.swma ta.alma

ta.cog

دانتوں کا مرکز (گھراؤ کا مرکز) اعداد و شمار اور فبونیکی گولڈن تناسب پر مبنی ایک اشارے ہے.

ta.cog(source, length) 

مثال

plot(ta.cog(close, 10))

// the same on pine
pine_cog(source, length) =>
    sum = math.sum(source, length)
    num = 0.0
    for i = 0 to length - 1
        price = source[i]
        num := num + price * (i + 1)
    -num / sum

plot(pine_cog(close, 10))

واپسیکشش ثقل کا مرکز.

دلائل

• source(سیریز int/float) عمل کرنے کے لئے اقدار کی سیریز.
• length(سیریز int) سلاخوں کی تعداد (لمبائی)

یہ بھی ملاحظہ کریں ta.stoch

ta.dev

سیریز اور اس کے ٹی ایس ایم اے کے مابین فرق کی پیمائش

ta.dev(source, length) 

مثال

plot(ta.dev(close, 10))

// the same on pine
pine_dev(source, length) =>
    mean = ta.sma(source, length)
    sum = 0.0
    for i = 0 to length - 1
        val = source[i]
        sum := sum + math.abs(val - mean)
    dev = sum/length
plot(pine_dev(close, 10))

واپسیکی انحرافsourceکے لئےlengthسلاخوں کے پیچھے.

دلائل

• source(سیریز int/float) عمل کرنے کے لئے اقدار کی سیریز.
• length(سیریز int) سلاخوں کی تعداد (لمبائی)

یہ بھی ملاحظہ کریں ta.variance ta.stdev

ta.stdev

ta.stdev(source, length, biased) 

مثال

plot(ta.stdev(close, 5))

//the same on pine
isZero(val, eps) => math.abs(val) <= eps

SUM(fst, snd) =>
    EPS = 1e-10
    res = fst + snd
    if isZero(res, EPS)
        res := 0
    else
        if not isZero(res, 1e-4)
            res := res
        else
            15

pine_stdev(src, length) =>
    avg = ta.sma(src, length)
    sumOfSquareDeviations = 0.0
    for i = 0 to length - 1
        sum = SUM(src[i], -avg)
        sumOfSquareDeviations := sumOfSquareDeviations + sum * sum

    stdev = math.sqrt(sumOfSquareDeviations / length)
plot(pine_stdev(close, 5))

واپسیمعیاری انحراف.

دلائل

• source(سیریز int/float) عمل کرنے کے لئے اقدار کی سیریز.
• length(سیریز int) سلاخوں کی تعداد (لمبائی)
• biased(سیریز bool) تعین کرتا ہے کہ کون سا تخمینہ استعمال کیا جانا چاہئے۔ اختیاری۔ ڈیفالٹ سچ ہے۔

تبصرےاگرbiasedسچ ہے تو، فنکشن کا حساب پورے آبادی کا ایک متعصب تخمینہ استعمال کرتے ہوئے کیا جائے گا، اگر غلط ہے تو - ایک نمونہ کا غیر متعصب تخمینہ.

یہ بھی ملاحظہ کریں ta.dev ta.variance

ta.ema

ایما فنکشن ایکسپونینشیل ویٹڈ چلتی اوسط واپس کرتا ہے۔ ایما میں وزن کے عوامل میں ایکسپونینشیل کمی واقع ہوتی ہے۔ اس کا حساب فارمولے کا استعمال کرتے ہوئے کیا جاتا ہے: ای ایم اے = الفا * ماخذ + (1 - الفا) * ای ایم اے [1] ، جہاں الفا = 2 / (لمبائی + 1) ۔

ta.ema(source, length) 

مثال

plot(ta.ema(close, 15))

//the same on pine
pine_ema(src, length) =>
    alpha = 2 / (length + 1)
    sum = 0.0
    sum := na(sum[1]) ? src : alpha * src + (1 - alpha) * nz(sum[1])
plot(pine_ema(close,15))

واپسیکے exponential چلتی اوسطsourceجہاں الفا = 2 / (لمبائی + 1)

دلائل

• source(سیریز int/float) عمل کرنے کے لئے اقدار کی سیریز.
• length(سادہ int) سلاخوں کی تعداد (لمبائی)

تبصرےبراہ کرم نوٹ کریں کہ اس متغیر/فنکشن کا استعمال اشارے کو دوبارہ پینٹ کرنے کا سبب بن سکتا ہے۔

یہ بھی ملاحظہ کریں ta.sma ta.rma ta.wma ta.vwma ta.swma ta.alma

ta.wma

wma فنکشن وزن شدہ چلتی اوسط واپس کرتا ہےsourceکے لئےlengthسلاخوں کو پیچھے ہٹائیں۔ WMA میں وزن کے عوامل ریاضیاتی ترقی میں کم ہوتے ہیں۔

ta.wma(source, length) 

مثال

plot(ta.wma(close, 15))

// same on pine, but much less efficient
pine_wma(x, y) =>
    norm = 0.0
    sum = 0.0
    for i = 0 to y - 1
        weight = (y - i) * y
        norm := norm + weight
        sum := sum + x[i] * weight
    sum / norm
plot(pine_wma(close, 15))

واپسیوزن شدہ چلتی اوسطsourceکے لئےlengthسلاخوں کے پیچھے.

دلائل

• source(سیریز int/float) عمل کرنے کے لئے اقدار کی سیریز.
• length(سیریز int) سلاخوں کی تعداد (لمبائی)

یہ بھی ملاحظہ کریں ta.sma ta.ema ta.rma ta.vwma ta.swma ta.alma

ta.swma

فکسڈ لمبائی کے ساتھ ہم آہنگی سے وزن شدہ چلتی اوسط: 4. وزن: [1/6، 2/6، 2/6، 1/6].

ta.swma(source)

مثال

plot(ta.swma(close))

// same on pine, but less efficient
pine_swma(x) =>
    x[3] * 1 / 6 + x[2] * 2 / 6 + x[1] * 2 / 6 + x[0] * 1 / 6
plot(pine_swma(close))

واپسیہم آہنگی سے وزن شدہ چلتی اوسط.

دلائل

• source(سیریز int/float) ماخذ سیریز.

یہ بھی ملاحظہ کریں ta.sma ta.ema ta.rma ta.wma ta.vwma ta.alma

ta.hma

ہما فنکشن ہل چلتی اوسط واپس کرتا ہے.

ta.hma(source, length)

مثال

src = input(defval=close, title="Source")
length = input(defval=9, title="Length")
hmaBuildIn = ta.hma(src, length)
plot(hmaBuildIn, title="Hull MA", color=#674EA7)

واپسیہول ماخذ کے لمبائی واپس سلاخوں کے لئے اوسط منتقل.

دلائل

• source(سیریز int/float) عمل کرنے کے لئے اقدار کی سیریز.
• length(سادہ int) بار کی تعداد.

یہ بھی ملاحظہ کریں ta.ema ta.rma ta.wma ta.vwma ta.sma

ta.rma

آر ایس آئی میں استعمال ہونے والا اوسط اوسط۔ یہ الفا = 1 / لمبائی کے ساتھ تیزی سے وزن والا اوسط اوسط ہے۔

ta.rma(source, length)

مثال

plot(ta.rma(close, 15))

//the same on pine
pine_rma(src, length) =>
  alpha = 1/length
  sum = 0.0
  sum := na(sum[1]) ? ta.sma(src, length) : alpha * src + (1 - alpha) * nz(sum[1])
plot(pine_rma(close, 15))

واپسیکے exponential چلتی اوسطsourceجہاں الفا = 1 /length.

دلائل

• source(سیریز int/float) عمل کرنے کے لئے اقدار کی سیریز.
• length(سادہ int) سلاخوں کی تعداد (لمبائی)

یہ بھی ملاحظہ کریں ta.sma ta.ema ta.wma ta.vwma ta.swma ta.alma ta.rsi

ta.rsi

رشتہ دار طاقت کا اشاریہ۔ اس کا حسابta.rma()کے اوپر اور نیچے کی تبدیلیوں کیsourceگزشتہlength bars.

ta.rsi(source, length)

مثال

plot(ta.rsi(close, 7))

// same on pine, but less efficient
pine_rsi(x, y) => 
    u = math.max(x - x[1], 0) // upward ta.change
    d = math.max(x[1] - x, 0) // downward ta.change
    rs = ta.rma(u, y) / ta.rma(d, y)
    res = 100 - 100 / (1 + rs)
    res

plot(pine_rsi(close, 7))

واپسیرشتہ دار طاقت کا اشاریہ (RSI)

دلائل

• source(سیریز int/float) عمل کرنے کے لئے اقدار کی سیریز.
• length(سادہ int) سلاخوں کی تعداد (لمبائی)

یہ بھی ملاحظہ کریں ta.rma

ta.tsi

حقیقی طاقت کا انڈیکس۔ یہ کسی مالیاتی آلہ کی بنیادی رفتار کے چلتے ہوئے اوسط کا استعمال کرتا ہے۔

ta.tsi(source, short_length, long_length)

واپسیحقیقی طاقت انڈیکس. ایک قدر کی حد میں [-1، 1].

دلائل

• source(سیریز int/float) ماخذ سیریز.
• short_lengthمختصر لمبائی.
• long_lengthلمبی لمبائی.

ta.roc

فنکشن roc (تبدیلی کی شرح) موجودہ قدر کے درمیان فرق دکھاsourceاور قدرsourceکہ تھاlengthدن پہلے. یہ فارمولے کی طرف سے شمار کیا جاتا ہے: 100 * تبدیلی ((src، لمبائی) / src[لمبائی].

ta.roc(source, length)

واپسیتبدیلی کی شرحsourceکے لئےlengthسلاخوں کے پیچھے.

دلائل

• source(سیریز int/float) عمل کرنے کے لئے اقدار کی سیریز.
• length(سیریز int) سلاخوں کی تعداد (لمبائی)

ta.range

ایک سیریز میں کم از کم اور زیادہ سے زیادہ اقدار کے درمیان فرق واپس کرتا ہے.

ta.range(source, length)

واپسیسیریز میں کم از کم اور زیادہ سے زیادہ اقدار کے درمیان فرق.

دلائل

• source(سیریز int/float) عمل کرنے کے لئے اقدار کی سیریز.
• length(سیریز int) سلاخوں کی تعداد (لمبائی)

ta.macd

ایم اے سی ڈی (متحرک اوسط تبادلہ / تغیر) ۔ اس کا مقصد اسٹاک کی قیمت میں رجحان کی طاقت ، سمت ، رفتار اور مدت میں تبدیلیوں کا انکشاف کرنا ہے۔

ta.macd(source, fastlen, slowlen, siglen) 

مثال

[macdLine, signalLine, histLine] = ta.macd(close, 12, 26, 9)
plot(macdLine, color=color.blue)
plot(signalLine, color=color.orange)
plot(histLine, color=color.red, style=plot.style_histogram)

اگر آپ کو صرف ایک قدر کی ضرورت ہے تو ، اس طرح کے پلیس ہولڈرز _ استعمال کریں:

مثال

[_, signalLine, _] = ta.macd(close, 12, 26, 9)
plot(signalLine, color=color.orange)

واپسیتین MACD سیریز کا ٹوپل: MACD لائن، سگنل لائن اور ہسٹوگرام لائن۔

دلائل

• source(سیریز int/float) عمل کرنے کے لئے اقدار کی سیریز.
• fastlen(سادہ int) تیز رفتار لمبائی دلیل.
• slowlen(سادہ int) سست لمبائی دلیل.
• siglen(سادہ int) سگنل لمبائی دلیل.

یہ بھی ملاحظہ کریں ta.sma ta.ema

ta.mode

سیریز کا موڈ لوٹاتا ہے۔ اگر ایک ہی تعدد کے ساتھ کئی اقدار ہیں تو ، یہ سب سے چھوٹی قدر لوٹاتا ہے۔

ta.mode(source, length)

واپسیسیریز کا موڈ.

دلائل

• source(سیریز int/float) عمل کرنے کے لئے اقدار کی سیریز.
• length(سیریز int) سلاخوں کی تعداد (لمبائی)

ta.median

سیریز کا میڈین لوٹاتا ہے۔

ta.median(source, length) 

واپسیسیریز کا میڈین۔

دلائل

• source(سیریز int/float) عمل کرنے کے لئے اقدار کی سیریز.
• length(سیریز int) سلاخوں کی تعداد (لمبائی)

ta.linreg

لکیری رجسٹریشن وکر۔ ایک ایسی لائن جو صارف کے ذریعہ طے شدہ وقت کی مدت میں بیان کردہ قیمتوں کو بہترین فٹ بیٹھتی ہے۔ اس کا حساب کم سے کم مربع طریقہ استعمال کرتے ہوئے کیا جاتا ہے۔ اس فنکشن کا نتیجہ فارمولے کا استعمال کرتے ہوئے شمار کیا جاتا ہے: لائنریگ = انٹرسیپٹ + ڈیلپ * (لمبائی - 1 - آفسیٹ) ، جہاں انٹرسیپٹ اور ڈیلپ کم سے کم مربع طریقہ کے ساتھ شمار کردہ اقدار ہیںsource series.

ta.linreg(source, length, offset) 

واپسیلکیری رجعت وکر.

دلائل

• source(سیریز int/float) ماخذ سیریز.
• length(سیریز int)
• offset(سادہ int) آفسیٹ.

ta.bb

بولنگر بینڈ۔ بولنگر بینڈ ایک تکنیکی تجزیہ کا آلہ ہے جس کی وضاحت لائنوں کے ایک سیٹ کے ذریعہ کی جاتی ہے جس میں سیکیورٹی کی قیمت کے سادہ حرکت پذیر اوسط (ایس ایم اے) سے دو معیاری انحراف (مثبت اور منفی) دکھائے جاتے ہیں ، لیکن اسے صارف کی ترجیحات کے مطابق ایڈجسٹ کیا جاسکتا ہے۔

ta.bb(series, length, mult) 

مثال

[middle, upper, lower] = ta.bb(close, 5, 4)
plot(middle, color=color.yellow)
plot(upper, color=color.yellow)
plot(lower, color=color.yellow)

// the same on pine
f_bb(src, length, mult) =>
    float basis = ta.sma(src, length)
    float dev = mult * ta.stdev(src, length)
    [basis, basis + dev, basis - dev]

[pineMiddle, pineUpper, pineLower] = f_bb(close, 5, 4)

plot(pineMiddle)
plot(pineUpper)
plot(pineLower)

واپسیبولنگر بینڈ.

دلائل

• series(سیریز int/float) عمل کرنے کے لئے اقدار کی سیریز.
• length(سیریز int) سلاخوں کی تعداد (لمبائی)
• mult(سادہ int/float) معیاری انحراف کا عنصر.

یہ بھی ملاحظہ کریں ta.sma ta.stdev ta.kc

ta.bbw

بولنگر بینڈ کی چوڑائی۔ بولنگر بینڈ کی چوڑائی وسط بینڈ کے ذریعہ تقسیم شدہ اوپری اور نچلے بولنگر بینڈ کے درمیان فرق ہے۔

ta.bbw(series, length, mult) 

مثال

plot(ta.bbw(close, 5, 4), color=color.yellow)

// the same on pine
f_bbw(src, length, mult) =>
    float basis = ta.sma(src, length)
    float dev = mult * ta.stdev(src, length)
    ((basis + dev) - (basis - dev)) / basis

plot(f_bbw(close, 5, 4))

واپسیبولنگر بینڈ کی چوڑائی.

دلائل

• series(سیریز int/float) عمل کرنے کے لئے اقدار کی سیریز.
• length(سیریز int) سلاخوں کی تعداد (لمبائی)
• mult(سادہ int/float) معیاری انحراف کا عنصر.

یہ بھی ملاحظہ کریں ta.bb ta.sma ta.stdev

ta.cci

سی سی آئی (سامان چینل انڈیکس) کا حساب کسی سامان کی عام قیمت اور اس کے سادہ چلنے والے اوسط کے درمیان فرق کے طور پر کیا جاتا ہے ، جس میں عام قیمت کے اوسط مطلق انحراف کو تقسیم کیا جاتا ہے۔ انڈیکس کو زیادہ پڑھنے کے قابل اعداد و شمار فراہم کرنے کے لئے 0.015 کے الٹا عنصر کے ساتھ پیمانہ کیا جاتا ہے۔

ta.cci(source, length) 

واپسیلمبائی باروں کے لئے ذریعہ کی خام مال چینل انڈیکس واپس.

دلائل

• source(سیریز int/float) عمل کرنے کے لئے اقدار کی سیریز.
• length(سیریز int) سلاخوں کی تعداد (لمبائی)

ta.change

موجودہ قدر اور سابقہ قدر کے درمیان فرق، ماخذ - ماخذ [لمبائی]

ta.change(source, length) 

ta.change(source) 

واپسیگھٹانے کا نتیجہ۔

دلائل

• source(سیریز int/float) ماخذ سیریز.
• length(سیریز انٹ) موجودہ بار سے پچھلے بار میں آفسیٹ۔ اختیاری ، اگر نہیں دیا گیا ہے تو ، لمبائی = 1 استعمال کیا جاتا ہے۔

یہ بھی ملاحظہ کریں ta.mom ta.cross

ta.mom

رفتارsourceقیمت اورsourceقیمتlengthبار پہلے. یہ صرف ایک فرق ہے: ماخذ - ماخذ [لمبائی].

ta.mom(source, length) 

واپسیرفتارsourceقیمت اورsourceقیمتlengthسلاخوں پہلے.

دلائل

• source(سیریز int/float) عمل کرنے کے لئے اقدار کی سیریز.
• length(سیریز int) موجودہ بار سے پچھلے بار میں آفسیٹ.

یہ بھی ملاحظہ کریں ta.change

ta.cmo

چینڈ مومنٹم آسکیلیٹر۔ حالیہ منافع اور حالیہ نقصانات کے مجموعے کے درمیان فرق کا حساب لگاتا ہے اور پھر اسی مدت میں تمام قیمتوں کی نقل و حرکت کے مجموعے سے نتیجہ تقسیم کرتا ہے۔

ta.cmo(series, length) 

مثال

plot(ta.cmo(close, 5), color=color.yellow)

// the same on pine
f_cmo(src, length) =>
    float mom = ta.change(src)
    float sm1 = math.sum((mom >= 0) ? mom : 0.0, length)
    float sm2 = math.sum((mom >= 0) ? 0.0 : -mom, length)
    100 * (sm1 - sm2) / (sm1 + sm2)

plot(f_cmo(close, 5))

واپسیچینڈ مومنٹم اوسیلیٹر.

دلائل

• series(سیریز int/float) عمل کرنے کے لئے اقدار کی سیریز.
• length(سیریز int) سلاخوں کی تعداد (لمبائی)

یہ بھی ملاحظہ کریں ta.rsi ta.stoch math.sum

ta.percentile_linear_interpolation

دو قریب ترین صفوں کے درمیان لکیری مداخلت کے طریقہ کار کا استعمال کرتے ہوئے فیصد کا حساب لگاتا ہے.

ta.percentile_linear_interpolation(source, length, percentage) 

واپسیکے پی-ویں فیصدsourceسیریز کے لئےlengthسلاخوں کے پیچھے.

دلائل

• source(سیریز int/float) عمل کرنے کے لئے اقدار کی سیریز (ماخذ).
• length(سیریز int) واپس بار کی تعداد (لمبائی).
• percentage(سادہ int/float) فی صد، 0 سے لے کر 100 تک کا ایک عدد۔

تبصرےنوٹ کریں کہ اس طریقہ کار کا استعمال کرتے ہوئے حساب لگایا گیا فیصد ہمیشہ ان پٹ ڈیٹا سیٹ کا رکن نہیں ہوگا۔

یہ بھی ملاحظہ کریں ta.percentile_nearest_rank

ta.percentile_nearest_rank

قریبی درجہ کے طریقہ کار کا استعمال کرتے ہوئے فیصد کا حساب لگاتا ہے۔

ta.percentile_nearest_rank(source, length, percentage) 

واپسیکے پی-ویں فیصدsourceسیریز کے لئےlengthسلاخوں کے پیچھے.

دلائل

• source(سیریز int/float) عمل کرنے کے لئے اقدار کی سیریز (ماخذ).
• length(سیریز int) واپس بار کی تعداد (لمبائی).
• percentage(سادہ int/float) فی صد، 0 سے لے کر 100 تک کا ایک عدد۔

تبصرے100 بار سے کم لمبائی پر قریبی رینج کا طریقہ استعمال کرنے سے ایک ہی نمبر کو ایک فیصد سے زیادہ استعمال کیا جاسکتا ہے۔ قریبی درجہ کے طریقہ کار کا استعمال کرتے ہوئے حساب لگایا ایک فیصد ہمیشہ ان پٹ ڈیٹا سیٹ کا ایک رکن ہو گا. 100 ویں فیصد کو ان پٹ ڈیٹا سیٹ میں سب سے بڑی قیمت کے طور پر بیان کیا گیا ہے۔

یہ بھی ملاحظہ کریں ta.percentile_linear_interpolation

ta.percentrank

فی صد رینک اس کا فی صد ہے کہ کتنی پچھلی اقدار دی گئی سیریز کی موجودہ قدر سے کم یا مساوی تھی۔

ta.percentrank(source, length) 

واپسیفیصد درجہ بندیsourceکے لئےlengthسلاخوں کے پیچھے.

دلائل

• source(سیریز int/float) عمل کرنے کے لئے اقدار کی سیریز.
• length(سیریز int) سلاخوں کی تعداد (لمبائی)

ta.variance

تغیرات اس کی اوسط سے ایک سیریز کے مربع انحراف کی توقع ہے (ٹی ایس ایم اے) ، اور یہ غیر رسمی طور پر اندازہ لگاتا ہے کہ اعداد کا ایک مجموعہ ان کے اوسط سے کتنا پھیلا ہوا ہے۔

ta.variance(source, length, biased) 

واپسیکے تغیرsourceکے لئےlengthسلاخوں کے پیچھے.

دلائل

• source(سیریز int/float) عمل کرنے کے لئے اقدار کی سیریز.
• length(سیریز int) سلاخوں کی تعداد (لمبائی)
• biased(سیریز bool) تعین کرتا ہے کہ کون سا تخمینہ استعمال کیا جانا چاہئے۔ اختیاری۔ ڈیفالٹ سچ ہے۔

تبصرےاگرbiasedسچ ہے تو، فنکشن کا حساب پورے آبادی کا ایک متعصب تخمینہ استعمال کرتے ہوئے کیا جائے گا، اگر غلط ہے تو - ایک نمونہ کا غیر متعصب تخمینہ.

یہ بھی ملاحظہ کریں ta.dev ta.stdev

ta.tr

ta.tr(handle_na) 

واپسیسچائی کی حد۔ یہ ہے math.max ((اعلی - کم ، math.abs ((اعلی - قریب [1]) ، math.abs ((کم - قریب [1])).

دلائل

• handle_na(سادہ بول) NaN اقدار کو کس طرح سنبھالا جاتا ہے۔ اگر سچ ہے ، اور پچھلے دنs بند NaN ہے تو tr کا حساب موجودہ دن کے اعلی کم کے طور پر کیا جائے گا۔ بصورت دیگر (اگر غلط ہے) tr ایسے معاملات میں NaN واپس کردے گا۔ یہ بھی نوٹ کریں ، کہ ta.atr استعمال کرتا ہےta.tr(سچ)

تبصرے ta.tr(false)بالکل ایک ہی ہےta.tr.

یہ بھی ملاحظہ کریں ta.atr

ta.mfi

منی فلو انڈیکس۔ منی فلو انڈیکس (ایم ایف آئی) ایک تکنیکی آسکیلیٹر ہے جو کسی اثاثے میں زیادہ خریدنے یا زیادہ فروخت کی حالت کی نشاندہی کرنے کے لئے قیمت اور حجم کا استعمال کرتا ہے۔

ta.mfi(series, length) 

مثال

plot(ta.mfi(hlc3, 14), color=color.yellow)

// the same on pine
pine_mfi(src, length) =>
    float upper = math.sum(volume * (ta.change(src) <= 0.0 ? 0.0 : src), length)
    float lower = math.sum(volume * (ta.change(src) >= 0.0 ? 0.0 : src), length)
    mfi = 100.0 - (100.0 / (1.0 + upper / lower))
    mfi

plot(pine_mfi(hlc3, 14))

واپسیمنی فلو انڈیکس۔

دلائل

• series(سیریز int/float) عمل کرنے کے لئے اقدار کی سیریز.
• length(سیریز int) سلاخوں کی تعداد (لمبائی)

یہ بھی ملاحظہ کریں ta.rsi math.sum

ta.kc

Keltner Channels۔ Keltner Channel ایک تکنیکی تجزیہ اشارے ہے جو مرکزی حرکت پذیر اوسط لائن اور چینل لائنوں کو اوپر اور نیچے کے فاصلے پر دکھاتا ہے۔

ta.kc(series, length, mult) 

ta.kc(series, length, mult, useTrueRange) 

مثال

[middle, upper, lower] = ta.kc(close, 5, 4)
plot(middle, color=color.yellow)
plot(upper, color=color.yellow)
plot(lower, color=color.yellow)


// the same on pine
f_kc(src, length, mult, useTrueRange) =>
    float basis = ta.ema(src, length)
    float span = (useTrueRange) ? ta.tr : (high - low)
    float rangeEma = ta.ema(span, length)
    [basis, basis + rangeEma * mult, basis - rangeEma * mult]
    
[pineMiddle, pineUpper, pineLower] = f_kc(close, 5, 4, true)

plot(pineMiddle)
plot(pineUpper)
plot(pineLower)

واپسیKeltner چینلز.

دلائل

• series(سیریز int/float) عمل کرنے کے لئے اقدار کی سیریز.
• length(سادہ int) سلاخوں کی تعداد (لمبائی)
• mult(سادہ int/float) معیاری انحراف کا عنصر.
• useTrueRange(سادہ بول) ایک اختیاری دلیل۔ اگر True Range استعمال کیا جاتا ہے تو وضاحت کرتا ہے۔ ڈیفالٹ درست ہے۔ اگر قدر غلط ہے تو ، حد کا حساب (اعلی - کم) کے ساتھ کیا جائے گا۔

یہ بھی ملاحظہ کریں ta.ema ta.atr ta.bb

ta.kcw

Keltner چینلز کی چوڑائی۔ Keltner چینلز کی چوڑائی وسط چینل کی طرف سے تقسیم اوپری اور نچلے Keltner چینلز کے درمیان فرق ہے.

ta.kcw(series, length, mult) 

ta.kcw(series, length, mult, useTrueRange) 

مثال

plot(ta.kcw(close, 5, 4), color=color.yellow)

// the same on pine
f_kcw(src, length, mult, useTrueRange) =>
    float basis = ta.ema(src, length)
    float span = (useTrueRange) ? ta.tr : (high - low)
    float rangeEma = ta.ema(span, length)
    
    ((basis + rangeEma * mult) - (basis - rangeEma * mult)) / basis

plot(f_kcw(close, 5, 4, true))

واپسیKeltner چینلز چوڑائی.

دلائل

• series(سیریز int/float) عمل کرنے کے لئے اقدار کی سیریز.
• length(سادہ int) سلاخوں کی تعداد (لمبائی)
• mult(سادہ int/float) معیاری انحراف کا عنصر.
• useTrueRange(سادہ بول) ایک اختیاری دلیل۔ اگر True Range استعمال کیا جاتا ہے تو وضاحت کرتا ہے۔ ڈیفالٹ درست ہے۔ اگر قدر غلط ہے تو ، حد کا حساب (اعلی - کم) کے ساتھ کیا جائے گا۔

یہ بھی ملاحظہ کریں ta.kc ta.ema ta.atr ta.bb

ta.correlation

ارتباط کا گتانک۔ اس ڈگری کی وضاحت کرتا ہے جس میں دو سیریز ان کی ٹاسما اقدار سے انحراف کرتی ہیں۔

ta.correlation(source1, source2, length) 

واپسیرابطے کا گتانک

دلائل

• source1(سیریز int/float) ماخذ سیریز.
• source2(سیریز int/float) ہدف سیریز.
• length(سلسلہ int) لمبائی (باروں کی تعداد واپس).

یہ بھی ملاحظہ کریں request.security

ta.cross

ta.cross(source1, source2) 

واپسیسچ ہے اگر دو سیریز ایک دوسرے کو پار کر چکے ہیں، دوسری صورت میں غلط ہے.

دلائل

• source1(سیریز int/float) پہلی ڈیٹا سیریز۔
• source2(سیریز int/float) دوسرا ڈیٹا سیریز.

یہ بھی ملاحظہ کریں ta.change

ta.crossover

کےsource1سیریز کو اس طرح بیان کیا گیا ہے کہ اس نے پار کیا ہےsource2سیریز اگر، موجودہ بار پر، قدرsource1کی قدر سے زیادہ ہےsource2، اور پچھلے بار پر، کی قدرsource1کی قدر سے کم تھاsource2.

ta.crossover(source1, source2) 

واپسیسچ ہے اگرsource1پار کیاsource2دوسری صورت میں غلط.

دلائل

• source1(سیریز int/float) پہلی ڈیٹا سیریز۔
• source2(سیریز int/float) دوسرا ڈیٹا سیریز.

ta.crossunder

کےsource1-سیریز کے تحت کراسنگ کے طور پر مقرر کیا جاتا ہےsource2سیریز اگر، موجودہ بار پر، قدرsource1کی قدر سے کم ہےsource2، اور پچھلے بار پر، کی قدرsource1کی قدر سے زیادہ تھاsource2.

ta.crossunder(source1, source2) 

واپسیسچ ہے اگرsource1کے تحت پارsource2دوسری صورت میں غلط.

دلائل

• source1(سیریز int/float) پہلی ڈیٹا سیریز۔
• source2(سیریز int/float) دوسرا ڈیٹا سیریز.

ta.atr

فنکشن atr (اوسط حقیقی رینج) حقیقی رینج کا RMA لوٹاتا ہے۔ حقیقی رینج max ((high - low ، abs ((high - close [1]) ، abs ((low - close [1])) ہے۔

ta.atr(length) 

مثال

plot(ta.atr(14))

//the same on pine
pine_atr(length) =>
    trueRange = na(high[1])? high-low : math.max(math.max(high - low, math.abs(high - close[1])), math.abs(low - close[1]))
    //true range can be also calculated with ta.tr(true)
    ta.rma(trueRange, length)

plot(pine_atr(14))

واپسیاوسط حقیقی رینج (ATR)

دلائللمبائی (سادہ int) لمبائی (بار پیچھے کی تعداد).

یہ بھی ملاحظہ کریں ta.tr ta.rma

ta.sar

پیرابولک SAR (پیرابولک اسٹاپ اینڈ ریورس) ایک ایسا طریقہ ہے جو جے ویلس وائلڈر ، جونیئر نے تیار کیا ہے ، تاکہ تجارت شدہ سامان کی مارکیٹ قیمت کی سمت میں ممکنہ الٹ ملے۔

ta.sar(start, inc, max) 

مثال

plot(ta.sar(0.02, 0.02, 0.2), style=plot.style_cross, linewidth=3)

// The same on Pine
pine_sar(start, inc, max) =>
  var float result = na
  var float maxMin = na
  var float acceleration = na
  var bool isBelow = na
  bool isFirstTrendBar = false
  
  if bar_index == 1
    if close > close[1]
      isBelow := true
      maxMin := high
      result := low[1]
    else
      isBelow := false
      maxMin := low
      result := high[1]
    isFirstTrendBar := true
    acceleration := start
  
  result := result + acceleration * (maxMin - result)
  
  if isBelow
    if result > low
      isFirstTrendBar := true
      isBelow := false
      result := math.max(high, maxMin)
      maxMin := low
      acceleration := start
  else
    if result < high
      isFirstTrendBar := true
      isBelow := true
      result := math.min(low, maxMin)
      maxMin := high
      acceleration := start
      
  if not isFirstTrendBar
    if isBelow
      if high > maxMin
        maxMin := high
        acceleration := math.min(acceleration + inc, max)
    else
      if low < maxMin
        maxMin := low
        acceleration := math.min(acceleration + inc, max)
  
  if isBelow
    result := math.min(result, low[1])
    if bar_index > 1
      result := math.min(result, low[2])
    
  else
    result := math.max(result, high[1])
    if bar_index > 1
      result := math.max(result, high[2])
  
  result
  
plot(pine_sar(0.02, 0.02, 0.2), style=plot.style_cross, linewidth=3)

واپسیپیرابولک SAR.

دلائل

• start(سادہ int/float) شروع کریں.
• inc(سادہ int/float) اضافہ.
• max(سادہ int/float) زیادہ سے زیادہ.

ta.barssince

آخری بار شرط درست تھی کے بعد بار کی تعداد شمار کرتا ہے.

ta.barssince(condition) 

مثال

// get number of bars since last color.green bar
plot(ta.barssince(close >= open))

واپسیشرط درست تھی کے بعد بار کی تعداد.

تبصرےاگر موجودہ بار سے پہلے اس شرط کو کبھی پورا نہیں کیا گیا ہے تو ، فنکشن na لوٹاتا ہے۔ براہ کرم نوٹ کریں کہ اس متغیر/فنکشن کا استعمال اشارے کو دوبارہ پینٹ کرنے کا سبب بن سکتا ہے۔

یہ بھی ملاحظہ کریں ta.lowestbars ta.highestbars ta.valuewhen ta.highest ta.lowest

ta.cum

مجموعی (کل)sourceدوسرے الفاظ میں یہ تمام عناصر کا مجموعہ ہےsource.

ta.cum(source) 

واپسیمجموعی مجموعی سیریز

دلائل

• source(سیریز int/float)

یہ بھی ملاحظہ کریں math.sum

ta.dmi

ڈی ایم آئی فنکشن سمت کی نقل و حرکت انڈیکس ((ڈی ایم آئی) لوٹاتا ہے۔

ta.dmi(diLength, adxSmoothing) 

مثال

len = input.int(17, minval=1, title="DI Length")
lensig = input.int(14, title="ADX Smoothing", minval=1, maxval=50)
[diplus, diminus, adx] = ta.dmi(len, lensig)
plot(adx, color=color.red, title="ADX")
plot(diplus, color=color.blue, title="+DI")
plot(diminus, color=color.orange, title="-DI")

واپسیتین ڈی ایم آئی سیریز کا ٹوپل: مثبت سمت کی تحریک (+ ڈی آئی) ، منفی سمت کی تحریک (- ڈی آئی) اور اوسط سمت کی تحریک انڈیکس (ADX) ۔

دلائل

• diLength(سادہ int) DI مدت.
• adxSmoothing(سادہ int) ADX ہموار مدت.

یہ بھی ملاحظہ کریں ta.rsi ta.tsi ta.mfi

ta.falling

ٹیسٹ اگرsourceسیریز اب کے لئے گر رہا ہےlengthسلاخوں کی لمبائی

ta.falling(source, length) 

واپسیدرست اگر موجودہsourceقیمت کسی بھی پچھلے سے کم ہےsourceکے لئے قدرlengthسلاخوں واپس، جھوٹے دوسری صورت میں.

دلائل

• source(سیریز int/float) عمل کرنے کے لئے اقدار کی سیریز.
• length(سیریز int) سلاخوں کی تعداد (لمبائی)

یہ بھی ملاحظہ کریں ta.rising

ta.rising

ٹیسٹ اگرsourceسیریز اب کے لئے بڑھ رہی ہےlengthسلاخوں کی لمبائی

ta.rising(source, length) 

واپسیدرست اگر موجودہsourceاس سے پہلے کسی بھیsourceکے لئےlengthسلاخوں واپس، جھوٹے دوسری صورت میں.

دلائل

• source(سیریز int/float) عمل کرنے کے لئے اقدار کی سیریز.
• length(سیریز int) سلاخوں کی تعداد (لمبائی)

یہ بھی ملاحظہ کریں ta.falling

ta.pivothigh

یہ فنکشن محور کے اعلی نقطہ کی قیمت واپس کرتا ہے۔ اگر کوئی محور اعلی نقطہ نہیں تھا تو یہ NaN واپس کرتا ہے۔

ta.pivothigh(source, leftbars, rightbars) 

ta.pivothigh(leftbars, rightbars) 

مثال

leftBars = input(2)
rightBars=input(2)
ph = ta.pivothigh(leftBars, rightBars)
plot(ph, style=plot.style_cross, linewidth=3, color= color.red, offset=-rightBars)

واپسیپوائنٹ کی قیمت یا NaN.

دلائل

• source(سیریز int/float) ایک اختیاری دلیل۔ قدر کا حساب لگانے کے لئے ڈیٹا سیریز۔ High ڈیفالٹ کے مطابق۔
• leftbars(سیریز int/float) بائیں طاقت.
• rightbars(سیریز int / تیرتا) دائیں لمبائی.

تبصرےاگر دلیلیں leftbars یا rightbars سیریز ہیں تو آپ کو source متغیر کے لئے max_bars_back فنکشن استعمال کرنا چاہئے۔

ta.pivotlow

یہ فنکشن محور کے کم نقطہ کی قیمت واپس کرتا ہے۔ اگر کوئی محور کم نقطہ نہیں تھا تو یہ NaN واپس کرتا ہے۔

ta.pivotlow(source, leftbars, rightbars) 

ta.pivotlow(leftbars, rightbars) 

مثال

leftBars = input(2)
rightBars=input(2)
pl = ta.pivotlow(close, leftBars, rightBars)
plot(pl, style=plot.style_cross, linewidth=3, color= color.blue, offset=-rightBars)

واپسیپوائنٹ کی قیمت یا NaN.

دلائل

• source(سیریز int/float) ایک اختیاری دلیل۔ قدر کا حساب لگانے کے لئے ڈیٹا سیریز۔ Low ڈیفالٹ کے مطابق۔
• leftbars(سیریز int/float) بائیں طاقت.
• rightbars(سیریز int / تیرتا) دائیں لمبائی.

تبصرےاگر دلیلیں leftbars یا rightbars سیریز ہیں تو آپ کو source متغیر کے لئے max_bars_back فنکشن استعمال کرنا چاہئے۔

ta.highest

واپس بار کی ایک دی گئی تعداد کے لئے سب سے زیادہ قیمت.

ta.highest(source, length) 

ta.highest(length) 

واپسیسیریز میں سب سے زیادہ قیمت.

دلائل

• source(سیریز int/float) عمل کرنے کے لئے اقدار کی سیریز.
• length(سیریز int) سلاخوں کی تعداد (لمبائی)

تبصرےدو ارگ ورژن:sourceایک سلسلہ ہے اورlengthواپس بار کی تعداد ہے. ایک آرگ ورژن:lengthواپس سلاخوں کی تعداد ہے. الگورتھم ایک کے طور پر اعلی استعمال کرتا ہےsource series.

یہ بھی ملاحظہ کریں ta.lowest ta.lowestbars ta.highestbars ta.valuewhen ta.barssince

ta.highestbars

ایک مقررہ تعداد باروں کے لئے سب سے زیادہ قدر آفسیٹ.

ta.highestbars(source, length) 

ta.highestbars(length) 

واپسیسب سے زیادہ بار کے لئے آفسیٹ.

دلائل

• source(سیریز int/float) عمل کرنے کے لئے اقدار کی سیریز.
• length(سیریز int) سلاخوں کی تعداد (لمبائی)

تبصرےدو ارگ ورژن:sourceایک سلسلہ ہے اورlengthواپس بار کی تعداد ہے. ایک آرگ ورژن:lengthواپس سلاخوں کی تعداد ہے. الگورتھم ایک کے طور پر اعلی استعمال کرتا ہےsource series.

یہ بھی ملاحظہ کریں ta.lowest ta.highest ta.lowestbars ta.barssince ta.valuewhen

ta.stoch

اسٹوکاسٹک۔ اس کا حساب فارمولے کے ذریعہ کیا جاتا ہے: 100 * (قریب - کم ترین ((کم ، لمبائی)) / (اعلی ترین ((اعلی ، لمبائی) - کم ترین ((کم ، لمبائی)).

ta.stoch(source, high, low, length) 

واپسی Stochastic.

دلائل

• source(سیریز int/float) ماخذ سیریز.
• high(سیریز int/float) اعلی کی سیریز.
• low(سیریز int/float) کم کی سیریز.
• length(سلسلہ int) لمبائی (باروں کی تعداد واپس).

یہ بھی ملاحظہ کریں ta.cog

ta.supertrend

سپر ٹرینڈ اشارے۔ سپر ٹرینڈ ایک رجحان کی پیروی کرنے والا اشارہ ہے۔

ta.supertrend(factor, atrPeriod) 

مثال

//@version=5
indicator("Pine Script™ Supertrend")

[supertrend, direction] = ta.supertrend(3, 10)
plot(direction < 0 ? supertrend : na, "Up direction", color = color.green, style=plot.style_linebr)
plot(direction > 0 ? supertrend : na, "Down direction", color = color.red, style=plot.style_linebr)

// The same on Pine Script™
pine_supertrend(factor, atrPeriod) =>
  src = hl2
  atr = ta.atr(atrPeriod)
  upperBand = src + factor * atr
  lowerBand = src - factor * atr
  prevLowerBand = nz(lowerBand[1])
  prevUpperBand = nz(upperBand[1])

  lowerBand := lowerBand > prevLowerBand or close[1] < prevLowerBand ? lowerBand : prevLowerBand
  upperBand := upperBand < prevUpperBand or close[1] > prevUpperBand ? upperBand : prevUpperBand
  int direction = na
  float superTrend = na
  prevSuperTrend = superTrend[1]
  if na(atr[1])
    direction := 1
  else if prevSuperTrend == prevUpperBand
    direction := close > upperBand ? -1 : 1
  else
    direction := close < lowerBand ? 1 : -1
  superTrend := direction == -1 ? lowerBand : upperBand
  [superTrend, direction]

[pineSupertrend, pineDirection] = pine_supertrend(3, 10)
plot(pineDirection < 0 ? pineSupertrend : na, "Up direction", color = color.green, style=plot.style_linebr)
plot(pineDirection > 0 ? pineSupertrend : na, "Down direction", color = color.red, style=plot.style_linebr)

واپسیدو سپر ٹرینڈ سیریز کا ٹوپل: سپر ٹرینڈ لائن اور رجحان کی سمت۔ ممکنہ اقدار 1 (نیچے کی سمت) اور -1 (اوپر کی سمت) ہیں۔

دلائل

• factor(سیریز int/float) ضرب جس سے ATR مل جائے گا ضرب.
• atrPeriod(سادہ int) ATR کی لمبائی

یہ بھی ملاحظہ کریں ta.macd

ta.lowest

واپس بار کی ایک دی گئی تعداد کے لئے سب سے کم قیمت.

ta.lowest(source, length) 

ta.lowest(length) 

واپسیسیریز میں سب سے کم قدر.

دلائل

• source(سیریز int/float) عمل کرنے کے لئے اقدار کی سیریز.
• length(سیریز int) سلاخوں کی تعداد (لمبائی)

تبصرےدو ارگ ورژن:sourceایک سلسلہ ہے اورlengthواپس بار کی تعداد ہے. ایک آرگ ورژن:lengthواپس سلاخوں کی تعداد ہے. الگورتھم ایک کے طور پر کم استعمال کرتا ہےsource series.

یہ بھی ملاحظہ کریں ta.highest ta.lowestbars ta.highestbars ta.valuewhen ta.barssince

ta.lowestbars

ایک مقررہ تعداد باروں کے لئے کم سے کم قدر آفسیٹ.

ta.lowestbars(source, length) 

ta.lowestbars(length) 

واپسیسب سے کم بار کے لئے آفسیٹ.

دلائل

• source(سیریز int/float) عمل کرنے کے لئے اقدار کی سیریز.
• length(سیریز int) واپس بار کی تعداد.

تبصرےدو ارگ ورژن:sourceایک سلسلہ ہے اورlengthواپس بار کی تعداد ہے. ایک آرگ ورژن:lengthواپس سلاخوں کی تعداد ہے. الگورتھم ایک کے طور پر کم استعمال کرتا ہےsource series.

یہ بھی ملاحظہ کریں ta.lowest ta.highest ta.highestbars ta.barssince ta.valuewhen

ta.valuewhen

بار پر source سیریز کی قدر لوٹاتا ہے جہاں condition nth تازہ ترین واقعہ پر سچ تھا۔

ta.valuewhen(condition, source, occurrence) 

مثال

slow = ta.sma(close, 7)
fast = ta.sma(close, 14)
// Get value of `close` on second most recent cross
plot(ta.valuewhen(ta.cross(slow, fast), close, 1))

دلائل

• condition(سلسلہ بول) تلاش کرنے کے لئے شرط.
• source(سیریز int/float/bool/color) وہ قدر جو اس بار سے واپس کی جائے گی جہاں شرط پوری ہو.
• occurrence(سادہ انٹ) شرط کا واقع ہونا۔ نمبرنگ 0 سے شروع ہوتی ہے اور وقت میں واپس جاتی ہے ، لہذا 0 condition کا تازہ ترین واقعہ ہے ، 1 دوسرا تازہ ترین ہے اور اسی طرح۔ ایک عدد ہونا ضروری ہے >= 0.

تبصرےاس فنکشن کو ہر بار پر عملدرآمد کی ضرورت ہوتی ہے۔ اس کا استعمال کسی for یا while لوپ ڈھانچے کے اندر استعمال کرنے کی سفارش نہیں کی جاتی ہے ، جہاں اس کا رویہ غیر متوقع ہوسکتا ہے۔ براہ کرم نوٹ کریں کہ اس فنکشن کا استعمال اشارے کو دوبارہ پینٹ کرنے کا سبب بن سکتا ہے۔

یہ بھی ملاحظہ کریں ta.lowestbars ta.highestbars ta.barssince ta.highest ta.lowest

ta.vwap

حجم پر وزن شدہ اوسط قیمت

ta.vwap(source) 

واپسیحجم وزن شدہ اوسط.

دلائل

• source(سیریز int/float) ماخذ سیریز.

یہ بھی ملاحظہ کریں ta.vwap

ta.vwma

vwma فنکشن حجم وزن شدہ چلتی اوسط کی واپسی کرتا ہےsourceکے لئےlengthسلاخوں کے پیچھے. یہ ایک ہی ہے: sma ((ذرائع * حجم، لمبائی) / sma ((حجم، لمبائی).

ta.vwma(source, length) 

مثال

plot(ta.vwma(close, 15))

// same on pine, but less efficient
pine_vwma(x, y) =>
    ta.sma(x * volume, y) / ta.sma(volume, y)
plot(pine_vwma(close, 15))

واپسیحجم پر وزن شدہ اوسط حرکت پذیرsourceکے لئےlengthسلاخوں کے پیچھے.

دلائل

• source(سیریز int/float) عمل کرنے کے لئے اقدار کی سیریز.
• length(سیریز int) سلاخوں کی تعداد (لمبائی)

یہ بھی ملاحظہ کریں ta.sma ta.ema ta.rma ta.wma ta.swma ta.alma

ta.wpr

ولیمز ٪ آر۔ اوسیلیٹر موجودہ اختتامی قیمت کو پچھلی وقت کی مدت بار کے اعلی اور کم کے سلسلے میں دکھاتا ہے۔

ta.wpr(length) 

مثال

plot(ta.wpr(14), title="%R", color=color.new(#ff6d00, 0))

واپسیولیمز %R.

دلائل

• length(سیریز int) سلاخوں کی تعداد

یہ بھی ملاحظہ کریں ta.mfi ta.cmo

پلاٹ

پلاٹ

چارٹ پر اعداد و شمار کا ایک سلسلہ دکھاتا ہے۔

plot(series, title, color, linewidth, style, trackprice, histbase, offset, join, editable, show_last, display) 

مثال

plot(high+low, title='Title', color=color.new(#00ffaa, 70), linewidth=2, style=plot.style_area, offset=15, trackprice=true)

// You may fill the background between any two plots with a fill() function:
p1 = plot(open)
p2 = plot(close)
fill(p1, p2, color=color.new(color.green, 90))

واپسیایک پلاٹ آبجیکٹ، جو بھرنے میں استعمال کیا جا سکتا ہے.

دلائل

• series(سلسلہ int/float) اعداد و شمار کی سیریز جس کا نقشہ بنایا جائے۔ مطلوبہ دلیل۔
• title(const string) پلاٹ کا عنوان.
• color(سیریز کا رنگ) پلاٹ کا رنگ۔ آپ مسلسل استعمال کر سکتے ہیں جیسے رنگ=رنگ.سرخ یا color=#ff001a کے ساتھ ساتھ color = close >= open جیسے پیچیدہ اظہار؟color.green : color.red. اختیاری دلیل.
• linewidth(ان پٹ انٹ) پلاٹ لائن کی چوڑائی۔ ڈیفالٹ ویلیو 1 ہے۔ ہر انداز پر لاگو نہیں ہوتا ہے۔
• style(plot_style) پلاٹ کی قسم۔ ممکنہ اقدار یہ ہیں: plot.style_line ، plot.style_stepline ، plot.style_stepline_diamond ، plot.style_histogram ، plot.style_cross ، plot.style_area ، plot.style_columns ، plot.style_circles ، plot.style_linebr ، plot.style_areabr۔ ڈیفالٹ قیمت plot.style_line ہے۔
• trackprice(ان پٹ بول) اگر سچ ہے تو ایک افقی قیمت لائن آخری اشارے کی قیمت کی سطح پر دکھائی جائے گی۔ ڈیفالٹ غلط ہے۔
• histbase(input int/float) plot.style_histogram، plot.style_columns یا plot.style_area style کے ساتھ پلاٹ ریڈر کرتے وقت حوالہ کی سطح کے طور پر استعمال ہونے والی قیمت کی قیمت۔ ڈیفالٹ 0.0 ہے۔
• offset(سیریز انٹ) دی گئی تعداد میں سلاخوں پر پلاٹ کو بائیں یا دائیں طرف منتقل کرتا ہے۔ ڈیفالٹ 0 ہے۔
• join(ان پٹ bool) اگر سچ ہے تو پلاٹ پوائنٹس لائن کے ساتھ شامل ہوں گے ، جو صرف پلاٹ.سٹائل_کراس اور پلاٹ.سٹائل_سرکل اسٹائل پر لاگو ہوتے ہیں۔ ڈیفالٹ غلط ہے۔
• editable(const bool) اگر سچ ہے تو پلاٹ سٹائل فارمیٹ ڈائیلاگ میں قابل تدوین ہوگا۔ ڈیفالٹ سچ ہے۔
• show_last(ان پٹ انٹ) اگر مقرر کیا جائے تو، چارٹ پر پلاٹ کرنے کے لئے سلاخوں کی تعداد (آخری بار سے ماضی میں واپس) کی وضاحت کرتا ہے.
• display(plot_display) کنٹرولز جہاں پلاٹ دکھایا جاتا ہے۔ ممکنہ اقدار یہ ہیں: display.none، display.all۔ ڈیفالٹ display.all ہے۔
• overlay(const bool) FMZ پلیٹ فارم کی توسیع کا دلیل ہے ، اس کا استعمال موجودہ فنکشن کو مین امیج (سچ پر مقرر) یا ذیلی امیج (جھوٹی پر مقرر) پر ظاہر کرنے کے لئے کیا جاتا ہے ، ڈیفالٹ ویلیو غلط ہے۔ اگر یہ دلیل متعین نہیں کی گئی ہے تو ، اسے اس کے مطابق مقرر کیا جائے گاoverlayدلیل میںstrategyیاindicator، اگرstrategyیاindicatorسیٹ نہیں کرتاoverlayدلیل، یہ ڈیفالٹ دلیلوں کے مطابق عملدرآمد کیا جائے گا.

یہ بھی ملاحظہ کریں plotshape plotchar bgcolor

پلاٹ شیپ

چارٹ پر بصری شکلیں دکھاتا ہے۔

plotshape(series, title, style, location, color, offset, text, textcolor, editable, size, show_last, display) 

مثال

data = close >= open
plotshape(data, style=shape.xcross)

دلائل

• series(سلسلہ bool) اعداد و شمار کی سیریز کو شکلوں کے طور پر پلاٹ کیا جائے گا۔ سیریز کو location.absolute کے علاوہ تمام مقام اقدار کے لئے بولین اقدار کی ایک سیریز کے طور پر سمجھا جاتا ہے۔ مطلوبہ دلیل۔
• title(const string) پلاٹ کا عنوان.
• style(ان پٹ سٹرنگ) پلاٹ کی قسم۔ ممکنہ اقدار یہ ہیں: shape.xcross، shape.cross، shape.triangleup، shape.triangledown، shape.flag، shape.circle، shape.arrowup، shape.arrowdown، shape.labelup، shape.labeldown، shape.square، shape.diamond۔ ڈیفالٹ قدر shape.xcross ہے۔
• location(ان پٹ سٹرنگ) چارٹ پر شکلوں کا مقام۔ ممکنہ اقدار یہ ہیں: location.abovebar، location.belowbar،location.top، location.bottom، location.absolute. ڈیفالٹ قدر location.abovebar ہے.
• color(سیریز کا رنگ) شکلوں کا رنگ۔ آپ مسلسل استعمال کر سکتے ہیں جیسے رنگ=رنگ.سرخ یا color=#ff001a کے ساتھ ساتھ color = close >= open جیسے پیچیدہ اظہار؟color.green : color.red. اختیاری دلیل.
• offset(سیریز انٹ) دی گئی تعداد میں سلاخوں پر بائیں یا دائیں طرف شکلوں کو منتقل کرتا ہے۔ ڈیفالٹ 0 ہے۔
• text(const string) شکل کے ساتھ ظاہر کرنے کے لئے متن۔ آپ کثیر لائن متن استعمال کرسکتے ہیں ، لائنوں کو الگ کرنے کے لئے \n فرار ترتیب استعمال کریں۔ مثال: لائن ایک \n لائن دو
• textcolor(سیریز کا رنگ) متن کا رنگ۔ آپ مسلسل استعمال کر سکتے ہیں جیسے textcolor=color.red یا textcolor=#ff001a کے ساتھ ساتھ textcolor = close >= open جیسے پیچیدہ اظہار؟color.green : color.red. اختیاری دلیل.
• editable(const bool) اگر سچ ہے تو پلاٹ شیپ سٹائل فارمیٹ ڈائیلاگ میں قابل تدوین ہوگا۔ ڈیفالٹ سچ ہے۔
• show_last(ان پٹ انٹ) اگر مقرر کیا گیا ہے تو، شکلوں کی تعداد کی وضاحت کرتا ہے (آخری بار سے ماضی میں واپس) چارٹ پر پلاٹ کرنے کے لئے.
• size(const string) چارٹ پر شکلوں کا سائز۔ ممکنہ اقدار یہ ہیں:size.auto، سائز.چھوٹا، سائز.چھوٹا، سائز.معمولی، سائز.بڑا، سائز.بڑا۔ ڈیفالٹ ہےsize.auto.
• display(plot_display) کنٹرولز جہاں پلاٹ دکھایا جاتا ہے۔ ممکنہ اقدار یہ ہیں: display.none، display.all۔ ڈیفالٹ display.all ہے۔
• overlay(const bool) FMZ پلیٹ فارم کی توسیع کا دلیل ہے ، اس کا استعمال موجودہ فنکشن کو مین امیج (سچ پر مقرر) یا ذیلی امیج (جھوٹی پر مقرر) پر ظاہر کرنے کے لئے کیا جاتا ہے ، ڈیفالٹ ویلیو غلط ہے۔ اگر یہ دلیل متعین نہیں کی گئی ہے تو ، اسے اس کے مطابق مقرر کیا جائے گاoverlayدلیل میںstrategyیاindicator، اگرstrategyیاindicatorسیٹ نہیں کرتاoverlayدلیل، یہ ڈیفالٹ دلیلوں کے مطابق عملدرآمد کیا جائے گا.

یہ بھی ملاحظہ کریں plot plotchar bgcolor

پلاٹچار

چارٹ پر کسی بھی دیئے گئے ایک یونیکوڈ کردار کا استعمال کرتے ہوئے بصری شکلوں کو پلاٹ کرتا ہے۔

plotchar(series, title, char, location, color, offset, text, textcolor, editable, size, show_last, display) 

مثال

data = close >= open
plotchar(data, char='❄')

دلائل

• series(سلسلہ bool) اعداد و شمار کی سیریز کو شکلوں کے طور پر پلاٹ کیا جائے گا۔ سیریز کو location.absolute کے علاوہ تمام مقام اقدار کے لئے بولین اقدار کی ایک سیریز کے طور پر سمجھا جاتا ہے۔ مطلوبہ دلیل۔
• title(const string) پلاٹ کا عنوان.
• char(ان پٹ سٹرنگ) ایک بصری شکل کے طور پر استعمال کرنے کے لئے کردار.
• location(ان پٹ سٹرنگ) چارٹ پر شکلوں کا مقام۔ ممکنہ اقدار یہ ہیں: location.abovebar، location.belowbar،location.top، location.bottom، location.absolute. ڈیفالٹ قدر location.abovebar ہے.
• color(سیریز کا رنگ) شکلوں کا رنگ۔ آپ مسلسل استعمال کر سکتے ہیں جیسے رنگ=رنگ.سرخ یا color=#ff001a کے ساتھ ساتھ color = close >= open جیسے پیچیدہ اظہار؟color.green : color.red. اختیاری دلیل.
• offset(سیریز انٹ) دی گئی تعداد میں سلاخوں پر بائیں یا دائیں طرف شکلوں کو منتقل کرتا ہے۔ ڈیفالٹ 0 ہے۔
• text(const string) شکل کے ساتھ ظاہر کرنے کے لئے متن۔ آپ کثیر لائن متن استعمال کرسکتے ہیں ، لائنوں کو الگ کرنے کے لئے \n فرار ترتیب استعمال کریں۔ مثال: لائن ایک \n لائن دو
• textcolor(سیریز کا رنگ) متن کا رنگ۔ آپ مسلسل استعمال کر سکتے ہیں جیسے textcolor=color.red یا textcolor=#ff001a کے ساتھ ساتھ textcolor = close >= open جیسے پیچیدہ اظہار؟color.green : color.red. اختیاری دلیل.
• editable(const bool) اگر سچ ہے تو plotchar سٹائل فارمیٹ ڈائیلاگ میں قابل تدوین ہوگا۔ ڈیفالٹ سچ ہے۔
• show_last(ان پٹ انٹ) اگر مقرر کیا جائے تو، چارٹ پر پلاٹ کرنے کے لئے حروف کی تعداد (آخری بار سے ماضی میں) کی وضاحت کرتا ہے.
• size(const string) چارٹ پر حروف کا سائز۔ ممکنہ اقدار یہ ہیں:size.auto، سائز.چھوٹا، سائز.چھوٹا، سائز.معمولی، سائز.بڑا، سائز.بڑا۔ ڈیفالٹ ہےsize.auto.
• display(plot_display) کنٹرولز جہاں پلاٹ دکھایا جاتا ہے۔ ممکنہ اقدار یہ ہیں: display.none، display.all۔ ڈیفالٹ display.all ہے۔
• overlay(const bool) FMZ پلیٹ فارم کی توسیع کا دلیل ہے ، اس کا استعمال موجودہ فنکشن کو مین امیج (سچ پر مقرر) یا ذیلی امیج (جھوٹی پر مقرر) پر ظاہر کرنے کے لئے کیا جاتا ہے ، ڈیفالٹ ویلیو غلط ہے۔ اگر یہ دلیل متعین نہیں کی گئی ہے تو ، اسے اس کے مطابق مقرر کیا جائے گاoverlayدلیل میںstrategyیاindicator، اگرstrategyیاindicatorسیٹ نہیں کرتاoverlayدلیل، یہ ڈیفالٹ دلیلوں کے مطابق عملدرآمد کیا جائے گا.

یہ بھی ملاحظہ کریں plot plotshape bgcolor

پلاٹکینڈل

چارٹ پر موم بتیاں پلاٹ.

plotcandle(open, high, low, close, title, color, wickcolor, editable, show_last, bordercolor, display)

مثال

indicator("plotcandle example", overlay=true)
plotcandle(open, high, low, close, title='Title', color = open < close ? color.green : color.red, wickcolor=color.black)

دلائل

• open(سیریز int/float) موم بتیوں کی کھلی اقدار کے طور پر استعمال ہونے والی اعداد و شمار کی کھلی سیریز۔ مطلوبہ دلیل۔
• high(سیریز int/float) موم بتیوں کی اعلی اقدار کے طور پر استعمال ہونے والی اعداد و شمار کی بڑی سیریز۔ مطلوبہ دلیل۔
• low(سیریز int/float) شمعوں کی کم اقدار کے طور پر استعمال ہونے والی اعداد و شمار کی کم سیریز۔ مطلوبہ دلیل۔
• close(سیریز int/float) موم بتیوں کی قریبی اقدار کے طور پر استعمال ہونے والی اعداد و شمار کی قریبی سیریز۔ مطلوبہ دلیل۔
• title(const string) پلاٹ کے عنوان. اختیاری دلیل.
• color(سیریز رنگ) موم بتیوں کا رنگ۔ آپ مسلسل استعمال کر سکتے ہیں جیسے رنگ=رنگ.سرخ یا color=#ff001a کے ساتھ ساتھ color = close >= open جیسے پیچیدہ اظہار؟color.green : color.red. اختیاری دلیل.
• wickcolor(سیریز رنگ) موم بتیوں کی فلیٹ کا رنگ۔ ایک اختیاری دلیل۔
• editable(const bool) اگر سچ ہے تو plotcandle سٹائل فارمیٹ ڈائیلاگ میں قابل تدوین ہوگا۔ ڈیفالٹ سچ ہے۔
• show_last(ان پٹ انٹ) اگر مقرر کیا جاتا ہے تو، شمعیں کی تعداد کی وضاحت کرتا ہے (آخری بار سے ماضی میں واپس) چارٹ پر پلاٹ کرنے کے لئے.
• bordercolor(سیریز رنگ) موم بتیوں کے سرحدی رنگ. ایک اختیاری دلیل.
• display(plot_display) کنٹرولز جہاں پلاٹ دکھایا جاتا ہے۔ ممکنہ اقدار یہ ہیں: display.none، display.all۔ ڈیفالٹ display.all ہے۔
• overlay(const bool) FMZ پلیٹ فارم کی توسیع کا دلیل ہے ، اس کا استعمال موجودہ فنکشن کو مین امیج (سچ پر مقرر) یا ذیلی امیج (جھوٹی پر مقرر) پر ظاہر کرنے کے لئے کیا جاتا ہے ، ڈیفالٹ ویلیو غلط ہے۔ اگر یہ دلیل متعین نہیں کی گئی ہے تو ، اسے اس کے مطابق مقرر کیا جائے گاoverlayدلیل میںstrategyیاindicator، اگرstrategyیاindicatorسیٹ نہیں کرتاoverlayدلیل، یہ ڈیفالٹ دلیلوں کے مطابق عملدرآمد کیا جائے گا.

تبصرےیہاں تک کہ اگر کھلی، اعلی، کم یا قریب کی ایک قدر برابر NaN ہے، تو بار کو کوئی ڈرا کی ضرورت نہیں ہے. کھلے، اعلی، کم یا بند کی زیادہ سے زیادہ قیمت high اور کم سے کم قیمت low پر مقرر کی جائے گی.

یہ بھی ملاحظہ کریں plotbar

پلوٹارو

چارٹ پر اوپر اور نیچے تیر پلاٹ. اوپر تیر ہر اشارے مثبت قدر پر تیار کیا جاتا ہے, نیچے تیر ہر منفی قدر پر تیار کیا جاتا ہے. اشارے واپس na تو کوئی تیر تیار کیا جاتا ہے. تیر مختلف اونچائی ہے, زیادہ مطلق

مزید