Strategi beli trailing adalah strategi yang mengikuti tren. Ketika rata-rata bergerak cepat melintasi rata-rata bergerak lambat, itu memicu sinyal posisi terbuka. Tidak seperti posisi pembukaan langsung, strategi ini tidak akan memasuki pasar segera setelah sinyal posisi terbuka dipicu, tetapi akan mengeksekusi pesanan beli hanya ketika harga mencapai kondisi tertentu. Ini dapat meningkatkan keuntungan strategi sampai batas tertentu.
Strategi ini didasarkan pada sistem crossover rata-rata bergerak dengan dua rata-rata bergerak. rata-rata bergerak cepat dan rata-rata bergerak lambat dihitung masing-masing.
Logika eksekusi akan berbeda ketika opsi beli trailing diaktifkan:
Ketika sinyal panjang dipicu, alih-alih membeli langsung, catat harga terendah pada saat itu.
Kemudian hitung ambang harga beli berdasarkan persentase pembelian terakhir, yaitu harga terendah * (1 + persentase).
Di bar berikutnya, terus bandingkan harga terendah bar saat ini dengan ambang harga beli.
Ketika harga terendah melintasi ambang harga beli, eksekusi pesanan beli.
Dengan cara ini, kita bisa masuk ke pasar dengan harga yang lebih baik setelah tren dikonfirmasi.
Keuntungan dari strategi ini adalah:
Menggunakan beli trailing dapat menghindari risiko false breakout dengan memasuki pasar setelah tren menjadi lebih jelas.
Melalui trailing buy, harga yang lebih baik dapat dicapai, meningkatkan keuntungan sampai batas tertentu.
Strategi ini sederhana dan mudah diterapkan.
Persentase kenaikan pembelian terakhir dapat disesuaikan, membuat strategi lebih fleksibel.
Periode rata-rata bergerak dapat disesuaikan untuk beradaptasi dengan lingkungan pasar yang berbeda.
Ada juga beberapa risiko dalam strategi ini:
Membeli yang tertinggal dapat menyebabkan keterlambatan tertentu dan kehilangan kesempatan untuk masuk.
Pengaturan yang tidak tepat dari persentase kenaikan pembelian akhir dapat mengakibatkan ketidakmampuan untuk membeli.
Periode rata-rata bergerak yang tidak tepat dapat menghasilkan lebih banyak sinyal palsu.
Strategi dapat mengalami kerugian besar di berbagai pasar.
Ini adalah strategi sederhana dengan ruang untuk optimasi parameter.
Langkah-langkah yang sesuai:
Singkatkan persentase pembelian yang tertinggal dengan benar untuk mengurangi lag.
Uji pengaturan persentase yang berbeda untuk menemukan yang optimal.
Mengoptimalkan periode rata-rata bergerak untuk menyesuaikan pasar.
Tambahkan filter lain untuk menghindari pasar yang berbeda.
Pertimbangkan untuk menambahkan stop loss untuk mengurangi kerugian.
Strategi dapat dioptimalkan dalam arah berikut:
Tambahkan indikator harga-volume seperti Klinger untuk menghindari ketidakcocokan harga-volume.
Tambahkan volume kondisi penilaian, hanya membeli ketika volume memperluas.
Mengoptimalkan periode rata-rata bergerak untuk produk yang berbeda.
Tambahkan indikator volatilitas untuk menghindari zona rentang.
Tambahkan ATR stop loss.
Pertimbangkan untuk membuat persentase melonjak dinamis, melonjak lebih cepat ketika tren lebih jelas.
Secara singkat, strategi beli trailing meningkatkan strategi dengan mengikuti harga ke titik masuk yang lebih baik sambil tetap sederhana. Tapi masih ada beberapa risiko dalam strategi ini yang memerlukan optimasi lebih lanjut untuk menyesuaikan lebih banyak situasi pasar. Secara keseluruhan, strategi ini memberikan ide yang layak referensi untuk perdagangan kuantitatif.
/*backtest
start: 2023-10-01 00:00:00
end: 2023-10-08 00:00:00
period: 5m
basePeriod: 1m
exchanges: [{"eid":"Futures_Binance","currency":"BTC_USDT"}]
*/
//@version=5
//
// ▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒
// -----------------------------------------------------------------------------
// Copyright 2022 Iason Nikolas | jason5480
// Trailing Buy script may be freely distributed under the MIT license.
//
// Permission is hereby granted, free of charge,
// to any person obtaining a copy of this software and associated documentation files (the "Software"),
// to deal in the Software without restriction, including without limitation the rights to use, copy, modify, merge,
// publish, distribute, sublicense, and/or sell copies of the Software, and to permit persons to whom the Software is furnished to do so,
// subject to the following conditions:
//
// The above copyright notice and this permission notice shall be included in all copies or substantial portions of the Software.
//
// THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,
// EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
// FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM,
// DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM,
// OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE SOFTWARE.
//
// -----------------------------------------------------------------------------
//
// Authors: @jason5480
// Revision: v1.0.0
// Date: 15-Feb-2022
//
// Description
// =============================================================================
// This strategy will go long if fast MA crosses over slow MA.
// If the trailing buy is checked then the strategy instead of entering into the position
// directly it will follow the price downwards (percentagewise) with small steps
// If the price raise by this percentage then the entry order will be executed
//
// The strategy has the following parameters:
//
// Fast SMA Length - How many candles back to calculte the fast SMA.
// Slow SMA Length - How many candles back to calculte the slow SMA.
// Enable Trailing - Enable or disable the trailing
// Training Buy Deviation % - The step to follow the price when the open position condition is met.
// Source Buy - The price to compare the current buyPrice in order to trigger the buy order when trailing
//
// -----------------------------------------------------------------------------
// Disclaimer:
// 1. I am not licensed financial advisors or broker dealer. I do not tell you
// when or what to buy or sell. I developed this software which enables you
// execute manual or automated using TradingView. The
// software allows you to set the criteria you want for entering and exiting
// trades.
// 2. Do not trade with money you cannot afford to lose.
// 3. I do not guarantee consistent profits or that anyone can make money with no
// effort. And I am not selling the holy grail.
// 4. Every system can have winning and losing streaks.
// 5. Money management plays a large role in the results of your trading. For
// example: lot size, account size, broker leverage, and broker margin call
// rules all have an effect on results. Also, your Take Profit and Stop Loss
// settings for individual pair trades and for overall account equity have a
// major impact on results. If you are new to trading and do not understand
// these items, then I recommend you seek education materials to further your
// knowledge.
//
// YOU NEED TO FIND AND USE THE TRADING SYSTEM THAT WORKS BEST FOR YOU AND YOUR
// TRADING TOLERANCE.
//
// I HAVE PROVIDED NOTHING MORE THAN A TOOL WITH OPTIONS FOR YOU TO TRADE WITH THIS PROGRAM ON TRADINGVIEW.
//
// I accept suggestions to improve the script.
// If you encounter any problems I will be happy to share with me.
// -----------------------------------------------------------------------------
//
// ▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒
// SETUP ============================================================================================================
strategy(title = 'Trailing Buy',
shorttitle = 'TB',
overlay = true,
pyramiding = 0,
default_qty_type = strategy.percent_of_equity,
default_qty_value = 100,
initial_capital = 100000)
//
// ▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒
// FILTERS ==========================================================================================================
// INPUT ============================================================================================================
usefromDate = input.bool(defval = true, title = 'From', inline = "From Date", group = "Filters")
fromDate = input(defval = timestamp('01 Jan 2021 00:00 UTC'), title = '', inline = "From Date", group = 'Filters')
usetoDate = input.bool(defval = false, title = 'To ', inline = "To Date", group = "Filters")
toDate = input(defval = timestamp('31 Dec 2121 23:59 UTC'), title = '', inline = "To Date", group = 'Filters')
// LOGIC ============================================================================================================
isWithinPeriod() => true
// PLOT =============================================================================================================
bgcolor(color = isWithinPeriod() ? color.new(color.gray, 90) : na, title = 'Period')
//
// ▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒
// STRATEGY =========================================================================================================
// INPUT ============================================================================================================
fastMALen = input.int(defval = 21, title = 'Fast/Slow SMA Length', inline = 'MA Length', group = 'Strategy')
slowMALen = input.int(defval = 49, title = '', tooltip = 'How many candles back to calculte the fast/slow SMA.', inline = 'MA Length', group = 'Strategy')
// LOGIC ============================================================================================================
fastMA = ta.sma(close, fastMALen)
slowMA = ta.sma(close, slowMALen)
bool openLongPosition = isWithinPeriod() and ta.crossover(fastMA, slowMA)
bool closeLongPosition = ta.crossunder(fastMA, slowMA)
bool longIsActive = openLongPosition or strategy.position_size > 0
// PLOT =============================================================================================================
var fastColor = color.new(#0056BD, 0)
plot(series = fastMA, title = 'Fast SMA', color = fastColor, linewidth = 1, style = plot.style_line)
var slowColor = color.new(#FF6A00, 0)
plot(series = slowMA, title = 'Slow SMA', color = slowColor, linewidth = 1, style = plot.style_line)
plotshape(series = openLongPosition and strategy.position_size <= 0 ? fastMA : na, title = 'Buy', text = 'Buy', style = shape.labelup, location = location.absolute, color = color.new(color.green, 0), textcolor = color.new(color.white, 0), size = size.tiny)
//
// ▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒
// BUY ==============================================================================================================
// INPUT ============================================================================================================
enableTrailing = input.bool(defval = true, title = 'Enable Trailing', tooltip = 'Enable or disable the trailing for buy.', group = 'Buy')
trailingBuyDeviationPerc = input.float(defval = 4.0, title = 'Trailing Buy Deviation %', minval = 0.01, maxval = 100, step = 0.05, tooltip = 'The step to follow the price when the open position condition is met.', group = 'Buy') / 100
srcBuy = input.source(defval = high, title = 'Source Buy', tooltip = 'The price to check to trigger the buy order', group = 'Buy')
// LOGIC ============================================================================================================
int barsSinceOpenLong = nz(ta.barssince(openLongPosition), 999999)
int barsSinceCloseLong = nz(ta.barssince(closeLongPosition), 999999)
bool tryOpenLongPosition = isWithinPeriod() and barsSinceCloseLong >= barsSinceOpenLong and not (strategy.position_size > 0)
float longBuyPrice = na
longBuyPrice := if openLongPosition and not (strategy.position_size > 0)
low * (1 + trailingBuyDeviationPerc)
else if tryOpenLongPosition
math.min(low * (1 + trailingBuyDeviationPerc), nz(longBuyPrice[1], 999999))
else
na
bool executeLongPosition = enableTrailing ? isWithinPeriod() and srcBuy > longBuyPrice : openLongPosition
// PLOT =============================================================================================================
var buyColor = color.new(#419388, 0)
plot(series = enableTrailing ? longBuyPrice : na, title = 'Long Buy Price', color = buyColor, linewidth = 1, style = plot.style_linebr, offset = 1)
//
// ▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒
// POSITION ORDERS ==================================================================================================
// LOGIC ============================================================================================================
// getting into LONG position
strategy.entry(id = 'Long Entry', direction = strategy.long, when = executeLongPosition, alert_message = 'Long(' + syminfo.ticker + '): Started')
// submit close order on trend reversal
strategy.close(id = 'Long Entry', when = closeLongPosition, comment = 'Close Long', alert_message = 'Long(' + syminfo.ticker + '): Closed at market price')
// PLOT =============================================================================================================
var posColor = color.new(color.white, 0)
plot(series = strategy.position_avg_price, title = 'Position', color = posColor, linewidth = 1, style = plot.style_linebr)
// ==================================================================================================================