Tài nguyên đang được tải lên... tải...
  1. Quảng trường
  2. Chiến lược tăng cường xu hướng định lượng đa lớp của AO

Chiến lược tăng cường xu hướng định lượng đa lớp của AO

Tác giả:ChaoZhang, Ngày: 2024-12-05 15:01:48
Tags:AOEMAWFWA

AO Multi-Layer Quantitative Trend Enhancement Strategy

Tổng quan

Chiến lược này là một hệ thống giao dịch đa lớp dựa trên động lực và theo xu hướng. Nó kết hợp Williams Alligator, Williams Fractals, Awesome Oscillator (AO), và Exponential Moving Average (EMA) để xác định các cơ hội dài có khả năng cao. Chiến lược sử dụng một cơ chế triển khai vốn nhiều lớp, tăng dần các vị trí khi xu hướng tăng cường, với khả năng nắm giữ tối đa 5 vị trí đồng thời, mỗi vị trí sử dụng 10% vốn.

Nguyên tắc chiến lược

Chiến lược này sử dụng nhiều cơ chế lọc để đảm bảo độ chính xác hướng giao dịch. Thứ nhất, nó sử dụng EMA để đánh giá xu hướng dài hạn, chỉ tìm kiếm các cơ hội dài hạn khi giá trên EMA. Thứ hai, nó đánh giá xu hướng ngắn hạn thông qua sự kết hợp của Williams Alligator và Fractals, xác nhận xu hướng tăng khi một sự đột phá fractal tăng xảy ra trên đường răng của Alligator. Cuối cùng, sau khi xác nhận xu hướng, chiến lược tìm kiếm các tín hiệu dài của chỉ số AO saucer cho thời gian nhập cảnh cụ thể. Hệ thống chỉ sử dụng 10% vốn mỗi giao dịch và có thể mở tối đa 5 vị trí dài khi xu hướng tăng cường. Khi sự kết hợp của fractal và Alligator chỉ ra sự đảo ngược xu hướng, tất cả các vị trí đều bị đóng.

Ưu điểm chiến lược

  1. Cơ chế lọc nhiều lớp làm giảm hiệu quả các tín hiệu sai
  2. Quản lý vốn khoa học với xây dựng vị trí tiến bộ
  3. Các đặc điểm theo xu hướng cho phép ghi lại các xu hướng chính
  4. Không có lệnh dừng lỗ cố định, sử dụng các chỉ số kỹ thuật để xác định cuối xu hướng động
  5. Hệ thống có khả năng cấu hình tốt cho các điều kiện thị trường khác nhau
  6. Kiểm tra hậu quả cho thấy yếu tố lợi nhuận tốt và lợi nhuận trung bình

Rủi ro chiến lược

  1. Có thể tạo ra các tín hiệu sai liên tiếp trong các thị trường khác nhau
  2. Khả năng rút vốn đáng kể trong quá trình đảo ngược xu hướng
  3. Nhiều điều kiện lọc có thể bỏ lỡ một số cơ hội giao dịch
  4. Trong quản lý vốn, việc xây dựng vị trí liên tục có thể mang lại rủi ro trong thời kỳ biến động
  5. Lựa chọn tham số EMA ảnh hưởng đáng kể đến hiệu suất chiến lược

Để giảm thiểu những rủi ro này, khuyến cáo: - Tối ưu hóa các thông số cho các môi trường thị trường khác nhau - Xem xét thêm bộ lọc biến động - Thiết lập các điều kiện xây dựng vị trí nghiêm ngặt hơn - Đặt giới hạn rút tiền tối đa

Hướng dẫn tối ưu hóa chiến lược

  1. Thiết lập chỉ số ATR để lọc biến động
  2. Thêm phân tích âm lượng để cải thiện độ tin cậy tín hiệu
  3. Phát triển cơ chế thích nghi tham số năng động
  4. Cơ chế thu lợi nhuận hoàn hảo để thoát khỏi thời điểm khi xu hướng suy yếu
  5. Thêm mô-đun nhận dạng trạng thái thị trường cho các bộ tham số khác nhau trong các môi trường thị trường khác nhau

Tóm lại

Đây là một chiến lược theo xu hướng được thiết kế tốt đạt được lợi nhuận tốt trong khi duy trì an toàn thông qua sự kết hợp của nhiều chỉ số kỹ thuật.

/*backtest
start: 2019-12-23 08:00:00
end: 2024-12-04 00:00:00
period: 1d
basePeriod: 1d
exchanges: [{"eid":"Futures_Binance","currency":"BTC_USDT"}]
*/

// This Pine Script™ code is subject to the terms of the Mozilla Public License 2.0 at https://mozilla.org/MPL/2.0/
// © Skyrexio

