En la carga de los recursos... Cargando...
  1. Cuadrado
  2. Estrategia de divergencia de los indicadores de rentabilidad basada en el eje

Estrategia de divergencia de los indicadores de rentabilidad basada en el eje

El autor:¿ Qué pasa?, Fecha: 2023-11-28 13:43:05
Las etiquetas:

img

Resumen general

Esta estrategia se llama Estrategia de Divergencia del RSI basada en el pivote. Utiliza la divergencia entre los indicadores del RSI en diferentes ciclos para determinar los puntos de entrada y salida, y agrega el RSI a largo plazo como condición de filtro para mejorar la estabilidad de la estrategia.

Estrategia lógica

La estrategia evalúa principalmente la oportunidad de comprar cuando hay una divergencia alcista oculta o divergencia alcista regular entre el RSI a corto plazo (como el RSI de 5 días) y el precio; y vender cuando hay una divergencia bajista oculta o divergencia bajista regular.

Una divergencia alcista regular significa que el precio hace un nuevo mínimo mientras que el RSI no hace un nuevo mínimo; una divergencia alcista oculta es lo contrario, el precio no hace un nuevo mínimo mientras que el RSI hace un nuevo mínimo.

Además, la estrategia también introduce el RSI a largo plazo (como el RSI de 50 días) como una condición de filtro. Solo considera las señales de compra cuando el RSI largo es mayor de 50; y considera la salida de stop loss o take profit cuando el RSI largo es menor de 30.

Ventajas

La mayor ventaja de esta estrategia es que utiliza tanto las señales de divergencia del RSI a corto plazo como el filtro del RSI a largo plazo, lo que puede evitar quedar atrapado y perder tendencias hasta cierto punto.

  1. La señal de divergencia del RSI a corto plazo puede dar una evaluación temprana de las oportunidades de reversión de precios y captar puntualmente los puntos de inflexión;
  2. El filtro del RSI a largo plazo evita pasar a largo ciegamente cuando la tendencia es incierta;
  3. Los diversos tipos de métodos de obtención de beneficios y la obtención parcial de beneficios ayudan a reducir el riesgo;
  4. El mecanismo de pirámide permite agregar posiciones y amplía aún más el potencial de ganancia.

Los riesgos

La estrategia también tiene algunos riesgos:

  1. Las divergencias del RSI no siempre son válidas y pueden presentarse señales falsas;
  2. Los riesgos se amplifican después de la pirámide. Las pérdidas podrían acelerarse si el juicio es erróneo;
  3. Los ajustes inadecuados de la toma de beneficios también pueden conducir a una toma de beneficios prematura o a beneficios insuficientes.

Las medidas de gestión del riesgo correspondientes incluyen: establecer razonablemente las condiciones de stop loss/take profit, controlar el tamaño de las posiciones, obtener ganancias parciales para suavizar la curva de renta variable, etc.

Direcciones de optimización

Hay margen para una mayor optimización de la estrategia:

  1. Los parámetros del RSI pueden optimizarse aún más para encontrar la mejor combinación;
  2. Las señales de divergencia de otros indicadores, como el MACD y el KD, pueden probarse.
  3. Los parámetros pueden optimizarse específicamente para determinados productos (como el petróleo crudo, los metales preciosos, etc.) para mejorar la adaptabilidad.

Resumen de las actividades

Esta estrategia combina las señales de divergencia RSI a corto/largo plazo y a largo plazo para mejorar la rentabilidad mientras se controlan los riesgos. Refleja múltiples principios en el diseño de estrategias cuantitativas, incluyendo cuándo entrar, cuándo salir, tomar ganancias parciales, establecer stop loss/take profit, etc. Esta es una estrategia de divergencia RSI ejemplar para referencia.

/*backtest
start: 2023-11-20 00:00:00
end: 2023-11-27 00:00:00
period: 5m
basePeriod: 1m
exchanges: [{"eid":"Futures_Binance","currency":"BTC_USDT"}]
*/

