وسائل لوڈ ہو رہے ہیں... لوڈنگ...
  1. مربع
  2. LazyBear اشارے پر مبنی سکیز مومنٹم ٹریڈنگ حکمت عملی

LazyBear اشارے پر مبنی سکیز مومنٹم ٹریڈنگ حکمت عملی

مصنف:چاؤ ژانگ، تاریخ: 2024-02-05 14:48:01
ٹیگز:

img

جائزہ

یہ حکمت عملی LazyBear کے Squeeze Momentum Indicator پر مبنی ہے، جس میں اضافی رفتار فلٹرز، تبدیل شدہ ڈیٹا ماخذ، اور بہتر رسک مینجمنٹ سسٹم اور حسب ضرورت بیک ٹسٹنگ ٹائم فریم شامل ہیں، جس کا مقصد اتار چڑھاؤ کے بعد قیمتوں میں اضافے کو پکڑنا ہے۔

حکمت عملی منطق

اس حکمت عملی میں قیمت کے چینلز کا حساب لگانے کے لئے بولنگر بینڈ اور کیلٹنر چینلز کا استعمال کیا جاتا ہے۔ بریک آؤٹ بڑھتی ہوئی اتار چڑھاؤ کی نشاندہی کرتا ہے۔ اس میں لیزی بیئر کا سکس مومنٹم اشارے شامل ہے جو قیمت کی رفتار کی سمت کا تعین کرنے کے لئے لکیری رجعت کا استعمال کرتا ہے۔

اس حکمت عملی میں رفتار فلٹر شامل ہوتے ہیں ، صرف اس وقت تجارت ہوتی ہے جب مطلق رفتار ایک حد سے تجاوز کرتی ہے۔ رفتار فلٹر گزرنے کے ساتھ اتار چڑھاؤ کے دباؤ (چینل تنگ) پر ، یہ طویل / مختصر کے لئے رجحان کی سمت کا فیصلہ کرتا ہے۔ یہ خطرات کو کنٹرول کرنے کے لئے اسٹاپ نقصان ، منافع اور ٹریلنگ اسٹاپ بھی طے کرتا ہے۔

فوائد کا تجزیہ

حکمت عملی میں جامع فیصلے کے لئے متعدد اشارے شامل ہیں۔ یہ خطرہ مینجمنٹ میکانزم کے ساتھ فی تجارت نقصان کو محدود کرتی ہے۔ یہ پریشر کے بعد قیمت کے رجحانات کا بروقت اندازہ لگا سکتی ہے۔ حسب ضرورت پیرامیٹرز اسے موافقت پذیر بناتے ہیں۔

خطرے کا تجزیہ

اہم خطرات میں شامل ہیں: غلط فیصلوں کا سبب بننے والے غلط بریک آؤٹ؛ پیرامیٹر کی غلط ترتیبات کے ساتھ وقت میں الٹ جانے میں ناکامی؛ نقصانات کو بڑھانے والے اسٹاپ نقصان کی خلاف ورزی۔ پیرامیٹرز کو بہتر بنانے ، رسک مینجمنٹ کی ترتیبات کو ایڈجسٹ کرنے ، مناسب مصنوعات اور تجارتی سیشنوں کا انتخاب کرکے ان کو کم کیا جاسکتا ہے۔

اصلاح کی ہدایات

حجم جیسے دوسرے اشارے فلٹرز کو جوڑنے پر غور کریں۔ زیادہ درستگی کے ل moment رفتار کی حد کو ٹھیک کریں؛ سخت خطرہ کنٹرول کے ل draw ڈراؤنڈ اسٹاپ نقصان شامل کریں۔ زیادہ مصنوعات میں ٹیسٹ کی تاثیر۔ یہ اصلاحات حکمت عملی کو زیادہ مضبوط اور عمومی بنا سکتی ہیں۔

خلاصہ

