Una estrategia de combinación de MACD y DMI basada en el marco de tiempo multicloud

El autor:¿ Qué pasa?, Fecha: 2024-02-02 18:04:28
Las etiquetas:

基于多时间框架的一云延伸MACD和DMI组合策略

Resumen

Esta estrategia utiliza una extensión de la nube, el indicador de media móvil de dispersión (MACD) y el indicador de tendencia (DMI) en múltiples marcos de tiempo para identificar oportunidades potenciales de compra y venta. Está diseñada para proporcionar una referencia para los operadores que desean examinar el mercado desde dos dimensiones, corto y mediano.

Principios estratégicos

La estrategia se basa en señales de coincidencia en los gráficos de 15 minutos (M15) y 1 hora (H1) para ejecutar las condiciones de compra y venta, mientras que se refiere al marco de tiempo de 4 horas (H4) como confirmación adicional.

Condiciones de compra

Los precios en los marcos de tiempo M15, H1 y H4 están por encima de la extensión de una nube
La línea MACD en el gráfico H1 es superior a la línea de señal y ambas líneas son superiores a 0.
La línea DI + en el gráfico H1 es más alta que la línea DI, con un ADX de al menos 25
La línea MACD en el gráfico M15 es superior a 0, la línea DI+ es superior a la línea DI, y el ADX es de al menos 25

Condiciones de venta

Los precios en los marcos de tiempo M15, H1 y H4 se extienden por debajo de una nube
La línea MACD en el gráfico H1 está por debajo de la línea de señal, y ambas líneas están por debajo de 0.
La línea DI en el gráfico H1 es más alta que la línea DI +, y el ADX es de al menos 25
La línea MACD en el gráfico M15 es inferior a 0, la línea DI es superior a la línea DI +, y el ADX es de al menos 25

Entrada y salida

Cuando se cumplen todas las condiciones de compra, se establecen posiciones multifinales, lo que indica que hay un impulso alcista a lo largo del marco de tiempo
Cuando se cumplen todas las condiciones de venta, se establecen posiciones en blanco, lo que indica que hay una tendencia a la baja a lo largo del marco de tiempo
El equilibrio cuando se cumplen las condiciones opuestas, lo que indica un posible cambio o pérdida de impulso

Las ventajas estratégicas

Considerar más marcos de tiempo para mejorar la precisión de las decisiones
Una nube se extiende para determinar la dirección y la intensidad de la tendencia
El MACD determina el movimiento a corto y mediano plazo
DMI determina la fuerza de compra y tendencia
La combinación de varios indicadores para evaluar la dirección del mercado.
Condiciones de compra y venta personalizadas con parámetros ajustables
Puede ser ampliamente utilizado en mercados con tendencias claras

El riesgo estratégico

La discrepancia en la determinación de los marcos de tiempo puede causar señales erróneas.
La extensión de una nube puede ser engañosa si no se usa correctamente
El MACD y el DMI están rezagados y pueden perder el punto de inflexión.
Se necesita monitorear varios indicadores de marco de tiempo al mismo tiempo
Los grandes cambios en los precios de las emergencias deben ser manejados con precaución

Dirección de optimización estratégica

Optimización de la combinación de parámetros de extensión de una nube, MACD y DMI
Prueba más combinaciones de marcos de tiempo, como las líneas de tiempo.
Añadir confirmación de otros indicadores, como la volatilidad, las medias móviles, etc.
Para obtener más información histórica, optimice las condiciones de compra y venta.
Parámetros de optimización dinámica combinados con métodos como el aprendizaje automático

Resumen

Esta estrategia aprovecha las ventajas de un análisis de múltiples marcos de tiempo y de múltiples indicadores para identificar eficazmente la dirección y la intensidad de las tendencias. Puede aplicarse a diferentes variedades mediante ajustes de parámetros y también se puede optimizar para sectores específicos. Sin embargo, los operadores deben tener en cuenta las limitaciones de los indicadores y tomar las medidas adecuadas para controlar el riesgo.

/*backtest
start: 2024-01-25 00:00:00
end: 2024-02-01 00:00:00
period: 1h
basePeriod: 15m
exchanges: [{"eid":"Futures_Binance","currency":"BTC_USDT"}]
*/

// This Pine Script™ code is subject to the terms of the Mozilla Public License 2.0 at https://mozilla.org/MPL/2.0/
// © haidinh83

//@version=5
strategy("Ichimoku, MACD, DMI Multiple time frame 21/01/2024", overlay=true)
    // Khung thời gian
timeframe1 = "5"   // M5
timeframe2 = "15"  // M15
timeframe3 = "60"  // H1
timeframe4 = "240" // H4

    // Nhập tham số ADX và DI
lengthDMI = input(14, title="DMI Length")
thresholdADX = input(20, title="ADX Threshold")

// Tính giá trị Ichimoku
ichimoku(tenkanPeriod, kijunPeriod, senkouPeriod) =>
    tenkanSen = (ta.highest(high, tenkanPeriod) + ta.lowest(low, tenkanPeriod)) / 2
    kijunSen = (ta.highest(high, kijunPeriod) + ta.lowest(low, kijunPeriod)) / 2
    senkouSpanA = (tenkanSen + kijunSen) / 2
    senkouSpanB = (ta.highest(high, senkouPeriod) + ta.lowest(low, senkouPeriod)) / 2
    [tenkanSen, kijunSen, senkouSpanA, senkouSpanB]

    // Lấy Ichimoku từng khung thời gian
