وسائل لوڈ ہو رہے ہیں... لوڈنگ...
  1. مربع
  2. رفتار دوہری حرکت پذیر اوسط کراس اوور حکمت عملی

رفتار دوہری حرکت پذیر اوسط کراس اوور حکمت عملی

مصنف:چاؤ ژانگ، تاریخ: 2023-10-20 16:44:30
ٹیگز:

img

جائزہ

یہ حکمت عملی قیمت کی رفتار کی سمت کا تعین کرنے کے لئے اوسط چلنے والے کراس اوورز کا استعمال کرتی ہے ، جس میں مجموعی رجحان کا فیصلہ کرنے کے لئے سنہری / موت کے کراسز کی تکمیل ہوتی ہے ، تاکہ رجحان کی پیروی کی جاسکے۔

حکمت عملی منطق

یہ حکمت عملی قیمت کی رفتار کی سمت کا تعین کرنے کے لئے ای ایم اے اور ایس ایم اے کراس اوورز کا استعمال کرتی ہے۔ ای ایم اے تیزی سے رد عمل ظاہر کرتا ہے جبکہ ایس ایم اے زیادہ مستحکم رد عمل ظاہر کرتا ہے۔ جب ای ایم اے ایس ایم اے سے اوپر عبور کرتا ہے تو ، اس کا فیصلہ کیا جاتا ہے کہ اوپر کی رفتار مضبوط ہے ، طویل ہوجائیں۔ جب ای ایم اے ایس ایم اے سے نیچے عبور کرتا ہے تو ، اس کا فیصلہ کیا جاتا ہے کہ نیچے کی رفتار مضبوط ہے ، مختصر ہوجائیں۔

اس کے علاوہ ، حکمت عملی مجموعی رجحان کی سمت کا تعین کرنے کے لئے تیز مدت کے ایس ایم اے اور سست مدت کے ایس ایم اے کے کراس اوور کا بھی استعمال کرتی ہے۔ جب تیز مدت کے ایس ایم اے سست ایس ایم اے سے اوپر عبور کرتے ہیں تو ، یہ ایک سنہری کراس ہوتا ہے ، جس سے یہ ظاہر ہوتا ہے کہ مارکیٹ طویل مدتی اپ ٹرینڈ میں ہے۔ جب تیز مدت کے ایس ایم اے سست ایس ایم اے سے نیچے عبور کرتے ہیں تو ، یہ موت کا کراس ہوتا ہے ، جس سے یہ ظاہر ہوتا ہے کہ مارکیٹ طویل مدتی ڈاؤن ٹرینڈ میں ہے۔

یہ حکمت عملی طویل موقع کی نشاندہی کرتی ہے جب ای ایم اے ایس ایم اے سے اوپر گزر جاتا ہے۔ اگر اس وقت یہ سنہری کراس ہے تو ، اس کا مطلب یہ ہے کہ طویل عرصے سے چلنے میں قلیل مدتی رفتار اور طویل مدتی رجحان دونوں کی حمایت حاصل ہے ، جو ایک بہتر طویل وقت ہے۔ اگر یہ موت کا کراس ہے تو ، طویل عرصے سے چلنا صرف قلیل مدتی رفتار کی حمایت حاصل ہے اور طویل مدتی رجحان کے خلاف ہے ، جو ایک زیادہ خطرناک طویل وقت ہے۔

فوائد کا تجزیہ

  • قیمت کی رفتار اور سمت کا فیصلہ کرنے کے لئے ایم اے کراسورز کا استعمال کریں
  • قلیل مدتی رفتار اور طویل مدتی رجحان دونوں پر غور کریں
  • دوہری اشارے کی تصدیق سے وشوسنییتا میں اضافہ ہوتا ہے
  • ایم اے پیرامیٹرز کو ایڈجسٹ کرکے مختلف ادوار میں موافقت پذیر
  • مخصوص تجارتی سگنل دکھانے / چھپانے کے لئے حسب ضرورت

خطرے کا تجزیہ

  • ایم اے کراس اوورز میں تاخیر ہوتی ہے، بہترین اندراج / باہر نکلنے والے مقامات کو یاد کر سکتے ہیں
  • فکسڈ پیریڈ ایس ایم اے حقیقی وقت میں قیمت کی تبدیلی کی عکاسی نہیں کر سکتا
  • طویل / مختصر مدت کے ایم اے کے درمیان غلط کراسنگ ہوسکتی ہے
  • طویل عرصے تک ہولڈنگ سرمایہ دارانہ خطرے میں اضافہ کر سکتا ہے

سگنل کی تصدیق کے لئے دیگر اشارے کو جوڑ کر ، ایم اے کی مدت کو بہتر بنانے ، یا اسٹاپ نقصان کی ترتیب سے خطرات کو کم کیا جاسکتا ہے۔

اصلاح کی ہدایات

  • حجم، بولنگر بینڈ وغیرہ جیسے دیگر فلٹرز شامل کریں.
  • سٹاپ نقصان کی حکمت عملی شامل کریں
  • ایم اے کی مدت کو بہتر بنائیں
  • سرمایہ کے انتظام کو بہتر بنانا
  • متحرک پوزیشن سائزنگ پر غور کریں

