Sumber daya yang dimuat... Pemuatan...

DCCI Breakout Strategi

Penulis:ChaoZhang, Tanggal: 2024-02-18 10:13:21
Tag:

Gambaran umum

DCCI Breakout Strategy adalah strategi perdagangan jangka pendek yang mengidentifikasi situasi oversold dan overbought menggunakan indikator CCI. Ini menggabungkan indikator CCI dan garis rata-rata bergerak WMA. Ini panjang ketika indikator CCI memantul kembali dari zona oversold dan pendek ketika indikator CCI jatuh kembali dari zona overbought, keluar setelah menghasilkan keuntungan.

Logika Strategi

Strategi ini menggunakan indikator CCI untuk menilai kondisi overbought/oversold pasar. Indikator CCI dapat secara efektif mengidentifikasi situasi harga yang tidak normal. Nilai di bawah -100 menunjukkan pasar terlampau terjual sementara nilai di atas 100 menunjukkan pasar terlampau dibeli. Strategi akan panjang ketika indikator CCI melintasi di atas -100 dari bawah; dan akan pendek ketika indikator CCI melintasi di bawah 100 dari atas.

Pada saat yang sama, strategi ini juga menggabungkan garis rata-rata bergerak WMA untuk menentukan arah tren. Hanya ketika harga penutupan di atas garis WMA sinyal panjang akan berlaku; hanya ketika harga penutupan di bawah garis WMA sinyal pendek akan berlaku. Ini membantu menyaring beberapa sinyal perdagangan ambigu.

Setelah memasuki posisi, strategi menggunakan stop loss untuk mengendalikan risiko. Ada tiga metode stop loss opsional: stop strategi tetap, swing high/low stop, ATR stop. Ketika panjang, posisi akan dihentikan jika harga turun ke level stop; ketika pendek, posisi akan dihentikan jika harga naik ke level stop.

Analisis Keuntungan

Strategi ini memiliki keuntungan berikut:

Menangkap peluang oversold dan overbought secara tepat waktu dengan mengidentifikasi pembalikan menggunakan indikator CCI.
Menghindari perdagangan melawan tren dengan menggabungkan analisis arah tren menggunakan moving average.
Menyediakan beberapa metode stop loss opsional yang dapat disesuaikan berdasarkan kondisi pasar.
Sinyal perdagangan sederhana dan jelas yang mudah diterapkan.

Analisis Risiko

Strategi ini juga memiliki risiko berikut:

Indikator CCI dapat dengan mudah menghasilkan sinyal palsu yang tidak dapat dihindari sepenuhnya.
Penempatan stop loss yang tidak benar dapat menyebabkan over-stop out.
Ketidakmampuan untuk mengidentifikasi tren berarti terlalu banyak perdagangan yang tidak perlu dapat dihasilkan di berbagai pasar.
Ketidakmampuan untuk menilai arah pasar secara keseluruhan dapat mengakibatkan perdagangan ke arah yang salah.

Untuk mengatasi risiko ini, pendekatan optimalisasi utama adalah:

Masukkan indikator lain untuk menyaring sinyal CCI.
Mengoptimalkan penempatan berhenti melalui backtesting.
Tambahkan indikator identifikasi tren untuk menghindari pasar bergolak.
Tentukan arah perdagangan berdasarkan analisis area support dan resistance utama.

Arahan Optimasi

Aspek utama untuk mengoptimalkan strategi ini meliputi:

Optimasi Parameter CCI: Sesuaikan periode pencarian CCI, optimalkan parameter indikator.
Optimasi Stop Loss: Uji metode stop yang berbeda dan pilih stop loss yang optimal.
Optimasi Filter: Tambahkan filter tambahan seperti MACD, RSI untuk membangun sistem penyaringan multi-indikator untuk mengurangi sinyal palsu.
Pemfilteran Tren: Tambahkan indikator pengidentifikasi tren seperti rata-rata bergerak untuk menghindari perdagangan kontra-tren.
Pengambilan Keuntungan Otomatis: Membangun mekanisme pengambilan keuntungan dinamis untuk mengambil keuntungan secara otomatis berdasarkan volatilitas pasar.

