资源加载中... loading...
  1. Square
  2. Self-adaptive Quant Grid Trading Strategy

Self-adaptive Quant Grid Trading Strategy

Author: ChaoZhang, Date: 2024-02-02 18:08:22
Tags:

img

Overview

This strategy establishes a dynamic trading grid to achieve steady profits amid volatile markets. It automatically calculates grid spacing and upper/lower limit based on the preset number of grid lines. When the price breaks through each grid line, long/short positions will be built up in batches. Profits will be taken when the price hits the original grid lines again. The strategy supports both manual and automatic adjustment of grid parameters to adapt itself to changing market conditions.

Strategy Logic

  1. Calculate grid boundaries and grid line price array based on input parameters.

  2. When the price falls below a grid line without corresponding orders, long orders will be placed at the grid line price. When the price rises above the previous grid line (the first excluded) with existing position, the long orders of the previous line will be closed.

  3. If auto adjustment is enabled, grid upper/lower limits, grid spacing and grid arrays will be recalculated periodically based on recent candlestick data.

Advantage Analysis

  1. Realize steady profits amid volatile market. Long/short positions are built up and closed in batches at different price levels to achieve overall profit.

  2. Support both manual and automatic parameter adjustment. Manual adjustment offers better control but requires intervention. Automatic adjustment reduces workload and adapts to changing market dynamics.

  3. Max loss capped by limiting max number of grid lines. When price breaks all grid lines, risks are contained.

  4. Tune grid spacing to adjust profit/loss per trade. Smaller spacing lowers exposure per trade.

Risk Analysis

  1. Risk of being trapped in whipswa. Frequent price oscillation within grid range may lead to losses.

  2. Require adequate initial capital. Insufficient funding cannot support enough grid lines.

  3. Extreme grid numbers disadvantage profits. Too few grids fail to take full advantage of volatility while too many grids lead to minimal profits per trade. Extensive testing needed to determine optimal settings.

  4. Auto adjustment risks price manipulation. Relies on recent candlesticks which can be affected by short-term price operations.

Optimization

  1. Introduce stop loss logic such as trailing stop loss to futher restrict downside risk per direction.

  2. Optimize grid parameters via machine learning. Test different parameters across market conditions and train ML models to obtain optimal, adaptive parameters.

  3. Incorporate additional technical indicators. Assess current trend strength with indicators like MACD and RSI to guide grid quantity and parameter tuning.

  4. Enhance risk control by setting maximum allowable drawdown percentage. Disable strategy when threshold is breached to prevent further losses.

Conclusion

This strategy fully utilizes the characteristics of volatile markets and achieves steady profits through dynamic grid trading framework that offers both parameter flexibility and ease of operation. With further enhancements in loss control and automatic parameter optimization, it can become an ideal model for creating durable profits from market fluctuations.

/*backtest
start: 2024-01-02 00:00:00
end: 2024-02-01 00:00:00
period: 1h
basePeriod: 15m
exchanges: [{"eid":"Futures_Binance","currency":"BTC_USDT"}]
*/

//@version=4
strategy("(IK) Grid Script", overlay=true, pyramiding=14, close_entries_rule="ANY", default_qty_type=strategy.cash, initial_capital=100.0, currency="USD", commission_type=strategy.commission.percent, commission_value=0.1)
i_autoBounds    = input(group="Grid Bounds", title="Use Auto Bounds?", defval=true, type=input.bool)                             // calculate upper and lower bound of the grid automatically? This will theorhetically be less profitable, but will certainly require less attention
i_boundSrc      = input(group="Grid Bounds", title="(Auto) Bound Source", defval="Hi & Low", options=["Hi & Low", "Average"])     // should bounds of the auto grid be calculated from recent High & Low, or from a Simple Moving Average
i_boundLookback = input(group="Grid Bounds", title="(Auto) Bound Lookback", defval=250, type=input.integer, maxval=500, minval=0) // when calculating auto grid bounds, how far back should we look for a High & Low, or what should the length be of our sma
i_boundDev      = input(group="Grid Bounds", title="(Auto) Bound Deviation", defval=0.10, type=input.float, maxval=1, minval=-1)  // if sourcing auto bounds from High & Low, this percentage will (positive) widen or (negative) narrow the bound limits. If sourcing from Average, this is the deviation (up and down) from the sma, and CANNOT be negative.
i_upperBound    = input(group="Grid Bounds", title="(Manual) Upper Boundry", defval=0.285, type=input.float)                      // for manual grid bounds only. The upperbound price of your grid
i_lowerBound    = input(group="Grid Bounds", title="(Manual) Lower Boundry", defval=0.225, type=input.float)                      // for manual grid bounds only. The lowerbound price of your grid.
i_gridQty       = input(group="Grid Lines",  title="Grid Line Quantity", defval=8, maxval=15, minval=3, type=input.integer)       // how many grid lines are in your grid