// This source code is subject to the terms of the Mozilla Public License 2.0 at https://mozilla.org/MPL/2.0/
// © mohanee

//@version=4

//GOOGL setting  5 ,50 close, 3 , 1  profitLevel at 75 and No stop Loss shows win rate 99.03 % profit factor 5830.152

strategy(title="RSI5_50 with Divergence", overlay=false,pyramiding=2, default_qty_type=strategy.fixed, default_qty_value=3,    initial_capital=10000, currency=currency.USD)

len = input(title="RSI Period", minval=1, defval=5)
longRSILen = input(title="Long RSI Period", minval=10, defval=50)
src = input(title="RSI Source", defval=close)
lbR = input(title="Pivot Lookback Right", defval=3)
lbL = input(title="Pivot Lookback Left", defval=1)
takeProfitRSILevel = input(title="Take Profit at RSI Level", minval=50, defval=75)
stopLoss = input(title="Stop Loss%(if checked 8% rule applied)", defval=false)

shortTermRSI = rsi(close,len)
longTermRSI = rsi(close,longRSILen)

rangeUpper = input(title="Max of Lookback Range", defval=60)
rangeLower = input(title="Min of Lookback Range", defval=5)
plotBull = input(title="Plot Bullish", defval=true)
plotHiddenBull = input(title="Plot Hidden Bullish", defval=true)
plotBear = input(title="Plot Bearish", defval=true)
plotHiddenBear = input(title="Plot Hidden Bearish", defval=false)


bearColor = color.purple
bullColor = color.green
hiddenBullColor = color.new(color.green, 80)
hiddenBearColor = color.new(color.red, 80)
textColor = color.white
noneColor = color.new(color.white, 100)



