1. বর্গক্ষেত্র
2. আলফা ট্রেন্ড এবং কামাকে ঝুঁকি ব্যবস্থাপনার সাথে একত্রিত করার কৌশল অনুসরণ করে অভিযোজনমূলক প্রবণতা

আলফা ট্রেন্ড এবং কামাকে ঝুঁকি ব্যবস্থাপনার সাথে একত্রিত করার কৌশল অনুসরণ করে অভিযোজনমূলক প্রবণতা

লেখক:চাওঝাং, তারিখঃ ২০২৪-০৭-৩০ ১২ঃ৩০ঃ১৯
ট্যাগঃকামাএটিআরএমএফআইআরএসআই

---

---

/*backtest
start: 2024-06-01 00:00:00
end: 2024-06-30 23:59:59
period: 2h
basePeriod: 15m
exchanges: [{"eid":"Futures_Binance","currency":"BTC_USDT"}]
*/

//@version=5
strategy('AlphaTrend with KAMA and Risk Management', shorttitle='AT+KAMA+RM', overlay=true, format=format.price, precision=2, initial_capital=100000, default_qty_type=strategy.percent_of_equity, default_qty_value=100)

// AlphaTrend Inputs
coeff = input.float(1, 'AT Multiplier', step=0.1)
AP = input.int(14, 'AT Common Period', minval=1)
src = input.source(close, 'AT Source')
showsignals = input.bool(true, 'Show Signals?')
novolumedata = input.bool(false, 'Change calculation (no volume data)?')

// KAMA Inputs
kamaLength = input.int(21, 'KAMA Length', minval=1)

// Risk Management Inputs
profitTarget = input.float(10, 'Profit Target for Partial Exit (%)', minval=1, step=0.1)

// Yeni değişkenler
var float entryPrice = na
var string currentPosition = "flat"  // "long", "short", veya "flat"
var float partialExitPrice = na

// AlphaTrend Calculation
ATR = ta.sma(ta.tr, AP)
upT = low - ATR * coeff
downT = high + ATR * coeff
AlphaTrend = 0.0
AlphaTrend := (novolumedata ? ta.rsi(src, AP) >= 50 : ta.mfi(hlc3, AP) >= 50) ? upT < nz(AlphaTrend[1]) ? nz(AlphaTrend[1]) : upT : downT > nz(AlphaTrend[1]) ? nz(AlphaTrend[1]) : downT

// KAMA Calculation
xPrice = close
xvnoise = math.abs(xPrice - xPrice[1])
nAMA = 0.0
nfastend = 0.666
nslowend = 0.0645
nsignal = math.abs(xPrice - xPrice[kamaLength])

// Manual calculation of sum
nnoise = 0.0
for i = 0 to kamaLength-1
    nnoise := nnoise + xvnoise[i]
nefratio = nnoise != 0 ? nsignal / nnoise : 0
nsmooth = math.pow(nefratio * (nfastend - nslowend) + nslowend, 2)
nAMA := nz(nAMA[1]) + nsmooth * (xPrice - nz(nAMA[1]))

