وسائل لوڈ ہو رہے ہیں... لوڈنگ...
  1. مربع
  2. دوہری T3 ٹرینڈ ٹریکنگ کی بہتر حکمت عملی

دوہری T3 ٹرینڈ ٹریکنگ کی بہتر حکمت عملی

مصنف:چاؤ ژانگ، تاریخ: 2025-01-17 14:29:51
ٹیگز:T3TOTTای ایم اےاو ٹی ٹیآر ایس آئی

Optimized Dual T3 Trend Tracking Strategy

جائزہ

یہ حکمت عملی ٹیلسن ٹی 3 اشارے اور ٹوئن آپٹمائزڈ ٹرینڈ ٹریکر (ٹو ٹی ٹی) پر مبنی رجحان کے بعد کا نظام ہے۔ یہ ولیمز٪ آر مومنٹوم آسکیلیٹر کو شامل کرکے تجارتی سگنل کی نسل کو بہتر بناتا ہے۔ یہ حکمت عملی علیحدہ خرید اور فروخت پیرامیٹر کی ترتیبات کو استعمال کرتی ہے ، جس سے مارکیٹ کے مختلف حالات کے لئے لچکدار حساسیت کی ایڈجسٹمنٹ ممکن ہوتی ہے۔

حکمت عملی کے اصول

اسٹریٹیجی میں تین بنیادی اجزاء شامل ہیں: ٹیلسن ٹی 3 اشارے - ایکسپونینشل موونگ ایوریج (ای ایم اے) کا ایک بہتر ورژن جو متعدد وزن والے ای ایم اے حساب کتاب کے ذریعے ہموار رجحان لائن تیار کرتا ہے۔ ٹوئن آپٹمائزڈ ٹرینڈ ٹریکر (TOTT) - ایک موافقت پذیر رجحان کی پیروی کرنے والا آلہ جو قیمت کی کارروائی اور اتار چڑھاؤ کے گتانک کی بنیاد پر ایڈجسٹ ہوتا ہے ، خرید و فروخت کی شرائط کے لئے اوپری اور نچلے بینڈ کا حساب لگاتا ہے۔ ولیمز فی صد آر اشارے - ایک رفتار آکسیلیٹر استعمال کیا جاتا ہے overbought اور oversold حالات کی شناخت کے لئے.

سگنل جنریشن منطق: - خریدنے کی شرط: جب T3 لائن TOTT اوپری بینڈ کے اوپر کراس کرتی ہے اور ولیمز %R -20 (اوور سیلڈ) سے اوپر ہے - فروخت کی شرط: جب T3 لائن TOTT نچلے بینڈ سے نیچے عبور کرتی ہے اور ولیمز٪ R -70 سے اوپر ہے

حکمت عملی کے فوائد

  1. مضبوط سگنل استحکام - T3s کے متعدد ہموار کے ذریعے مؤثر طریقے سے جھوٹے بریک آؤٹ کے خطرات کو کم کرتا ہے
  2. اچھی موافقت - علیحدہ خرید / فروخت کے پیرامیٹرز مختلف مارکیٹ کے حالات کے لئے آزاد اصلاح کی اجازت دیتے ہیں
  3. جامع رسک کنٹرول - ثانوی تصدیق کے طور پر ولیمز %R کو ضم کرتا ہے
  4. واضح تصور - جامع چارٹ تصور کی حمایت فراہم کرتا ہے

حکمت عملی کے خطرات

  1. رجحان کی تبدیلی کی تاخیر - T3 کی متعدد ہموار سگنل تاخیر کا سبب بن سکتی ہے
  2. مختلف بازاروں کے لئے مناسب نہیں - استحکام کے دوران بہت زیادہ سگنل پیدا کر سکتا ہے
  3. اعلی پیرامیٹر حساسیت - مختلف مارکیٹ کے ماحول کے لئے کثرت سے ایڈجسٹمنٹ کی ضرورت ہے