f_getGridBounds(_bs, _bl, _bd, _up) =>
    if _bs == "Hi & Low"
        _up ? highest(close, _bl) * (1 + _bd) : lowest(close, _bl)  * (1 - _bd)
    else
        avg = sma(close, _bl)
        _up ? avg * (1 + _bd) : avg * (1 - _bd)

f_buildGrid(_lb, _gw, _gq) =>
    gridArr = array.new_float(0)
    for i=0 to _gq-1
        array.push(gridArr, _lb+(_gw*i))
    gridArr

f_getNearGridLines(_gridArr, _price) =>
    arr = array.new_int(3)
    for i = 0 to array.size(_gridArr)-1
        if array.get(_gridArr, i) > _price
            array.set(arr, 0, i == array.size(_gridArr)-1 ? i : i+1)
            array.set(arr, 1, i == 0 ? i : i-1)
            break
    arr

var upperBound      = i_autoBounds ? f_getGridBounds(i_boundSrc, i_boundLookback, i_boundDev, true) : i_upperBound  // upperbound of our grid
var lowerBound      = i_autoBounds ? f_getGridBounds(i_boundSrc, i_boundLookback, i_boundDev, false) : i_lowerBound // lowerbound of our grid
var gridWidth       = (upperBound - lowerBound)/(i_gridQty-1)                                                       // space between lines in our grid
var gridLineArr     = f_buildGrid(lowerBound, gridWidth, i_gridQty)                                                 // an array of prices that correspond to our grid lines
var orderArr        = array.new_bool(i_gridQty, false)                                                              // a boolean array that indicates if there is an open order corresponding to each grid line

var closeLineArr    = f_getNearGridLines(gridLineArr, close)                                                        // for plotting purposes - an array of 2 indices that correspond to grid lines near price
var nearTopGridLine = array.get(closeLineArr, 0)                                                                    // for plotting purposes - the index (in our grid line array) of the closest grid line above current price
var nearBotGridLine = array.get(closeLineArr, 1)                                                                    // for plotting purposes - the index (in our grid line array) of the closest grid line below current price
strategy.initial_capital = 50000
for i = 0 to (array.size(gridLineArr) - 1)
    if close < array.get(gridLineArr, i) and not array.get(orderArr, i) and i < (array.size(gridLineArr) - 1)
        buyId = i
        array.set(orderArr, buyId, true)
        strategy.entry(id=tostring(buyId), long=true, qty=(strategy.initial_capital/(i_gridQty-1))/close, comment="#"+tostring(buyId))
    if close > array.get(gridLineArr, i) and i != 0
        if array.get(orderArr, i-1)
            sellId = i-1
            array.set(orderArr, sellId, false)
            strategy.close(id=tostring(sellId), comment="#"+tostring(sellId))

if i_autoBounds
    upperBound  := f_getGridBounds(i_boundSrc, i_boundLookback, i_boundDev, true)
    lowerBound  := f_getGridBounds(i_boundSrc, i_boundLookback, i_boundDev, false)
    gridWidth   := (upperBound - lowerBound)/(i_gridQty-1)
    gridLineArr := f_buildGrid(lowerBound, gridWidth, i_gridQty)

closeLineArr    := f_getNearGridLines(gridLineArr, close)
nearTopGridLine := array.get(closeLineArr, 0)
nearBotGridLine := array.get(closeLineArr, 1)
More

2019 FMZ - All rights reserved