Kesimpulan

Secara keseluruhan, DCCI Breakout Strategy adalah sistem perdagangan jangka pendek yang sangat praktis. Ini mengidentifikasi situasi overbought / oversold menggunakan indikator CCI dan menggabungkan moving average untuk bias arah. Risiko dikelola melalui stop loss. Sinyal yang sederhana dan jelas membuat strategi ini mudah diterapkan untuk perdagangan jangka pendek. Pengujian dan pengoptimalan terus menerus dapat lebih meningkatkan kinerja strategi.

/*backtest
start: 2023-02-11 00:00:00
end: 2023-09-20 00:00:00
period: 1d
basePeriod: 1h
exchanges: [{"eid":"Futures_Binance","currency":"BTC_USDT"}]
*/

// This source code is subject to the terms of the Mozilla Public License 2.0 at https://mozilla.org/MPL/2.0/
// © tweakerID

// ---From the "Bitcoin Trading Strategies" book, by David Hanson---

// After testing, works better with an ATR stop instead of the Strategy Stop. This paramater
// can be changed from the strategy Inputs panel.

// "CCI Scalping Strategy
// Recommended Timeframe: 5 minutes
// Indicators: 20 Period CCI, 20 WMA
// Long when: Price closes above 20 WMA and CCI is below -100, enter when CCI crosses above -100.
// Stop: Above 20 WMA"

//@version=4
strategy("CCI Scalping Strat", 
     overlay=true, 
     default_qty_type=strategy.percent_of_equity, 
     default_qty_value=100, 
     initial_capital=10000, 
     commission_value=0.04, 
     calc_on_every_tick=false, 
     slippage=0)

direction = input(0, title = "Strategy Direction", type=input.integer, minval=-1, maxval=1)
strategy.risk.allow_entry_in(direction == 0 ? strategy.direction.all : (direction < 0 ? strategy.direction.short : strategy.direction.long))

/////////////////////// STRATEGY INPUTS ////////////////////////////////////////
title1=input(true, "-----------------Strategy Inputs-------------------")  

i_Stop = input(0, step=.05, title="Strategy Stop Mult")*.01
i_CCI=input(16, title="CCI Length")
i_WMA=input(5, title="WMA Length")

/////////////////////// BACKTESTER /////////////////////////////////////////////
title2=input(true, "-----------------General Inputs-------------------")  

// Backtester General Inputs
i_SL=input(true, title="Use Stop Loss and Take Profit")
i_SLType=input(defval="ATR Stop", title="Type Of Stop", options=["Strategy Stop", "Swing Lo/Hi", "ATR Stop"])
i_SPL=input(defval=10, title="Swing Point Lookback")
i_PercIncrement=input(defval=2, step=.1, title="Swing Point SL Perc Increment")*0.01
i_ATR = input(14, title="ATR Length")
i_ATRMult = input(10, step=.1, title="ATR Multiple")
i_TPRRR = input(1.5, step=.1, title="Take Profit Risk Reward Ratio")

// Bought and Sold Boolean Signal
bought = strategy.position_size > strategy.position_size[1] 
 or strategy.position_size < strategy.position_size[1]

// Price Action Stop and Take Profit
LL=(lowest(i_SPL))*(1-i_PercIncrement)
HH=(highest(i_SPL))*(1+i_PercIncrement)
LL_price = valuewhen(bought, LL, 0)
HH_price = valuewhen(bought, HH, 0)
entry_LL_price = strategy.position_size > 0 ? LL_price : na 
entry_HH_price = strategy.position_size < 0 ? HH_price : na 
tp=strategy.position_avg_price + (strategy.position_avg_price - entry_LL_price)*i_TPRRR
stp=strategy.position_avg_price - (entry_HH_price - strategy.position_avg_price)*i_TPRRR