نتیجہ

مجموعی طور پر ، یہ ایک نسبتا stable مستحکم اور قابل اعتماد رجحان کی پیروی کرنے والی حکمت عملی ہے۔ اس میں قلیل مدتی قیمت کی رفتار اور طویل مدتی رجحان کی سمت دونوں پر غور کیا جاتا ہے ، جو ایم اے کراس اوورز کے ذریعہ تجارتی سگنل تیار کرتا ہے۔ سنگل ایم اے حکمت عملیوں کے مقابلے میں ، اس کی تصدیق کے لئے دوہری اشارے کو جوڑ کر اس کی زیادہ وشوسنییتا ہے۔ لیکن رجحان کی پیروی کرنے والی حکمت عملی کے طور پر ، اس کے پیرامیٹر کی اصلاح اور رسک کنٹرول بہت اہم ہیں۔ اس کی صلاحیت کو واقعی احساس کرنے کے لئے بار بار جانچ اور ٹیوننگ کی ضرورت ہے۔ مسلسل اصلاحات اور بہتری کے ساتھ ، یہ حکمت عملی طویل مدتی مقداری سرمایہ کاری کے پورٹ فولیو کا ایک قیمتی جز بن سکتی ہے۔

/*backtest
start: 2023-09-19 00:00:00
end: 2023-10-19 00:00:00
period: 1h
basePeriod: 15m
exchanges: [{"eid":"Futures_Binance","currency":"BTC_USDT"}]
*/

// This source code is subject to the terms of the Mozilla Public License 2.0 at https://mozilla.org/MPL/2.0/
// © Cryptoluc1d

//@version=4
strategy("Equal-Length EMA/SMA Crossover Strategy", initial_capital=10000, default_qty_type=strategy.percent_of_equity, default_qty_value=25, commission_type=strategy.commission.percent, commission_value=0.2, overlay=true)

// Create inputs

mom_length = input(title="Momentum Length (EMA=SMA)", defval=50)
bias_length_fast  = input(title="Golden Cross Length (Fast)", defval=50)
bias_length_slow  = input(title="Golden Cross Length (Slow)", defval=100)

// Define MAs

ema = ema(close, mom_length) // EMA/SMA crossover of the same period for detecting trend acceleration/deceleration
sma = sma(close, mom_length)
bias_fast = sma(close, bias_length_fast) // golden/death cross for overall trend bias
bias_slow = sma(close, bias_length_slow)

// Define signal conditions

buy_trend = crossover(ema, sma) and bias_fast >= bias_slow // buy when EMA cross above SMA. if this happens during a bullish golden cross, buying is in confluence with the overall trend (bias).
buy_risky = crossover(ema, sma) and bias_fast < bias_slow // buy when EMA cross above SMA. if this happens during a bearish death cross, buying is early, more risky, and not in confluence with the overall trend (bias).
buy_late = crossover(sma, bias_slow) and ema > sma // the SMA crossing the Slow_SMA gives further confirmation of bullish trend, but signal comes later.
sell = crossunder(ema, sma) // sell when EMA cross under SMA.

// Enable option to hide signals, then plot signals

show_signal = input(title="Show Signals", defval=true)

plotshape(show_signal ? buy_trend : na, title='Trend Buy', style=shape.triangleup, location=location.belowbar, color=color.green, text='TREND BUY')
plotshape(show_signal ? buy_risky : na, title='Risky Buy', style=shape.triangleup, location=location.belowbar, color=color.olive, text='RISKY BUY')
plotshape(show_signal ? buy_late : na, title='Late Buy', style=shape.triangleup, location=location.belowbar, color=color.lime, text='LATE BUY')
plotshape(show_signal ? sell : na, title='Sell', style=shape.triangledown, location=location.abovebar, color=color.red, text='SELL')

// Define entry and exit conditions

longCondition = ema > sma and bias_fast >= bias_slow // LONG when EMA above SMA, and overall trend bias is bullish
if (longCondition)
    strategy.entry("BUY TREND", strategy.long)
exitLong = crossunder(ema, sma) // close LONG when EMA cross under SMA
strategy.close("BUY TREND", when=exitLong)

// // short conditions. turned off because up only.
// shortCondition = ema < sma and bias_fast <= bias_slow // SHORT when EMA under SMA, and overall trend bias is bearish
// if (shortCondition)
//     strategy.entry("SELL TREND", strategy.short)
// exitShort = crossover(ema, sma) // close SHORT when EMA cross over SMA
// strategy.close("SELL TREND", when=exitShort)

// Enable option to show MAs, then plot MAs

show_ma = input(title="Show MAs", defval=false)

plot(show_ma ? ema : na, title="Momentum EMA", color=color.green, linewidth=1)
plot(show_ma ? sma : na, title="Momentum SMA", color=color.yellow, linewidth=1)
plot(show_ma ? bias_fast : na, title="Golden Cross SMA (Fast)", color=color.orange, linewidth=2)
plot(show_ma ? bias_slow : na, title="Golden Cross SMA (Slow)", color=color.red, linewidth=2)
مزید

2019 FMZ - تمام حقوق محفوظ ہیں