यह रणनीति एक उपयोगकर्ता-परिभाषित सत्र के दौरान अल्पकालिक ब्रेकआउट के लिए मल्टी-टाइमफ्रेम डोनचियन को जोड़ती है। यह अल्पकालिक स्केलिंग रणनीतियों से संबंधित है।
समय सीमाओं में ब्रेकआउट जोन बनाने के लिए दिन और अल्पकालिक मध्य बिंदुओं की गणना करें।
केवल एक अनुकूलन योग्य ट्रेडिंग सत्र के दौरान व्यापार करें. सत्र की शुरुआत में प्रवेश करें, सत्र के अंत में बाहर निकलें.
प्रवेश मूल्य के रूप में मूल्य के वास्तविक समय ईएमए का उपयोग करें.
भागने के क्षेत्रों के बाहर बंद सेट करो।
जब कीमत मध्य बिंदु के पास वापस गिर जाती है, तो बंद हो जाती है, असफल ब्रेकआउट की पुष्टि होती है।
बहु-समय-सीमा संयोजन प्रभावी रूप से झूठे breakouts फ़िल्टर करने के लिए।
परिभाषित सत्र प्रमुख समाचार घटनाओं के आसपास जोखिम से बचते हैं।
ईएमए ट्रैकिंग गति के अनुरूप समय पर प्रविष्टियों की अनुमति देता है।
रुकना जोखिम को नियंत्रित करने में मदद करता है।
जबरन सत्र से बाहर निकलना रात भर के जोखिमों से बचाता है।
अल्पकालिक पलायनों को झटके और बंद होने का सामना करना पड़ सकता है।
सत्र समाप्त होने से पहले कुछ ब्रेकआउट पूर्ण लाभ नहीं कर सकते हैं।
खराब सत्र परिभाषा अवसरों को खो सकती है।
कोई गारंटी नहीं है कि प्रत्येक ब्रेकआउट अपेक्षित लाभ तक पहुंचेगा।
अनुकूलन से पैरामीटरों के अति अनुकूलन का खतरा होता है।
इष्टतम संयोजन खोजने के लिए ब्रेकआउट मापदंडों का परीक्षण करें।
प्रविष्टि की सटीकता में सुधार के लिए अतिरिक्त संकेतकों का मूल्यांकन करें।
लाभ बनाम जोखिम संतुलन के लिए ट्रेडिंग सत्र का अनुकूलन करें।
अनुसंधान को एकीकृत करने के लिए लाभ प्राप्त करने के लिए लाभकारी रणनीतियाँ अपनायी जाती हैं।
विभिन्न प्रतीकों में परीक्षण मापदंडों के अंतर।
गतिशील पैरामीटर अनुकूलन के लिए मशीन लर्निंग का उपयोग करें।
यह रणनीति सीमित सत्र ब्रेकआउट पर अल्पकालिक स्केलपिंग का प्रयास करती है। झूठे ब्रेकआउट और जोखिम नियंत्रण के आसपास अनुकूलन के साथ, इसे व्यावहारिक और कुशल अल्पकालिक प्रणाली में परिष्कृत किया जा सकता है।
/*backtest
start: 2023-08-20 00:00:00
end: 2023-09-19 00:00:00
period: 1h
basePeriod: 15m
exchanges: [{"eid":"Futures_Binance","currency":"BTC_USDT"}]
*/
//@version=3
strategy("Breakout Scalper", overlay=true)
// -------------------------------------------------------------------------------------------------
// INPUTS
// -------------------------------------------------------------------------------------------------
// Period of the "fast" donchian channel
fast_window = input(title="Fast Window", defval=13, minval=1)
// Used for the volatility (atr) period
slow_window = input(title="Slow Window", defval=52, minval=1)
// Period of EMA used as the current price
instant_period = input(title="Instant Period", defval=3, minval=1)
// Minimum ratio of cloud width to ATR in order for trade to be active
cloud_min_percent = input(title="Minimum Cloud ATR Multiplier", type=float, defval=1.0, minval=0)
// Session where we allow trades to be active
trading_sesh = input(title="Trading Session", defval='1000-1500')
// -------------------------------------------------------------------------------------------------
// -------------------------------------------------------------------------------------------------
// SESSION TIMING
// -------------------------------------------------------------------------------------------------
is_newbar(t) =>
na(t[1]) and not na(t) or t[1] < t
day_time = time("D")
sess_time = time(timeframe.period, trading_sesh)
day_open_bar = is_newbar(day_time)
sess_open_bar = is_newbar(sess_time)
sess_close_bar = na(sess_time) and not na(sess_time[1])
sess_is_open = false
sess_is_open := sess_open_bar ? true : (sess_close_bar ? false : sess_is_open[1])
// -------------------------------------------------------------------------------------------------
// -------------------------------------------------------------------------------------------------
// DONCHIANS
// -------------------------------------------------------------------------------------------------
slow_high = na
slow_high := day_open_bar ? high : (high > slow_high[1] ? high : slow_high[1])
slow_low = na
slow_low := day_open_bar ? low : (low < slow_low[1] ? low : slow_low[1])
slow_mid = (slow_high + slow_low) / 2
fast_low = max(slow_low, lowest(fast_window))
fast_high = min(slow_high, highest(fast_window))
fast_mid = (fast_low + fast_high) / 2
// -------------------------------------------------------------------------------------------------
// -------------------------------------------------------------------------------------------------
// TREND CLOUD
// -------------------------------------------------------------------------------------------------
cloud_width = fast_mid - slow_mid
slow_atr = atr(slow_window)
cloud_percent = cloud_width / slow_atr
cloud_color = cloud_percent > cloud_min_percent ? green : (cloud_percent < -cloud_min_percent ? red : gray)
fp = plot(fast_mid, title="Fast MidR", color=green)
sp = plot(slow_mid, title="Slow MidR", color=red)
fill(fp, sp, color=cloud_color)
// -------------------------------------------------------------------------------------------------
// -------------------------------------------------------------------------------------------------
// INSTANT PRICE
// -------------------------------------------------------------------------------------------------
instant_price = ema(close, instant_period)
plot(instant_price, title="Instant Price", color=black, transp=50)
// -------------------------------------------------------------------------------------------------
// -------------------------------------------------------------------------------------------------
// ENTRY SIGNALS & STOPS
// -------------------------------------------------------------------------------------------------
buy_entry_signal = sess_is_open and (instant_price > fast_mid) and (cloud_percent > cloud_min_percent)
sell_entry_signal = sess_is_open and (instant_price < fast_mid) and (cloud_percent < -cloud_min_percent)
buy_close_signal = sess_close_bar or (cloud_percent < 0)
sell_close_signal = sess_close_bar or (cloud_percent > 0)
entry_buy_stop = slow_high
entry_sell_stop = slow_low
exit_buy_stop = max(slow_low, fast_low)
exit_sell_stop = min(slow_high, fast_high)
entry_buy_stop_color = (strategy.position_size == 0) ? (buy_entry_signal ? green : na) : na
plotshape(entry_buy_stop, location=location.absolute, color=entry_buy_stop_color, style=shape.circle)
entry_sell_stop_color = (strategy.position_size == 0) ? (sell_entry_signal ? red : na) : na
plotshape(entry_sell_stop, location=location.absolute, color=entry_sell_stop_color, style=shape.circle)
exit_buy_stop_color = (strategy.position_size > 0) ? red : na
plotshape(exit_buy_stop, location=location.absolute, color=exit_buy_stop_color, style=shape.xcross)
exit_sell_stop_color = (strategy.position_size < 0) ? green : na
plotshape(exit_sell_stop, location=location.absolute, color=exit_sell_stop_color, style=shape.xcross)
// -------------------------------------------------------------------------------------------------
// -------------------------------------------------------------------------------------------------
// STRATEGY EXECUTION
// -------------------------------------------------------------------------------------------------
strategy.entry("long", strategy.long, stop=entry_buy_stop, when=buy_entry_signal)
strategy.cancel("long", when=not buy_entry_signal)
strategy.exit("stop", "long", stop=exit_buy_stop)
strategy.entry("short", strategy.short, stop=entry_sell_stop, when=sell_entry_signal)
strategy.cancel("short", when=not sell_entry_signal)
strategy.exit("stop", "short", stop=exit_sell_stop)
strategy.close("long", when=buy_close_signal)
strategy.close("short", when=sell_close_signal)
// -------------------------------------------------------------------------------------------------