خطرے کے کنٹرول کی تجاویز: - سٹاپ نقصان کے طریقہ کار کو نافذ کریں - تجارتی حجم کی حد مقرر کریں - رجحان کی تصدیق کے فلٹرز شامل کریں

اصلاح کی ہدایات

  1. متحرک پیرامیٹر اصلاح - موافقت پذیر پیرامیٹر ایڈجسٹمنٹ میکانزم تیار کریں
  2. مارکیٹ کے ماحول کی بہتر شناخت - رجحان کی طاقت کے اشارے متعارف کرانے
  3. بہتر رسک مینجمنٹ - متحرک سٹاپ نقصان اور منافع لینے کا اضافہ
  4. بہتر سگنل فلٹرنگ - اضافی تکنیکی اشارے کو ضم کرنا

خلاصہ

یہ واضح منطق کے ساتھ حکمت عملی کے بعد ایک اچھی طرح سے منظم رجحان ہے۔ T3 اشارے اور TOTT کے امتزاج کے ذریعہ ، ولیمز %R فلٹرنگ کے ساتھ مل کر ، یہ رجحان سازی کی منڈیوں میں عمدہ کارکردگی کا مظاہرہ کرتا ہے۔ اگرچہ کچھ موروثی تاخیر ہے ، حکمت عملی پیرامیٹر کی اصلاح اور رسک مینجمنٹ میں بہتری کے ذریعے عمدہ عملی قدر اور توسیع کی گنجائش دکھاتی ہے۔

/*backtest
start: 2019-12-23 08:00:00
end: 2025-01-15 08:00:00
period: 1d
basePeriod: 1d
exchanges: [{"eid":"Futures_Binance","currency":"BTC_USDT","balance":49999}]
*/

//@version=6
strategy("FON60DK by leventsah", overlay=true)

// Girdi AL
t3_length = input.int(5, title="Tillson Per AL", minval=1)
t3_opt = input.float(0.1, title="Tillson Opt AL", step=0.1, minval=0)
tott_length = input.int(5, title="TOTT Per AL", minval=1)
tott_opt = input.float(0.1, title="TOTT Opt AL", step=0.1, minval=0)
tott_coeff = input.float(0.006, title="TOTT Coeff AL", step=0.001, minval=0)

//GİRDİ SAT
t3_lengthSAT = input.int(5, title="Tillson Per SAT", minval=1)
t3_optSAT = input.float(0.1, title="Tillson Opt SAT", step=0.1, minval=0)
tott_lengthSAT = input.int(5, title="TOTT Per SAT", minval=1)
tott_opt_SAT = input.float(0.1, title="TOTT Opt SAT", step=0.1, minval=0)
tott_coeff_SAT = input.float(0.006, title="TOTT Coeff SAT", step=0.001, minval=0)

william_length = input.int(3, title="William %R Periyodu", minval=1)

// Tillson T3 AL
t3(src, length, opt) =>
    k = 2 / (length + 1)
    ema1 = ta.ema(src, length)
    ema2 = ta.ema(ema1, length)
    ema3 = ta.ema(ema2, length)
    ema4 = ta.ema(ema3, length)
    c1 = -opt * opt * opt
    c2 = 3 * opt * opt + 3 * opt * opt * opt
    c3 = -6 * opt * opt - 3 * opt - 3 * opt * opt * opt
    c4 = 1 + 3 * opt + opt * opt * opt + 3 * opt * opt
    t3_val = c1 * ema4 + c2 * ema3 + c3 * ema2 + c4 * ema1
    t3_val

t3_value = t3(close, t3_length, t3_opt)
t3_valueSAT = t3(close, t3_lengthSAT, t3_optSAT)