// ATR Stop
ATR=atr(i_ATR)*i_ATRMult
ATRLong = ohlc4 - ATR
ATRShort = ohlc4 + ATR
ATRLongStop = valuewhen(bought, ATRLong, 0)
ATRShortStop = valuewhen(bought, ATRShort, 0)
LongSL_ATR_price = strategy.position_size > 0 ? ATRLongStop : na 
ShortSL_ATR_price = strategy.position_size < 0 ? ATRShortStop : na 
ATRtp=strategy.position_avg_price + (strategy.position_avg_price - LongSL_ATR_price)*i_TPRRR
ATRstp=strategy.position_avg_price - (ShortSL_ATR_price - strategy.position_avg_price)*i_TPRRR

/////////////////////// STRATEGY LOGIC /////////////////////////////////////////

//CCI
CCI=cci(close, i_CCI)
//WMA
WMA=wma(close, i_WMA)

//Stops
LongStop=valuewhen(bought, WMA, 0)*(1-i_Stop)
ShortStop=valuewhen(bought, WMA, 0)*(1+i_Stop)
StratTP=strategy.position_avg_price + (strategy.position_avg_price - LongStop)*i_TPRRR
StratSTP=strategy.position_avg_price - (ShortStop - strategy.position_avg_price)*i_TPRRR

BUY = (close > WMA) and crossover(CCI , -100)
SELL = (close < WMA) and crossunder(CCI , 100)

//Trading Inputs
DPR=input(true, "Allow Direct Position Reverse")
reverse=input(false, "Reverse Trades")

// Entries
if reverse
    if not DPR
        strategy.entry("long", strategy.long, when=SELL and strategy.position_size == 0)
        strategy.entry("short", strategy.short, when=BUY and strategy.position_size == 0)
    else     
        strategy.entry("long", strategy.long, when=SELL)
        strategy.entry("short", strategy.short, when=BUY)
else
    if not DPR 
        strategy.entry("long", strategy.long, when=BUY and strategy.position_size == 0)
        strategy.entry("short", strategy.short, when=SELL and strategy.position_size == 0)
    else
        strategy.entry("long", strategy.long, when=BUY)
        strategy.entry("short", strategy.short, when=SELL)


SL= i_SLType == "Swing Lo/Hi" ? entry_LL_price : i_SLType == "ATR Stop" ? LongSL_ATR_price : LongStop
SSL= i_SLType == "Swing Lo/Hi" ? entry_HH_price : i_SLType == "ATR Stop" ? ShortSL_ATR_price : ShortStop
TP= i_SLType == "Swing Lo/Hi" ? tp : i_SLType == "ATR Stop" ? ATRtp : StratTP
STP= i_SLType == "Swing Lo/Hi" ? stp : i_SLType == "ATR Stop" ? ATRstp : StratSTP

strategy.exit("TP & SL", "long", limit=TP, stop=SL, when=i_SL)
strategy.exit("TP & SL", "short", limit=STP, stop=SSL, when=i_SL)

/////////////////////// PLOTS //////////////////////////////////////////////////


plot(WMA)
plot(i_SL and strategy.position_size > 0 ? SL : na , title='SL', style=plot.style_cross, color=color.red)
plot(i_SL and strategy.position_size < 0 ? SSL : na , title='SSL', style=plot.style_cross, color=color.red)
plot(i_SL and strategy.position_size > 0 ? TP : na, title='TP', style=plot.style_cross, color=color.green)
plot(i_SL and strategy.position_size < 0 ? STP : na, title='STP', style=plot.style_cross, color=color.green)
// Draw price action setup arrows
plotshape(BUY ? 1 : na, style=shape.triangleup, location=location.belowbar, 
 color=color.green, title="Bullish Setup", size=size.auto)
plotshape(SELL ? 1 : na, style=shape.triangledown, location=location.abovebar, 
 color=color.red, title="Bearish Setup", size=size.auto)

Lebih banyak

2019 FMZ - Semua hak dilindungi