plot(shortTermRSI, title="RSI", linewidth=2, color=#8D1699)
plot(longTermRSI, title="longTermRSI", linewidth=2, color=color.orange)

hline(50, title="Middle Line", linestyle=hline.style_dotted)
obLevel = hline(70, title="Overbought", linestyle=hline.style_dotted)
osLevel = hline(30, title="Oversold", linestyle=hline.style_dotted)
fill(obLevel, osLevel, title="Background", color=longTermRSI >=50 ? color.green:color.purple, transp=65)  // longTermRSI >=50

plFound = na(pivotlow(shortTermRSI, lbL, lbR)) ? false : true
phFound = na(pivothigh(shortTermRSI, lbL, lbR)) ? false : true

_inRange(cond) =>
    bars = barssince(cond == true)
    rangeLower <= bars and bars <= rangeUpper

//------------------------------------------------------------------------------
// Regular Bullish

// shortTermRSI: Higher Low
oscHL = shortTermRSI[lbR] > valuewhen(plFound, shortTermRSI[lbR], 1) and _inRange(plFound[1])

// Price: Lower Low
priceLL = low[lbR] < valuewhen(plFound, low[lbR], 1)

bullCond = plotBull and priceLL and oscHL and plFound

plot(
	 plFound ? shortTermRSI[lbR] : na,
	 offset=-lbR,
	 title="Regular Bullish",
	 linewidth=2,
	 color=(bullCond ? bullColor : noneColor),
	 transp=0
	 )


plotshape(
	 bullCond ? shortTermRSI[lbR] : na,
	 offset=-lbR,
	 title="Regular Bullish Label",
	 text=" Bull ",
	 style=shape.labelup,
	 location=location.absolute,
	 color=bullColor,
	 textcolor=textColor,
	 transp=0
	 )

//------------------------------------------------------------------------------
// Hidden Bullish

// shortTermRSI: Lower Low
oscLL = shortTermRSI[lbR] < valuewhen(plFound, shortTermRSI[lbR], 1) and _inRange(plFound[1])

// Price: Higher Low
priceHL = low[lbR] > valuewhen(plFound, low[lbR], 1)

hiddenBullCond = plotHiddenBull and priceHL and oscLL and plFound

plot(
	 plFound ? shortTermRSI[lbR] : na,
	 offset=-lbR,
	 title="Hidden Bullish",
	 linewidth=2,
	 color=(hiddenBullCond ? hiddenBullColor : noneColor),
	 transp=0
	 )

plotshape(
	 hiddenBullCond ? shortTermRSI[lbR] : na,
	 offset=-lbR,
	 title="Hidden Bullish Label",
	 text=" H Bull ",
	 style=shape.labelup,
	 location=location.absolute,
	 color=bullColor,
	 textcolor=textColor,
	 transp=0
	 )

longCondition= longTermRSI >=50  and ( (bullCond or hiddenBullCond ) )  or  (strategy.position_size>0 and crossover(shortTermRSI,20) )
//last condition above is to leg in if you are already in the Long trade, 


strategy.entry(id="RSIDivLE", long=true,  when=longCondition)


//------------------------------------------------------------------------------
// Regular Bearish

// shortTermRSI: Lower High
oscLH = shortTermRSI[lbR] < valuewhen(phFound, shortTermRSI[lbR], 1) and _inRange(phFound[1])

// Price: Higher High
priceHH = high[lbR] > valuewhen(phFound, high[lbR], 1)

bearCond = plotBear and priceHH and oscLH and phFound

plot(
	 phFound ? shortTermRSI[lbR] : na,
	 offset=-lbR,
	 title="Regular Bearish",
	 linewidth=2,
	 color=(bearCond ? bearColor : noneColor),
	 transp=0
	 )

plotshape(
	 bearCond ? shortTermRSI[lbR] : na,
	 offset=-lbR,
	 title="Regular Bearish Label",
	 text=" Bear ",
	 style=shape.labeldown,
	 location=location.absolute,
	 color=bearColor,
	 textcolor=textColor,
	 transp=0
	 )

//------------------------------------------------------------------------------
// Hidden Bearish

// shortTermRSI: Higher High
oscHH = shortTermRSI[lbR] > valuewhen(phFound, shortTermRSI[lbR], 1) and _inRange(phFound[1])

// Price: Lower High
priceLH = high[lbR] < valuewhen(phFound, high[lbR], 1)

hiddenBearCond = plotHiddenBear and priceLH and oscHH and phFound

plot(
	 phFound ? shortTermRSI[lbR] : na,
	 offset=-lbR,
	 title="Hidden Bearish",
	 linewidth=2,
	 color=(hiddenBearCond ? hiddenBearColor : noneColor),
	 transp=0
	 )

plotshape(
	 hiddenBearCond ? shortTermRSI[lbR] : na,
	 offset=-lbR,
	 title="Hidden Bearish Label",
	 text=" H Bear ",
	 style=shape.labeldown,
	 location=location.absolute,
	 color=bearColor,
	 textcolor=textColor,
	 transp=0
	 )
	 
	 
//calculate stop Loss
stopLossVal = stopLoss==true ? ( strategy.position_avg_price -  (strategy.position_avg_price*0.08) ) : 0

//partial profit
strategy.close(id="RSIDivLE", comment="TP1", qty=strategy.position_size*3/4, when=strategy.position_size>0 and (longTermRSI>=takeProfitRSILevel or crossover(longTermRSI,90)))
strategy.close(id="RSIDivLE",comment="TP2",   qty=strategy.position_size*3/4 , when=crossover(longTermRSI,70))
strategy.close(id="RSIDivLE",comment="TP3",   qty=strategy.position_size/2, when=crossover(longTermRSI,65))
strategy.close(id="RSIDivLE",comment="TP4",   qty=strategy.position_size/2 , when=crossover(longTermRSI,60))

//close the whole position when stoploss hits or longTermRSI goes below 30
strategy.close(id="RSIDivLE",comment="Exit",    when=crossunder(longTermRSI,30) or close<stopLossVal)
Más.

2019 FMZ - Todos los derechos reservados