// TOTT hesaplaması (Twin Optimized Trend Tracker)
Var_Func(src, length) =>
    valpha = 2 / (length + 1)
    vud1 = math.max(src - src[1], 0)
    vdd1 = math.max(src[1] - src, 0)
    vUD = math.sum(vud1, 9)
    vDD = math.sum(vdd1, 9)
    vCMO = (vUD - vDD) / (vUD + vDD)
    var float VAR = na
    VAR := valpha * math.abs(vCMO) * src + (1 - valpha * math.abs(vCMO)) * nz(VAR[1], src)
    VAR

VAR = Var_Func(close, tott_length)
VAR_SAT = Var_Func(close, tott_lengthSAT)

//LONG 
MAvg = VAR
fark = MAvg * tott_opt * 0.01
longStop = MAvg - fark
longStopPrev = nz(longStop[1], longStop)
longStop := MAvg > longStopPrev ? math.max(longStop, longStopPrev) : longStop
shortStop = MAvg + fark
shortStopPrev = nz(shortStop[1], shortStop)
shortStop := MAvg < shortStopPrev ? math.min(shortStop, shortStopPrev) : shortStop
dir = 1
dir := nz(dir[1], dir)
dir := dir == -1 and MAvg > shortStopPrev ? 1 : dir == 1 and MAvg < longStopPrev ? -1 : dir
MT = dir == 1 ? longStop : shortStop
OTT = MAvg > MT ? MT * (200 + tott_opt) / 200 : MT * (200 - tott_opt) / 200
OTTup = OTT * (1 + tott_coeff)
OTTdn = OTT * (1 - tott_coeff)

//CLOSE
MAvgS = VAR_SAT
farkS = MAvgS * tott_opt_SAT * 0.01
longStopS = MAvgS - farkS
longStopPrevS = nz(longStopS[1], longStopS)
longStopS := MAvgS > longStopPrevS ? math.max(longStopS, longStopPrevS) : longStopS
shortStopS = MAvgS + farkS
shortStopPrevS = nz(shortStopS[1], shortStopS)
shortStopS := MAvgS < shortStopPrevS ? math.min(shortStopS, shortStopPrevS) : shortStopS
dirS = 1
dirS := nz(dirS[1], dirS)
dirS := dirS == -1 and MAvgS > shortStopPrevS ? 1 : dirS == 1 and MAvgS < longStopPrevS ? -1 : dirS
MTS = dirS == 1 ? longStopS : shortStopS
OTTS = MAvgS > MTS ? MTS * (200 + tott_opt_SAT) / 200 : MTS * (200 - tott_opt_SAT) / 200
OTTupS = OTTS * (1 + tott_coeff_SAT)
OTTdnS = OTTS * (1 - tott_coeff_SAT)

// Calculation of Williams %R
williamsR = -100 * (ta.highest(high, william_length) - close) / (ta.highest(high, william_length) - ta.lowest(low, william_length))

// Alım koşulu
longCondition = (t3_value > OTTup) and (williamsR > -20)

// Short koşulu (long pozisyonunu kapatmak için)
shortCondition = (t3_valueSAT < OTTdnS) and (williamsR > -70)

// Alım pozisyonu açma
if (longCondition)
    strategy.entry("Long", strategy.long)

// Short koşulu sağlandığında long pozisyonunu kapama
if (shortCondition)
    strategy.close("Long")


// Alım pozisyonu boyunca barları yeşil yapma
barcolor(strategy.position_size > 0 ? color.green : na)

// Grafikte göstergeleri çizme
plot(t3_value, color=color.blue, linewidth=1, title="Tillson AL")
plot(OTTup, color=color.green, linewidth=1, title="TOTT Up AL")
plot(OTTdn, color=color.red, linewidth=1, title="TOTT Down AL")

// Grafikte göstergeleri çizme
plot(t3_valueSAT, color=color.blue, linewidth=1, title="Tillson SAT")
plot(OTTupS, color=color.green, linewidth=1, title="TOTT Up SAT")
plot(OTTdnS, color=color.red, linewidth=1, title="TOTT Down SAT")
متعلقہ
مزید

2019 FMZ - تمام حقوق محفوظ ہیں