//@version=6
//_______ <licence>
strategy(title = "MultiLayer Awesome Oscillator Saucer Strategy [Skyrexio]", 
         shorttitle = "AO Saucer", 
         overlay = true, 
         format = format.inherit, 
         pyramiding = 5, 
         calc_on_order_fills = false, 
         calc_on_every_tick = false, 
         default_qty_type = strategy.percent_of_equity, 
         default_qty_value = 10, 
         initial_capital = 10000, 
         currency = currency.NONE,  
         commission_type = strategy.commission.percent, 
         commission_value = 0.1,
         slippage = 5,
         use_bar_magnifier = true)


//_______ <constant_declarations>
var const color skyrexGreen               = color.new(#2ECD99, 0)
var const color skyrexGray                = color.new(#F2F2F2, 0)
var const color skyrexWhite               = color.new(#FFFFFF, 0)


//________<variables declarations>
var int trend                             = 0
var float upFractalLevel                  = na
var float upFractalActivationLevel        = na
var float downFractalLevel                = na
var float downFractalActivationLevel      = na
var float saucerActivationLevel           = na
bool highCrossesUpfractalLevel            = ta.crossover(high, upFractalActivationLevel)
bool lowCrossesDownFractalLevel           = ta.crossunder(low, downFractalActivationLevel)
var int signalsQtyInRow                   = 0


//_______ <inputs>
// Trading bot settings
sourceUuid               = input.string(title = "sourceUuid:", defval = "yourBotSourceUuid", group = "🤖Trading Bot Settings🤖")
secretToken              = input.string(title = "secretToken:", defval = "yourBotSecretToken", group = "🤖Trading Bot Settings🤖")


// Trading period settings
lookBackPeriodStart      = input(title = "Trade Start Date/Time", defval = timestamp('2023-01-01T00:00:00'), group = "🕐Trading Period Settings🕐")
lookBackPeriodStop       = input(title = "Trade Stop Date/Time", defval = timestamp('2025-01-01T00:00:00'), group = "🕐Trading Period Settings🕐")


// Strategy settings
EMaLength                = input.int(100, minval = 10, step = 10, title = "EMA Length", group = "📈Strategy settings📈")


//_______ <function_declarations>
//@function       Used to calculate Simple moving average for Alligator
//@param src      Sourse for smma Calculations
//@param length   Number of bars to calculate smma
//@returns        The calculated smma value 
smma(src, length) =>
    var float smma = na
    sma_value = ta.sma(src, length)
    smma := na(smma) ? sma_value : (smma * (length - 1) + src) / length
    smma

//_______ <calculations>


//Upfractal calculation 
upFractalPrice = ta.pivothigh(2, 2)
upFractal = not na(upFractalPrice) 


//Downfractal calculation 
downFractalPrice = ta.pivotlow(2, 2)
downFractal = not na(downFractalPrice)


//Calculating Alligator's teeth 
teeth = smma(hl2, 8)[5]


//Calculating upfractal and downfractal levels
if upFractal 
    upFractalLevel := upFractalPrice
else
    upFractalLevel := upFractalLevel[1]


if downFractal
    downFractalLevel := downFractalPrice
else
    downFractalLevel := downFractalLevel[1]


//Calculating upfractal activation level, downfractal activation level to approximate the trend and this current trend 
if upFractalLevel > teeth
    upFractalActivationLevel := upFractalLevel

if highCrossesUpfractalLevel
    trend := 1
    upFractalActivationLevel := na 
    downFractalActivationLevel := downFractalLevel


if downFractalLevel < teeth
    downFractalActivationLevel := downFractalLevel

if lowCrossesDownFractalLevel
    trend := -1
    downFractalActivationLevel := na 
    upFractalActivationLevel := upFractalLevel


if trend == 1
    upFractalActivationLevel := na

if trend == -1
    downFractalActivationLevel := na


//Calculating filter EMA 
filterEMA = ta.ema(close, EMaLength)


//Сalculating AO saucer signal
ao = ta.sma(hl2,5) - ta.sma(hl2,34)
diff = ao - ao[1]
saucerSignal = ao > ao[1] and ao[1] < ao[2] and ao > 0 and ao[1] > 0 and ao[2] > 0 and trend == 1 and close > filterEMA


//Calculating sauser activation level
if saucerSignal
    saucerActivationLevel := high    
else 
    saucerActivationLevel := saucerActivationLevel[1]


if not na(saucerActivationLevel[1]) and high < saucerActivationLevel[1] and diff > 0
    saucerActivationLevel := high
    saucerSignal := true
    

if (high > saucerActivationLevel[1] and not na(saucerActivationLevel)) or diff < 0
    saucerActivationLevel := na 


//Calculating number of valid saucer signal in current trading cycle 
if saucerSignal and not saucerSignal[1]
    signalsQtyInRow := signalsQtyInRow + 1


if not na(saucerActivationLevel[1]) and diff < 0 and na(saucerActivationLevel) and not (strategy.opentrades[1] <= strategy.opentrades - 1)
    signalsQtyInRow := signalsQtyInRow - 1


if trend == -1 and trend[1] == 1 
    signalsQtyInRow := 0


//_______ <strategy_calls>
//Defining trade close condition
closeCondition =  trend[1] == 1 and trend == -1


//Cancel stop buy order if current Awesome oscillator column lower, than prevoius 
if diff < 0 
    strategy.cancel_all()

//Strategy entry
if (signalsQtyInRow == 1 and not na(saucerActivationLevel)) 
    strategy.entry(id = "entry1", direction = strategy.long, stop = saucerActivationLevel + syminfo.mintick,  alert_message = '{\n"base": "' + syminfo.basecurrency + '",\n"quote": "' + syminfo.currency + '",\n"position": "entry1",\n"price": "' + str.tostring(close) + '",\n"sourceUuid": "' + sourceUuid + '",\n"secretToken": "' + secretToken + '",\n"timestamp": "' + str.tostring(timenow) + '"\n}')

if (signalsQtyInRow == 2 and not na(saucerActivationLevel)) 
    strategy.entry(id = "entry2", direction = strategy.long, stop = saucerActivationLevel + syminfo.mintick,  alert_message = '{\n"base": "' + syminfo.basecurrency + '",\n"quote": "' + syminfo.currency + '",\n"position": "entry2",\n"price": "' + str.tostring(close) + '",\n"sourceUuid": "' + sourceUuid + '",\n"secretToken": "' + secretToken + '",\n"timestamp": "' + str.tostring(timenow) + '"\n}')

if (signalsQtyInRow == 3 and not na(saucerActivationLevel)) 
    strategy.entry(id = "entry3", direction = strategy.long, stop = saucerActivationLevel + syminfo.mintick,  alert_message = '{\n"base": "' + syminfo.basecurrency + '",\n"quote": "' + syminfo.currency + '",\n"position": "entry3",\n"price": "' + str.tostring(close) + '",\n"sourceUuid": "' + sourceUuid + '",\n"secretToken": "' + secretToken + '",\n"timestamp": "' + str.tostring(timenow) + '"\n}')

if (signalsQtyInRow == 4 and not na(saucerActivationLevel)) 
    strategy.entry(id = "entry4", direction = strategy.long, stop = saucerActivationLevel + syminfo.mintick,  alert_message = '{\n"base": "' + syminfo.basecurrency + '",\n"quote": "' + syminfo.currency + '",\n"position": "entry4",\n"price": "' + str.tostring(close) + '",\n"sourceUuid": "' + sourceUuid + '",\n"secretToken": "' + secretToken + '",\n"timestamp": "' + str.tostring(timenow) + '"\n}')

if (signalsQtyInRow == 5 and not na(saucerActivationLevel)) 
    strategy.entry(id = "entry5", direction = strategy.long, stop = saucerActivationLevel + syminfo.mintick,  alert_message = '{\n"base": "' + syminfo.basecurrency + '",\n"quote": "' + syminfo.currency + '",\n"position": "entry5",\n"price": "' + str.tostring(close) + '",\n"sourceUuid": "' + sourceUuid + '",\n"secretToken": "' + secretToken + '",\n"timestamp": "' + str.tostring(timenow) + '"\n}')

//Strategy exit 
if (closeCondition)
    strategy.close_all(alert_message = '{\n"base": "' + syminfo.basecurrency + '",\n"quote": "' + syminfo.currency + '",\n"position": "close",\n"price": "' + str.tostring(close) + '",\n"sourceUuid": "' + sourceUuid + '",\n"secretToken": "' + secretToken + '",\n"timestamp": "' + str.tostring(timenow) + '"\n}')


//_______ <visuals>
//Plotting shapes for adding to current long trades
gradPercent = if strategy.opentrades == 2
    90
else if strategy.opentrades == 3
    80
else if strategy.opentrades == 4
    70
else if strategy.opentrades == 5
    60

pricePlot = plot(close, title="Price", color=color.new(color.blue, 100))
teethPlot = plot(strategy.opentrades > 1 ? teeth : na, title="Teeth", color= skyrexGreen, style=plot.style_linebr, linewidth = 2)
fill(pricePlot, teethPlot, color = color.new(skyrexGreen, gradPercent))
if strategy.opentrades != 1 and  strategy.opentrades[1] == strategy.opentrades - 1
    label.new(bar_index, teeth, style = label.style_label_up, color = color.lime, size = size.tiny, text="Buy More", textcolor = color.black, text_formatting = text.format_bold)


//_______ <alerts>
Có liên quan
Thêm nữa

2019 FMZ - Tất cả các quyền được bảo lưu