Der Moving Average (MA) hat eine Trendcharakteristik, die im Gegensatz zur Tages-K-Linie, die steigt und fällt, relativ stabil ist. Je länger der gleitende Durchschnitt, desto stabiler die Performance. Nicht leicht nach oben und unten, man muss auf die wahre Klarheit des Aktienpreistrends warten. Der gleitende Durchschnitt ist letztlich ein Trend-Tracking-Tool, das es leicht macht zu erkennen, ob ein Trend beendet oder umgekehrt ist und ob ein neuer Trend entsteht.
In dieser Ausgabe teilen wir die Kombinationsstrategie des MACD+MA-Index. In der technischen Analyse ist die Kombination von Indikatoren sehr verbreitet. Verschiedene Indikatoren haben unterschiedliche Betriebspunkte und Analysemethoden. Die Kombination von Indikatoren kann die Genauigkeit des Signals verbessern. Die Strategie besteht darin, die Beziehung zwischen Preis und MA zu vergleichen und dann die Beschleunigung der Preisbewegung durch den MACD-Index zu messen, um den Marktzustand zu beurteilen und eine einfache Timing-Handelsstrategie zu konstruieren.
(*backtest
start: 2018-11-01 00:00:00
end: 2018-11-22 00:00:00
period: 1h
exchanges: [{"eid":"Bitfinex","currency":"BTC_USD"}]
*)
// MACD calculation
FASTLENGTH:=12;
SLOWLENGTH:=26;
MACDLENGTH:=9;
// Length of MA
L1:=50;
L2:=120;
// stop loss 止损 5%
STOPLOSS:=5;
//MACD
MACDVALUE:=EMA(CLOSE,FASTLENGTH)-EMA(CLOSE,SLOWLENGTH);
AVGMACD:=EMA(MACDVALUE,MACDLENGTH);
MACDDIFF:=MACDVALUE-AVGMACD;
//MA1、MA2
DMA1:=MA(C,L1);
DMA2:=MA(C,L2);
BUYCONDITION:=MACDVALUE>0 && DMA1>DMA2 && MACDDIFF>0 && C>DMA1 && REF(C,1)>REF(DMA1,1);
SELLCONDITION:=MACDVALUE<0 && DMA1<DMA2 && MACDDIFF<0 && C<DMA1 && REF(C,1)<REF(DMA1,1);
// 开仓条件 When to open position
BKVOL=0 AND BUYCONDITION,BK;
SETSIGPRICETYPE(BK,NEW_ORDER);
SKVOL=0 AND SELLCONDITION,SK;
SETSIGPRICETYPE(SK,NEW_ORDER);
// 离场条件 When to close position
BKVOL>0 AND (REF(MACDVALUE,1)<0 OR REF(DMA1,1)<REF(DMA2,1)),SP;
SKVOL>0 AND (REF(MACDVALUE,1)>0 OR REF(DMA1,1)>REF(DMA2,1)),BP;
// 启动止损 Start stop loss
SKVOL>0 AND HIGH>=SKPRICE*(1+STOPLOSS*0.01),BP;
BKVOL>0 AND LOW<=BKPRICE*(1-STOPLOSS*0.01),SP;
AUTOFILTER;