Praktik dan aplikasi strategi thermometer pada platform kuantitatif penemu

Mengapa disebut termometer. Kami menamai sistem ini berdasarkan kemampuan adaptifnya untuk bertransformasi dan berdagang dalam dua mode pasar, goncangan dan tren. Sistem ini berasal dari pengamatan kami tentang keberhasilan sistem tertentu di area pasar tertentu. Sistem ini dapat menciptakan strategi dengan sifat ganda untuk memanfaatkan kedua mode pasar.

Pertama, kita membuat fungsi untuk membantu menentukan pola pasar. Berdasarkan output dari fungsi ini, thermostat beralih dari mode mengikuti ke mode berayun jangka pendek.

Trend tracking model menggunakan mekanisme trend tracking yang mirip dengan di Brin Band. Sistem swing jangka pendek adalah open-break yang berisi pengidentifikasian pola. Fungsi ini membandingkan jarak pasar berputar dengan jarak pasar yang sebenarnya berjalan:

Abs ((harga penutupan - harga penutupan[29])/ ((harga tertinggi ((30) - harga terendah ((harga terendah, 30 hari) * 100

Fungsi ini menghasilkan nilai antara 0 dan 100. Nilai yang lebih besar, semakin kecil kemacetan pasar saat ini. Jika nilai yang dikembalikan fungsi kurang dari 20, sistem masuk ke mode berayun jangka pendek.

Pada dasarnya, sebagian besar pasar menunjukkan pergerakan yang bergulir, dan sistem mencoba untuk menangkap fluktuasi dan mendapatkan keuntungan tipis dari itu. Pemanas mencoba untuk mencapai prestasi ini dengan impulsi pasar yang kecil untuk membeli / menjual. Jika fluktuasi cukup besar, sistem akan beralih mode.

Dengan analisis mendalam terhadap volatilitas jangka pendek, kami menemukan bahwa kadang-kadang membeli lebih baik daripada menjual, dan sebaliknya. Waktu ini dapat ditentukan dengan pola visual yang sederhana. Jika harga penutupan hari ini lebih tinggi dari harga tertinggi, terendah, dan penutupan kemarin (juga disebut titik kunci hari ini), maka kami berpikir bahwa pergerakan pasar besok mungkin akan turun. Namun, jika harga penutupan hari ini lebih rendah dari rata-rata harga tertinggi, terendah, dan penutupan kemarin, maka pasar hari ini mungkin akan naik. Kami mengklasifikasikan waktu ini sebagai harga yang lebih mudah dibeli dan dijual.

Strategi thermostat adalah strategi yang sangat populer di platform inventor quantification, dimana pengguna menambahkan beberapa logika transaksi tambahan sesuai dengan kebutuhan mereka sendiri, sehingga strategi tersebut lebih baik, berikut adalah kerangka kerja yang khas dari strategi thermostat di platform inventor quantification:

• Gambar utama: Rumus lintasan: TOP^^MAC+N_TMPTMP;//Brin saluran lintasan Rumus bawah jalur: BOTTOM^^MAC-N_TMPTMP;//Brin saluran bawah jalur

• Gambar: Rumus CMI:CMI:ABS ((C-REF ((C,N_CMI-1))/HHV ((H,N_CMI) -LLV ((L,N_CMI)) *100;//0-100 Nilai yang diambil semakin besar, menunjukkan semakin kuat tren, CMI <20 pola goncangan, CMI> 20 untuk tren

• Kode (dalam bahasa saya):

MAC:=MA(CLOSE,N);
TMP:=STD(CLOSE,N);
TOP^^MAC+N_TMP*TMP;      // 布林通道上轨
BOTTOM^^MAC-N_TMP*TMP;   // 布林通道下轨
BBOLL:=C>MAC;
SBOLL:=C<MAC;
N_CMI:=30;

CMI:ABS(C-REF(C,N_CMI-1))/(HHV(H,N_CMI)-LLV(L,N_CMI))*100; //0-100 取值越大，说明趋势越强，CMI<20震荡模式，CMI>20为趋势

N_KD:=9;
M1:=3;
M2:=3;
RSV:=(CLOSE-LLV(LOW,N_KD))/(HHV(HIGH,N_KD)-LLV(LOW,N_KD))*100; //收盘价与N周期最低值做差，N周期最高值与N周期最低值做差，两差之间做比值。

K:=SMA(RSV,M1,1); //RSV的移动平均值
D:=SMA(K,M2,1);   //K的移动平均值
MIND:=30;
BKD:=K>D AND D<MIND;
SKD:=K<D AND D>100-MIND;

// 震荡模式
BUYPK1:=CMI < 20 AND BKD;  //震荡多单买平开
SELLPK1:=CMI < 20 AND SKD; //震荡空单卖平开

// 趋势模式下原有震荡持仓的处理
SELLY1:=REF(CMI,BARSBK) < 20 AND C>BKPRICE*(1+0.01*STOPLOSS*3) AND K<D; //震荡多单止盈
BUYY1:=REF(CMI,BARSSK) < 20 AND C<SKPRICE*(1-0.01*STOPLOSS*3) AND K>D;  //震荡空单止盈

// 趋势模式
BUYPK2:=CMI >= 20 AND C > TOP;        // 趋势多单买平开
SELLPK2:=CMI >= 20 AND C < BOTTOM;    // 趋势空单卖平开

// 趋势模式下原有震荡持仓的处理
SELLY2:=REF(CMI,BARSBK) >= 20 AND C>BKPRICE*(1+0.01*STOPLOSS*3) AND SBOLL;//趋势多单止盈
BUYY2:=REF(CMI,BARSSK) >= 20 AND C<SKPRICE*(1-0.01*STOPLOSS*3) AND BBOLL;//趋势空单止盈
SELLS2:=REF(CMI,BARSBK) >= 20 AND C<BKPRICE*(1-0.01*STOPLOSS) AND SBOLL;//趋势多单止损
BUYS2:=REF(CMI,BARSSK) >= 20 AND C>SKPRICE*(1+0.01*STOPLOSS) AND BBOLL;//趋势空单止损

IF BARPOS>N THEN BEGIN
    BUYPK1,BPK;
    SELLPK1,SPK;
    BUYPK2,BPK;
    SELLPK2,SPK;
END
BUYY1,BP(SKVOL);
BUYY2,BP(SKVOL);
BUYS2,BP(SKVOL);
SELLY1,SP(BKVOL);
SELLY2,SP(BKVOL);
SELLS2,SP(BKVOL);

Hasil dari strategi ini adalah sebagai berikut:

Untuk informasi lebih lanjut, lihat:https://www.fmz.com/strategy/129086