// Plotting
color1 = AlphaTrend > AlphaTrend[2] ? #00E60F : AlphaTrend < AlphaTrend[2] ? #80000B : AlphaTrend[1] > AlphaTrend[3] ? #00E60F : #80000B
k1 = plot(AlphaTrend, color=color.new(#0022FC, 0), linewidth=3, title='AlphaTrend')
k2 = plot(AlphaTrend[2], color=color.new(#FC0400, 0), linewidth=3)
fill(k1, k2, color=color1)
plot(nAMA, color=color.yellow, linewidth=2, title='KAMA')

// Sinyal koşulları
buyCondition = (ta.crossover(nAMA, AlphaTrend) and ta.crossover(nAMA, AlphaTrend[2])) or
             (ta.crossover(nAMA, AlphaTrend) and nAMA > AlphaTrend[2]) or
             (ta.crossover(nAMA, AlphaTrend[2]) and nAMA > AlphaTrend)
sellCondition = (ta.crossunder(nAMA, AlphaTrend) and ta.crossunder(nAMA, AlphaTrend[2])) or
              (ta.crossunder(nAMA, AlphaTrend) and nAMA < AlphaTrend[2]) or
              (ta.crossunder(nAMA, AlphaTrend[2]) and nAMA < AlphaTrend)

// Yeni Sinyaller
buySignal = buyCondition
sellSignal = sellCondition

// Alım satım mantığı
if (buySignal and currentPosition != "long")
    if (currentPosition == "short")
        strategy.close("Short")
    strategy.entry("Long", strategy.long)
    entryPrice := close
    currentPosition := "long"
    partialExitPrice := entryPrice * (1 + profitTarget / 100)

if (sellSignal and currentPosition != "short")
    if (currentPosition == "long")
        strategy.close("Long")
    strategy.entry("Short", strategy.short)
    entryPrice := close
    currentPosition := "short"
    partialExitPrice := entryPrice * (1 - profitTarget / 100)

// Kısmi çıkış mantığı
if (currentPosition == "long" and high >= partialExitPrice)
    strategy.close("Long", comment="Partial Exit at " + str.tostring(profitTarget) + "% profit", qty_percent=50)
    partialExitPrice := na
if (currentPosition == "short" and low <= partialExitPrice)
    strategy.close("Short", comment="Partial Exit at " + str.tostring(profitTarget) + "% profit", qty_percent=50)
    partialExitPrice := na

// Plotting signals
plotshape(buySignal and showsignals ? AlphaTrend * 0.9999 : na, title='BUY', text='BUY', location=location.absolute, style=shape.labelup, size=size.tiny, color=color.new(#0022FC, 0), textcolor=color.new(color.white, 0))
plotshape(sellSignal and showsignals ? AlphaTrend * 1.0001 : na, title='SELL', text='SELL', location=location.absolute, style=shape.labeldown, size=size.tiny, color=color.new(color.maroon, 0), textcolor=color.new(color.white, 0))
plotshape(currentPosition == "long" and high >= partialExitPrice ? high : na, title='PARTIAL EXIT LONG', text='PARTIAL', location=location.absolute, style=shape.labeldown, size=size.tiny, color=color.new(color.orange, 0), textcolor=color.new(color.white, 0))
plotshape(currentPosition == "short" and low <= partialExitPrice ? low : na, title='PARTIAL EXIT SHORT', text='PARTIAL', location=location.absolute, style=shape.labelup, size=size.tiny, color=color.new(color.orange, 0), textcolor=color.new(color.white, 0))

// Alerts
alertcondition(buySignal, title='BUY Signal', message='KAMA crossed above AlphaTrend - BUY!')
alertcondition(sellSignal, title='SELL Signal', message='KAMA crossed below AlphaTrend - SELL!')
alertcondition((currentPosition == "long" and high >= partialExitPrice) or (currentPosition == "short" and low <= partialExitPrice), title='Partial Exit', message='Profit target reached - Closing half position!')

---

• মাল্টি-ইন্ডিকেটর ইন্টেলিজেন্ট পিরামিডিং কৌশল
• RSI ট্রেন্ড বিপরীত কৌশল
• আরএসআই-বোলিংজার ব্যান্ড ইন্টিগ্রেশন স্ট্র্যাটেজিঃ একটি গতিশীল স্ব-অ্যাডাপ্টিভ মাল্টি-ইনডিকেটর ট্রেডিং সিস্টেম
• মঙ্গলবারের টার্নআরাউন্ড কৌশল (উইকেন্ড ফিল্টার)
• মাল্টি-লেভেল ডায়নামিক ট্রেন্ড অনুসরণ সিস্টেম
• ট্রেলিং স্টপ লস স্ট্র্যাটেজি সহ চলমান গড় ক্রসওভার
• EMA RSI ক্রসওভার কৌশল
• RSI50_EMA লং-একমাত্র কৌশল
• সামগ্রিক মূল্য ফাঁক সংক্ষিপ্ত মেয়াদী প্রবণতা ধরা কৌশল
• ATR-RSI উন্নত ট্রেন্ড অনুসরণকারী ট্রেডিং সিস্টেম

---

• অ্যাডভান্সড কম্পোজিট মুভিং এভারেজ এবং মার্কেট ইম্পোমেন্টাম ট্রেন্ড ক্যাপচার স্ট্র্যাটেজি
• অ্যাডভান্সড ফিবোনাচি রিট্রেসিং এবং ভলিউম-ওয়েটেড প্রাইস অ্যাকশন ট্রেডিং কৌশল
• অ্যাডাপ্টিভ স্ট্যান্ডার্ড ডিভিয়েশন ব্রেকআউট ট্রেডিং স্ট্র্যাটেজিঃ ডায়নামিক ভোল্টেবিলিটি ভিত্তিক মাল্টি-পিরিয়ড অপ্টিমাইজেশন সিস্টেম
• ডায়নামিক পজিশন ডাবল মুভিং এভারেজ ক্রসওভার কৌশল
• এটিআর এবং ভলিউমকে একত্রিত করার কৌশল অনুসরণ করে ডাইনামিক সিগন্যাল লাইন ট্রেন্ড
• মাল্টি ইন্ডিকেটর ডায়নামিক ভোলটাইলিটি অ্যালার্ট ট্রেডিং সিস্টেম
• গ্যানের কোণে ভিত্তিক গতিশীল ট্রেডিং কৌশল
• ভিডাব্লুএপি-এটিআর ট্রেন্ড অনুসরণ এবং মূল্য বিপরীত কৌশল
• Bollinger Bands RSI Neutral Market Quantitative Trading Strategy Bollinger Bands RSI RSI Neutral Market Quantitative Trading Strategy Bollinger Bands RSI RSI Neutral Market Quantitative Trading Strategy Bollinger Bands RSI RSI Neutral Market Quantitative Trading Strategy Bollinger Bands RSI Neutral Market Neutral Market Quantitative Trading Strategy Bollinger Bands RSI ন্যূনতম বাজার নিরপেক্ষ পরিমাণিক ট্রেডিং কৌশল
• মাল্টি-লেভেল ওভারসোল্ড অ্যাসিললেটর কেনার কৌশল
• ডাবল ইন্ডিকেটর ক্রস কনফার্মেশন মম্পটাম ভলিউম পরিমাণগত ট্রেডিং কৌশল
• গতিশীল প্রবণতা অনুসরণকারী কৌশল - মাল্টি-ইন্ডিক্টর ইন্টিগ্রেটেড মম্পটাম বিশ্লেষণ সিস্টেম
• মাল্টি-ইএমএ এবং সুপারট্রেন্ড ক্রসওভার কৌশল
• গতিশীল গড় বিপরীত এবং গতিশীল কৌশল
• ডুয়াল ইএমএ ডায়নামিক ট্রেন্ড ক্যাপচার ট্রেডিং সিস্টেম
• মাল্টি-কনফার্মেশন বিপরীত ক্রয় কৌশল
• উন্নত ডুয়াল ইএমএ পুলব্যাক ব্রেকআউট ট্রেডিং কৌশল
• মাল্টি-টাইমফ্রেম এক্সপোনেনশিয়াল মুভিং এভারেজ ক্রসওভার কৌশল
• মাল্টি-পিরিয়ড ডায়নামিক চ্যানেল ক্রসওভার কৌশল
• সামগ্রিক মূল্য ফাঁক সংক্ষিপ্ত মেয়াদী প্রবণতা ধরা কৌশল