یہ مضمون ایک مقداری تجارتی حکمت عملی کی تفصیل سے وضاحت کرتا ہے جو تجارتی سگنل پیدا کرنے کے لئے RSI اشارے کا استعمال کرتا ہے۔ یہ RSI اشارے پر عملدرآمد کرتا ہے اور طویل اور مختصر تجارت کے لئے اندراج اور باہر نکلنے کے معیار طے کرتا ہے۔
I. حکمت عملی منطق
تجارتی منطق مندرجہ ذیل ہے:
RSI (((14) اشارے کا حساب لگائیں اور اسے EMA ((28) کا استعمال کرتے ہوئے ہموار کریں تاکہ عملدرآمد آسکیلیٹر حاصل کیا جاسکے۔
اعلی / نچلے بینڈ حاصل کرنے کے لئے عملدرآمد RSI پر بولنگر بینڈ کا حساب لگائیں۔ overbought / oversold زون مقرر کریں.
جب پروسیس شدہ آر ایس آئی انٹری لائن سے نیچے عبور کرتا ہے تو ، خرید کا اشارہ پیدا ہوتا ہے۔ جب یہ اس سے اوپر عبور کرتا ہے تو ، فروخت کا اشارہ پیدا ہوتا ہے۔
جب اشارے زیادہ خریدے گئے/زیادہ فروخت ہونے والے زون میں داخل ہوتا ہے، تو بند پوزیشن کا اشارہ پیدا ہوتا ہے۔
اس طرح ، آر ایس آئی کی خصوصیات کو الٹ جانے کے مواقع حاصل کرنے کے لئے استعمال کیا جاسکتا ہے۔ اشارے کی پروسیسنگ سگنل کے معیار اور حوالہ کی قیمت کو بھی بہتر بناتی ہے۔
II۔ اسٹریٹیجی کے فوائد
اس کا سب سے بڑا فائدہ اشارے کی پروسیسنگ سے پیرامیٹر ٹیوننگ کی جگہ میں اضافہ ہے ، جو تجارت کی تعدد پر سخت کنٹرول کی اجازت دیتا ہے اور اوور ٹریڈنگ کو روکتا ہے۔
ایک اور فائدہ یہ ہے کہ اشارے کے واضح عددی اقدار پر مبنی بدیہی اندراج کے معیار ہیں۔
آخر میں، زیادہ سے زیادہ خریدا/زیادہ سے زیادہ فروخت کی حد بھی بروقت منافع لینے اور ہر تجارت کے خطرے کو کنٹرول کرنے میں مدد ملتی ہے۔
III. ممکنہ کمزوریاں
تاہم، اس حکمت عملی میں مندرجہ ذیل خطرات بھی ہیں:
سب سے پہلے، آر ایس آئی ریورس ٹریڈنگ پر توجہ مرکوز کرتا ہے، جو رجحانات کے دوران غلط سگنل پیدا کرسکتا ہے.
دوسری بات یہ کہ پیرامیٹرز کو غلط طریقے سے ایڈجسٹ کرنے سے بھی زیادہ سے زیادہ اصلاح اور بدلتی ہوئی مارکیٹ کے حالات میں موافقت میں ناکامی پیدا ہوسکتی ہے۔
آخر میں، نسبتا کم جیت کی شرح بھی حکمت عملی کو کھینچنے کے خطرات کو بے نقاب کرتی ہے.
IV. خلاصہ
خلاصہ میں ، یہ مضمون بنیادی طور پر آر ایس آئی اشارے کا استعمال کرتے ہوئے ایک مقداری تجارتی حکمت عملی متعارف کراتا ہے۔ یہ پیرامیٹر ٹوننگ کے ذریعے تجارتی تعدد کو کنٹرول کرتا ہے اور اس میں داخلہ / باہر نکلنے کے واضح اصول ہیں۔ پیرامیٹرز کو بہتر بنانے کے دوران ، الٹ ٹریڈنگ کے خطرات کو بھی سنبھالنے کی ضرورت ہے۔ مجموعی طور پر ، یہ ایک آسان اور بدیہی آر ایس آئی حکمت عملی کا فریم ورک فراہم کرتا ہے۔
/*backtest
start: 2023-08-14 00:00:00
end: 2023-09-13 00:00:00
period: 3h
basePeriod: 15m
exchanges: [{"eid":"Futures_Binance","currency":"BTC_USDT"}]
*/
//@version=5
//-----------------------------------------------------------------
//This simple strategy base on RSI, EMA, Bollinger Bands to get Buy and Sell Signal with detail as below:
//-----------------------------------------------------------------
//1.Define Oscillator Line
//+ Oscillator Line is smoothed by ema(28) of RSI(14) on H1 Timeframe
//2.Define Overbought and Oversold
//+ Apply Bollinger Bands BB(80,3) on Oscillator Line and calculate %b
//+ Overbought Zone marked above level 0.8
//+ Oversold Zone marked below level 0.2
//3.Buy Signal
//+ Entry Long Positon when %b crossover Point of Entry Long
//+ Deafault Point of Entry Long is 0.2
//+ Buy signal marked by Green dot
//4.Sell Signal
//+ Entry Short Position when %b crossunder Point of Entry Short
//+ Deafault Point of Entry Short is 0.8
//+ Sell signal marked by Red dot
//5.Exit Signal
//+ Exit Position (both Long and Short) when %b go into Overbought Zone or Oversold Zone
//+ Exit signal marked by Yellow dot
//-----------------------------------------------------------------
strategy(title="RSI %b Signal [H1 Backtesting]", overlay=false)
//RSI
rsi_gr="=== RSI ==="
rsi_len = input(14, title = "RSI",inline="set",group=rsi_gr)
smoothed_len = input(28, title = "EMA",inline="set",group=rsi_gr)
rsi=ta.ema(ta.rsi(close,rsi_len),smoothed_len)
//rsi's BOLLINGER BANDS
pb_gr="=== %b ==="
length = input(80, title = "Length",inline="set1",group=pb_gr)
rsimult = input(3.0, title = "Multiplier",inline="set1",group=pb_gr)
ovb = input(0.8, title = "Overbought",inline="set2",group=pb_gr)
ovs = input(0.2, title = "Oversold",inline="set2",group=pb_gr)
et_short = input(0.8, title = "Entry Short",inline="set3",group=pb_gr)
et_long = input(0.2, title = "Entry Long",inline="set3",group=pb_gr)
[rsibasis, rsiupper, rsilower] = ta.bb(rsi, length, rsimult)
//rsi's %B
rsipB = ((rsi - rsilower) / (rsiupper - rsilower))
plot(rsipB, title="rsi's %B", color=rsipB>math.min(ovb,et_short)?color.red:rsipB<math.max(ovs,et_long)?color.green:color.aqua, linewidth=1)
h1=hline(1,color=color.new(color.red,100))
h4=hline(ovb,color=color.new(color.red,100))
h0=hline(0,color=color.new(color.green,100))
h3=hline(ovs,color=color.new(color.green,100))
h5=hline(0.5,color=color.new(color.silver,0),linestyle=hline.style_dotted)
fill(h1,h4, title="Resistance", color=color.new(color.red,90))
fill(h0,h3, title="Support", color=color.new(color.green,90))
//Signal
rsi_buy=
rsipB[1]<et_long
and
rsipB>et_long
rsi_sell=
rsipB[1]>et_short
and
rsipB<et_short
rsi_exit=
(rsipB[1]>ovs and rsipB<ovs)
or
(rsipB[1]<ovb and rsipB>ovb)
plotshape(rsi_buy?rsipB:na,title="Buy",style=shape.circle,color=color.new(color.green,0),location=location.absolute)
plotshape(rsi_sell?rsipB:na,title="Sell",style=shape.circle,color=color.new(color.red,0),location=location.absolute)
plotshape(rsi_exit?rsipB:na,title="Exit",style=shape.circle,color=color.new(color.yellow,0),location=location.absolute)
//Alert
strategy.entry("Long",strategy.long,when=rsi_buy)
strategy.close("Long",when=rsi_exit)
strategy.entry("Short",strategy.short,when=rsi_sell)
strategy.close("Short",when=rsi_exit)
//EOF