حکمت عملی میں قیمتوں کے رجحانات اور اتار چڑھاؤ کا نسبتا comprehensive جامع اندازہ لگایا گیا ہے جس میں انضمام کی اعلی ڈگری اور خطرے کے کنٹرول کے بہتر اقدامات ہیں۔ اس کو سکڑنے کے بعد قیمتوں کے پھیلنے کو پکڑنے میں مضبوط موافقت کے ل optimization اصلاح کی سمتوں کے ذریعہ مزید تقویت دی جاسکتی ہے۔

/*backtest
start: 2024-01-05 00:00:00
end: 2024-02-04 00:00:00
period: 2h
basePeriod: 15m
exchanges: [{"eid":"Futures_Binance","currency":"BTC_USDT"}]
*/

// @version=4
// Strategy based on LazyBear Squeeze Momentum Indicator
// © Bitduke
// All scripts: https://www.tradingview.com/u/Bitduke/#published-scripts

strategy(shorttitle="SMS", title="Squeeze Momentum Strategy", overlay=false )

length = input(12, title="BB Length")
mult = input(2.0, title="BB MultFactor")
lengthKC = input(16, title="KC Length")
mult_kc = input(1.5, title="KC MultFactor")


//FILTERS
useMomAverage = input(false, title="Filter for Momenutum value", type=input.bool)
MomentumMin = input(20, title="Min for momentum")

// Calculate BB
src = ohlc4

ma_1 = sma(src, length)
ma_2 = sma(src, lengthKC)
range_ma = sma(high - low, lengthKC)

dev = mult * stdev(src, length)

upper_bb = ma_1 + dev
lower_bb = ma_1 - dev

upper_kc = ma_2 + range_ma * mult_kc
lower_kc = ma_2 - range_ma * mult_kc

sqz_on = lower_bb > lower_kc and upper_bb < upper_kc
sqz_off = lower_bb < lower_kc and upper_bb > upper_kc
no_sqz = sqz_on == false and sqz_off == false

val = linreg(src - avg(avg(highest(hl2, lengthKC), lowest(low, lengthKC)), sma(hl2, lengthKC)), lengthKC, 0)

bcolor = iff(val > 0, iff(val > nz(val[1]), color.lime, color.green), iff(val < nz(val[1]), color.red, color.maroon))
scolor = no_sqz ? color.blue : sqz_on ? color.black : color.aqua
plot(val, color=bcolor, style=plot.style_histogram, linewidth=4)
plot(0, color=scolor, style=plot.style_cross, linewidth=2)

//LOGIC
//momentum filter
filterMom = useMomAverage ? abs(val) > MomentumMin / 100000 ? true : false : true

//standard condition
longCondition = scolor[1] != color.aqua and scolor == color.aqua and bcolor == color.lime and filterMom
exitLongCondition = bcolor == color.green
shortCondition = scolor[1] != color.aqua and scolor == color.aqua and bcolor == color.red and filterMom
exitShortCondition = bcolor == color.maroon

// Risk Management Sysyem
stop_loss = input(defval = 600, title="Stop Loss", minval = 0)
take_profit = input(defval = 1000, title="Take Profit", minval = 0)
trailing_stop = input(defval = 20, title="Trailing Stop", minval = 0)
// If the zero value is set for stop loss, take profit or trailing stop, then the function is disabled
s_loss = stop_loss >= 1 ? stop_loss : na
tk_profit = take_profit >= 1 ? take_profit : na
tr_stop = trailing_stop >= 1 ? trailing_stop : na


//STRATEGY
strategy.entry("SQ_Long", strategy.long, when=longCondition)
strategy.exit("Exit Long", from_entry = "SQ_Long", profit = take_profit, trail_points = trailing_stop, loss = s_loss)
strategy.close("SQ_Long", exitLongCondition)

strategy.entry("SQ_Short", strategy.short, when=shortCondition)
strategy.exit("Exit Short", from_entry = "SQ_Short", profit = take_profit, trail_points = trailing_stop, loss = s_loss )
strategy.close("SQ_Short", when=exitShortCondition)
مزید

2019 FMZ - تمام حقوق محفوظ ہیں