Thermometer-Strategie in der Praxis und Anwendung von Quantifizierungsplattformen für Erfinder

Warum man es Thermometer nennt. Wir haben das System nach seiner Anpassungsfähigkeit benannt, um in den beiden Modellen des Marktes, der Erschütterungen und Trends umzuwandeln und zu handeln. Das System stammt aus unserer Beobachtung des Erfolgs bestimmter Systeme in bestimmten Marktbereichen.

Zunächst erstellen wir eine Funktion, die hilft, Marktmuster zu bestimmen. Aufgrund der Ausgabe dieser Funktion wechselt der Thermostat vom Folge-Modus in den Kurzzeit-Schwank-Modus.

Der Trend-Tracking-Modus verwendet einen ähnlichen Trend-Tracking-Mechanismus wie der in der Breitband-Reihe. Die kurzfristige Schwingung ist ein offenes Durchbruchssystem, das die Patternerkennung enthält. Diese Funktion vergleicht die Entfernung, die der Markt anläuft, mit der tatsächlichen Entfernung, die der Markt geht:

Abs ((Abschlusspreis - Abschlusspreis[29])/ ((Höchster Preis ((30) - Niedriger Preis ((Niedriger Preis, 30 Tage) * 100

Die Funktion erzeugt einen Wert zwischen 0 und 100. Je größer der Wert, desto geringer ist die Überlastung des aktuellen Marktes. Wenn die Funktion einen Wert von weniger als 20 zurückgibt, tritt das System in einen kurzfristigen Schwingungsmodus ein.

Grundsätzlich zeigt der größte Teil des Marktes eine schwankende Bewegung, bei der das System versucht, die Schwankungen zu ergreifen und einen geringen Gewinn daraus zu machen. Der Thermostat versucht, diese Leistung durch einen kleinen Kauf/Verkaufspurt zu erreichen. Wenn die Schwankungen groß genug sind, wechselt das System das Modell.

Durch eine eingehende Analyse von kurzfristigen Schwankungen haben wir festgestellt, dass es manchmal besser ist, zu kaufen, als zu verkaufen, und umgekehrt. Diese Zeiten lassen sich durch ein einfaches visuelles Modell bestimmen. Wenn der Schlusskurs heute höher ist als die Höhen, Tiefen und Schlusskurs von gestern (auch als Schlüsselpunkte des Tages bezeichnet), denken wir, dass die Marktbewegung morgen möglicherweise nach unten geht.

Die Thermostat-Strategie ist eine sehr beliebte Strategie auf der Inventor-Quantifizierungsplattform, bei der Benutzer zusätzliche Handelslogik hinzufügen, um die Strategie noch besser zu machen, je nach ihren Bedürfnissen.

• Die Hauptdarstellung: Auflaufformel: TOP^^MAC+N_TMPTMP;//Brin-Kanal auflauf Unterbahnformel: BOTTOM^^MAC-N_TMPTMP;//Brin-Kanal unterbahn

• Das Bild zeigt: CMI-Formel: CMI:ABS ((C-REF ((C,N_CMI-1))/HHV ((H,N_CMI) -LLV ((L,N_CMI)) *100;//0-100 Je größer die Auswertung ist, desto stärker ist der Trend, CMI <20 für die Erschütterungsart, CMI>20 für den Trend.

• Der Code ((My Language)):

MAC:=MA(CLOSE,N);
TMP:=STD(CLOSE,N);
TOP^^MAC+N_TMP*TMP;      // 布林通道上轨
BOTTOM^^MAC-N_TMP*TMP;   // 布林通道下轨
BBOLL:=C>MAC;
SBOLL:=C<MAC;
N_CMI:=30;

CMI:ABS(C-REF(C,N_CMI-1))/(HHV(H,N_CMI)-LLV(L,N_CMI))*100; //0-100 取值越大，说明趋势越强，CMI<20震荡模式，CMI>20为趋势

N_KD:=9;
M1:=3;
M2:=3;
RSV:=(CLOSE-LLV(LOW,N_KD))/(HHV(HIGH,N_KD)-LLV(LOW,N_KD))*100; //收盘价与N周期最低值做差，N周期最高值与N周期最低值做差，两差之间做比值。

K:=SMA(RSV,M1,1); //RSV的移动平均值
D:=SMA(K,M2,1);   //K的移动平均值
MIND:=30;
BKD:=K>D AND D<MIND;
SKD:=K<D AND D>100-MIND;

// 震荡模式
BUYPK1:=CMI < 20 AND BKD;  //震荡多单买平开
SELLPK1:=CMI < 20 AND SKD; //震荡空单卖平开

// 趋势模式下原有震荡持仓的处理
SELLY1:=REF(CMI,BARSBK) < 20 AND C>BKPRICE*(1+0.01*STOPLOSS*3) AND K<D; //震荡多单止盈
BUYY1:=REF(CMI,BARSSK) < 20 AND C<SKPRICE*(1-0.01*STOPLOSS*3) AND K>D;  //震荡空单止盈

// 趋势模式
BUYPK2:=CMI >= 20 AND C > TOP;        // 趋势多单买平开
SELLPK2:=CMI >= 20 AND C < BOTTOM;    // 趋势空单卖平开

// 趋势模式下原有震荡持仓的处理
SELLY2:=REF(CMI,BARSBK) >= 20 AND C>BKPRICE*(1+0.01*STOPLOSS*3) AND SBOLL;//趋势多单止盈
BUYY2:=REF(CMI,BARSSK) >= 20 AND C<SKPRICE*(1-0.01*STOPLOSS*3) AND BBOLL;//趋势空单止盈
SELLS2:=REF(CMI,BARSBK) >= 20 AND C<BKPRICE*(1-0.01*STOPLOSS) AND SBOLL;//趋势多单止损
BUYS2:=REF(CMI,BARSSK) >= 20 AND C>SKPRICE*(1+0.01*STOPLOSS) AND BBOLL;//趋势空单止损

IF BARPOS>N THEN BEGIN
    BUYPK1,BPK;
    SELLPK1,SPK;
    BUYPK2,BPK;
    SELLPK2,SPK;
END
BUYY1,BP(SKVOL);
BUYY2,BP(SKVOL);
BUYS2,BP(SKVOL);
SELLY1,SP(BKVOL);
SELLY2,SP(BKVOL);
SELLS2,SP(BKVOL);

Die Ergebnisse der Strategie sind wie folgt:

Weitere Informationen finden Sie unter:https://www.fmz.com/strategy/129086