[tenkanM5, kijunM5, spanAM5, spanBM5] = request.security(syminfo.tickerid, timeframe1, ichimoku(9, 26, 52))
[tenkanM15, kijunM15, spanAM15, spanBM15] = request.security(syminfo.tickerid, timeframe2, ichimoku(9, 26, 52))
[tenkanH1, kijunH1, spanAH1, spanBH1] = request.security(syminfo.tickerid, timeframe3, ichimoku(9, 26, 52))
[tenkanH4, kijunH4, spanAH4, spanBH4] = request.security(syminfo.tickerid, timeframe4, ichimoku(9, 26, 52))

    // Tính giá trị MACD và Signal Line cho từng khung thời gian
[macdM5, signalM5, _] = request.security(syminfo.tickerid, timeframe1, ta.macd(close, 12, 26, 9))
[macdM15, signalM15, _] = request.security(syminfo.tickerid, timeframe2, ta.macd(close, 12, 26, 9))
[macdH1, signalH1, _] = request.security(syminfo.tickerid, timeframe3, ta.macd(close, 12, 26, 9))
[macdH4, signalH4, _] = request.security(syminfo.tickerid, timeframe4, ta.macd(close, 12, 26, 9))

  // Tính giá trị DMI cho từng khung thời gian
calcDMI(len) =>
    up = ta.change(high)
    down = -ta.change(low)
    plusDM = na(up) ? na : (up > down and up > 0 ? up : 0)
    minusDM = na(down) ? na : (down > up and down > 0 ? down : 0)
    trur = ta.rma(ta.tr, len)
    plus = fixnan(100 * ta.rma(plusDM, len) / trur)
    minus = fixnan(100 * ta.rma(minusDM, len) / trur)
    adx = 100 * ta.rma(math.abs(plus - minus) / (plus + minus == 0 ? 1 : plus + minus), len)
    [plus, minus, adx]  // Đảm bảo mỗi phần của hàm nằm trên một dòng riêng biệt


[plusM5, minusM5, adxM5] = request.security(syminfo.tickerid, timeframe1, calcDMI(lengthDMI))
[plusM15, minusM15, adxM15] = request.security(syminfo.tickerid, timeframe2, calcDMI(lengthDMI))
[plusH1, minusH1, adxH1] = request.security(syminfo.tickerid, timeframe3, calcDMI(lengthDMI))
[plusH4, minusH4, adxH4] = request.security(syminfo.tickerid, timeframe4, calcDMI(lengthDMI))



// Điều kiện mua cho H1
buyConditionH1 = (close > spanAM15) and (close > spanAH1) and (close > spanAH4) and 
                 (macdH1 > signalH1) and (macdH1 > 0) and (signalH1 > 0) and 
                 (plusH1 > minusH1) and (adxH1 >= 25)

// Điều kiện mua cho M15
buyConditionM15 = (close > spanAM15) and (close > spanAH1) and (close > spanAH4) and 
                  (macdM15 > 0) and (plusM15 > minusM15) and (adxM15 >= 25)

// Điều kiện mua tổng hợp
buyCondition = buyConditionH1 and buyConditionM15

// Điều kiện bán cho H1
sellConditionH1 = (close < spanAM15) and (close < spanAH1) and (close < spanAH4) and 
                  (macdH1 < signalH1) and (macdH1 < 0) and (signalH1 < 0) and 
                  (minusH1 > plusH1) and (adxH1 >= 25)

// Điều kiện bán cho M15
sellConditionM15 = (close < spanAM15) and (close < spanAH1) and (close < spanAH4) and 
                   (macdM15 < 0) and (minusM15 > plusM15) and (adxM15 >= 25)

// Điều kiện bán tổng hợp
sellCondition = sellConditionH1 and sellConditionM15

// Thực hiện giao dịch nếu điều kiện bán hoặc mua được đáp ứng
if buyCondition
    strategy.entry("Buy", strategy.long)

if sellCondition
    strategy.entry("Sell", strategy.short)


    // Vẽ và tô màu giữa Senkou Span A và B cho mỗi khung thời gian
p1 = plot(spanAM15, color=color.blue, title="Span A M15")
p2 = plot(spanBM15, color=color.blue, title="Span B M15")
fill(p1, p2, color=color.new(color.blue, 90), title="M15 Cloud")

p3 = plot(spanAH1, color=color.purple, title="Span A H1")
p4 = plot(spanBH1, color=color.purple, title="Span B H1")
fill(p3, p4, color=color.new(color.purple, 90), title="H1 Cloud")

p5 = plot(spanAH4, color=color.orange, title="Span A H4")
p6 = plot(spanBH4, color=color.orange, title="Span B H4")
fill(p5, p6, color=color.new(color.orange, 90), title="H4 Cloud")

    // Tô màu nền và hiển thị cảnh báo
 
bgcolor(buyCondition ? color.new(color.green, 45) : sellCondition ? color.new(color.red, 45) : na)
alertcondition(buyCondition, title="Mua Signal", message="Điều kiện mua đã được đáp ứng")
alertcondition(sellCondition, title="Bán Signal", message="Điều kiện bán đã được đáp ứng")

Más contenido

2019 - FMZ - Cuantificación de los inventores