এই নিবন্ধটি একটি পরিমাণগত ট্রেডিং কৌশল বিশদভাবে ব্যাখ্যা করে যা ট্রেডিং সংকেত তৈরির জন্য আরএসআই সূচক ব্যবহার করে। এটি আরএসআই সূচকটি প্রক্রিয়া করে এবং দীর্ঘ এবং সংক্ষিপ্ত ব্যবসায়ের জন্য প্রবেশ এবং প্রস্থান মানদণ্ড সেট করে।
I. কৌশলগত যুক্তি
মূল ট্রেডিং লজিক নিম্নরূপঃ
RSI (১৪) সূচক গণনা করুন এবং EMA (২৮) ব্যবহার করে এটি মসৃণ করুন।
উপরের/নিচের ব্যান্ড পেতে প্রক্রিয়াজাত আরএসআই-তে বোলিংজার ব্যান্ড গণনা করুন। অতিরিক্ত ক্রয়/অতিরিক্ত বিক্রয় অঞ্চল সেট করুন।
যখন প্রক্রিয়াজাত আরএসআই এন্ট্রি লাইনের নিচে অতিক্রম করে, তখন একটি ক্রয় সংকেত উৎপন্ন হয়। যখন এটি উপরে অতিক্রম করে, তখন একটি বিক্রয় সংকেত উৎপন্ন হয়।
যখন সূচকটি অতিরিক্ত ক্রয়/অতিরিক্ত বিক্রয় অঞ্চলে প্রবেশ করে, তখন একটি বন্ধ অবস্থানের সংকেত উৎপন্ন হয়।
এইভাবে, RSI এর বৈশিষ্ট্যগুলি বিপরীতমুখী সুযোগগুলি ক্যাপচার করতে ব্যবহার করা যেতে পারে। সূচক প্রক্রিয়াকরণ এছাড়াও সংকেত মান এবং রেফারেন্স মান উন্নত করে।
২. কৌশলটির সুবিধা
সবচেয়ে বড় সুবিধা হল সূচক প্রক্রিয়াকরণ থেকে প্যারামিটার টিউনিং স্পেস বৃদ্ধি, যা ট্রেডিং ফ্রিকোয়েন্সি উপর আরও কঠোর নিয়ন্ত্রণের অনুমতি দেয় এবং ওভারট্রেডিং প্রতিরোধ করে।
আরেকটি সুবিধা হল সূচকের স্পষ্ট সংখ্যাসূচক মানের উপর ভিত্তি করে স্বজ্ঞাত প্রবেশের মানদণ্ড।
অবশেষে, অতিরিক্ত ক্রয়/অতিরিক্ত বিক্রয়ের পরিসীমা ব্যবসায়ের জন্য সময়মত মুনাফা গ্রহণ এবং ঝুঁকি নিয়ন্ত্রণেও সহায়তা করে।
৩. সম্ভাব্য দুর্বলতা
তবে, এই কৌশলটি নিম্নলিখিত ঝুঁকিগুলিও বহন করেঃ
প্রথমত, আরএসআই বিপরীতমুখী ট্রেডগুলিতে মনোনিবেশ করে, যা প্রবণতার সময় মিথ্যা সংকেত তৈরি করতে পারে।
দ্বিতীয়ত, অনুপযুক্ত পরামিতিগুলিও অতিরিক্ত অপ্টিমাইজেশান এবং পরিবর্তিত বাজারের অবস্থার সাথে মানিয়ে নিতে ব্যর্থ হতে পারে।
অবশেষে, তুলনামূলকভাবে কম জয়ের হার কৌশলটিকে প্রত্যাহারের ঝুঁকিতে ফেলে দেয়।
IV. সংক্ষিপ্ত বিবরণ
সংক্ষেপে, এই নিবন্ধটি মূলত আরএসআই সূচক ব্যবহার করে একটি পরিমাণগত ট্রেডিং কৌশল প্রবর্তন করে। এটি পরামিতি টিউনিংয়ের মাধ্যমে বাণিজ্য ফ্রিকোয়েন্সি নিয়ন্ত্রণ করে এবং পরিষ্কার প্রবেশ / প্রস্থান নিয়ম রয়েছে। পরামিতিগুলি অনুকূল করার সময়, বিপরীত ট্রেডিংয়ের ঝুঁকিগুলিও পরিচালনা করা দরকার। সামগ্রিকভাবে, এটি একটি সহজ এবং স্বজ্ঞাত আরএসআই কৌশল কাঠামো সরবরাহ করে।
/*backtest
start: 2023-08-14 00:00:00
end: 2023-09-13 00:00:00
period: 3h
basePeriod: 15m
exchanges: [{"eid":"Futures_Binance","currency":"BTC_USDT"}]
*/
//@version=5
//-----------------------------------------------------------------
//This simple strategy base on RSI, EMA, Bollinger Bands to get Buy and Sell Signal with detail as below:
//-----------------------------------------------------------------
//1.Define Oscillator Line
//+ Oscillator Line is smoothed by ema(28) of RSI(14) on H1 Timeframe
//2.Define Overbought and Oversold
//+ Apply Bollinger Bands BB(80,3) on Oscillator Line and calculate %b
//+ Overbought Zone marked above level 0.8
//+ Oversold Zone marked below level 0.2
//3.Buy Signal
//+ Entry Long Positon when %b crossover Point of Entry Long
//+ Deafault Point of Entry Long is 0.2
//+ Buy signal marked by Green dot
//4.Sell Signal
//+ Entry Short Position when %b crossunder Point of Entry Short
//+ Deafault Point of Entry Short is 0.8
//+ Sell signal marked by Red dot
//5.Exit Signal
//+ Exit Position (both Long and Short) when %b go into Overbought Zone or Oversold Zone
//+ Exit signal marked by Yellow dot
//-----------------------------------------------------------------
strategy(title="RSI %b Signal [H1 Backtesting]", overlay=false)
//RSI
rsi_gr="=== RSI ==="
rsi_len = input(14, title = "RSI",inline="set",group=rsi_gr)
smoothed_len = input(28, title = "EMA",inline="set",group=rsi_gr)
rsi=ta.ema(ta.rsi(close,rsi_len),smoothed_len)
//rsi's BOLLINGER BANDS
pb_gr="=== %b ==="
length = input(80, title = "Length",inline="set1",group=pb_gr)
rsimult = input(3.0, title = "Multiplier",inline="set1",group=pb_gr)
ovb = input(0.8, title = "Overbought",inline="set2",group=pb_gr)
ovs = input(0.2, title = "Oversold",inline="set2",group=pb_gr)
et_short = input(0.8, title = "Entry Short",inline="set3",group=pb_gr)
et_long = input(0.2, title = "Entry Long",inline="set3",group=pb_gr)
[rsibasis, rsiupper, rsilower] = ta.bb(rsi, length, rsimult)
//rsi's %B
rsipB = ((rsi - rsilower) / (rsiupper - rsilower))
plot(rsipB, title="rsi's %B", color=rsipB>math.min(ovb,et_short)?color.red:rsipB<math.max(ovs,et_long)?color.green:color.aqua, linewidth=1)
h1=hline(1,color=color.new(color.red,100))
h4=hline(ovb,color=color.new(color.red,100))
h0=hline(0,color=color.new(color.green,100))
h3=hline(ovs,color=color.new(color.green,100))
h5=hline(0.5,color=color.new(color.silver,0),linestyle=hline.style_dotted)
fill(h1,h4, title="Resistance", color=color.new(color.red,90))
fill(h0,h3, title="Support", color=color.new(color.green,90))
//Signal
rsi_buy=
rsipB[1]<et_long
and
rsipB>et_long
rsi_sell=
rsipB[1]>et_short
and
rsipB<et_short
rsi_exit=
(rsipB[1]>ovs and rsipB<ovs)
or
(rsipB[1]<ovb and rsipB>ovb)
plotshape(rsi_buy?rsipB:na,title="Buy",style=shape.circle,color=color.new(color.green,0),location=location.absolute)
plotshape(rsi_sell?rsipB:na,title="Sell",style=shape.circle,color=color.new(color.red,0),location=location.absolute)
plotshape(rsi_exit?rsipB:na,title="Exit",style=shape.circle,color=color.new(color.yellow,0),location=location.absolute)
//Alert
strategy.entry("Long",strategy.long,when=rsi_buy)
strategy.close("Long",when=rsi_exit)
strategy.entry("Short",strategy.short,when=rsi_sell)
strategy.close("Short",when=rsi_exit)
//EOF