리소스 로딩... 로딩...

트레일링 스톱 로스 트렌드와 단일 지수 평형 이동 평균 전략에 따른 트렌드

저자:차오장, 날짜: 2024-01-08 11:37:44
태그:

전반적인 설명

이 전략은 단일 기하급수 평형 이동 평균 (SESMA) 과 후속 스톱 손실 메커니즘을 캔들리어 출구와 결합하여 매우 안정적이고 효율적인 트렌드 다음 전략을 형성합니다. SESMA는 가격의 트렌드 방향을 식별하는 주요 라인으로 작용합니다. 후속 스톱 손실 메커니즘은 이익을 보호하면서 전략의 위험을 효과적으로 줄일 수 있습니다.

전략 논리

이 전략은 두 가지 핵심 지표로 구성됩니다.

단일 기하급수 평형 이동 평균 (SESMA): SESMA는 EMA의 아이디어를 바탕으로 곡선을 매끄럽고 지연을 줄이기 위해 매개 변수를 개선합니다. 가격 추세를 판단하기 위해 SESMA의 방향과 수준을 사용합니다.
트래일링 스톱 로스 메커니즘: 최고 가격, 최저 가격 및 ATR 지표와 결합하여 실시간으로 긴 및 짧은 스톱 로스 라인을 계산합니다. 시장 변동성과 트렌드를 기반으로 스톱 로스 범위를 조정할 수있는 동적 조정 가능한 스톱 로스 메커니즘입니다. 스톱 로스 라인과 가격 수준 사이의 관계는 출구 주문의 시기를 결정하는 데 사용됩니다.

이 전략의 입시 신호는 가격이 SESMA를 넘을 때 발동됩니다. 출시 신호는 스톱 로스 라인에 의해 생성됩니다. 입시 / 출시 표시를 표시할 수 있습니다.

전략 의 장점

SESMA 계산 방식이 개선되어 효율적으로 지연을 줄이고 트렌드 추적 능력을 향상시킬 수 있습니다.
후속 스톱 손실 메커니즘은 너무 넓은 또는 너무 긴 스톱 손실을 피하기 위해 실시간 변동에 따라 스톱 손실 범위를 조정할 수 있습니다.
입구와 출구 신호를 표시하는 시각 보조 장치가 있습니다.
다양한 제품 및 매개 변수 최적화에 적합한 사용자 정의 가능한 매개 변수

위험 및 최적화 방향

트렌드 반전 시에는 스톱 로스가 조기에 발동될 수 있습니다. 적절한 스톱 로스 범위를 느슨하게 할 수 있습니다.
SESMA 매개 변수는 최적의 길이를 찾기 위해 최적화 될 수 있습니다.
ATR의 기간 매개 변수도 테스트할 수 있습니다.
표지판을 보여주는 효과를 테스트합니다.

결론

이 전략은 트렌드 판단과 위험 통제 지표를 통합하여 전략에 따른 비교적 강력한 트렌드를 형성합니다. 간단한 이동 평균 전략과 비교하면 이 전략은 유동성을 줄이는 동시에 트렌드를 더 유연하게 포착 할 수 있습니다. 매개 변수 최적화를 통해 전략은 다른 시장에서 더 나은 결과를 얻을 수 있습니다.

/*backtest
start: 2023-12-31 00:00:00
end: 2024-01-07 00:00:00
period: 10m
basePeriod: 1m
exchanges: [{"eid":"Futures_Binance","currency":"BTC_USDT"}]
*/


//@version=5
// This source code is subject to the terms of the Mozilla Public License 2.0 at https://mozilla.org/MPL/2.0/
// © simwai
strategy('Chandelier Exit ZLSMA Strategy', shorttitle='CE_ZLSMA', overlay = true, initial_capital = 1000, default_qty_value = 10, default_qty_type = strategy.percent_of_equity, calc_on_every_tick = false, process_orders_on_close = true, commission_value = 0.075)

// -- Colors --
color maximumYellowRed = color.rgb(255, 203, 98) // yellow
color rajah = color.rgb(242, 166, 84) // orange
color magicMint = color.rgb(171, 237, 198)
color languidLavender = color.rgb(232, 215, 255)
color maximumBluePurple = color.rgb(181, 161, 226)
color skyBlue = color.rgb(144, 226, 244)
color lightGray = color.rgb(214, 214, 214)
color quickSilver = color.rgb(163, 163, 163)
color mediumAquamarine = color.rgb(104, 223, 153)
color carrotOrange = color.rgb(239, 146, 46)

// -- Inputs --
length = input(title='ATR Period', defval=1)
mult = input.float(title='ATR Multiplier', step=0.1, defval=2)
showLabels = input(title='Show Buy/Sell Labels ?', tooltip='Created by Chandelier Exit (CE)', defval=false)
isSignalLabelEnabled = input(title='Show Signal Labels ?', defval=true)
useClose = input(title='Use Close Price for Extrema ?', defval=true)
zcolorchange = input(title='Enable Rising/Decreasing Highlightning', defval=false)
zlsmaLength = input(title='ZLSMA Length', defval=50)
offset = input(title='Offset', defval=0)

// -- CE - Credits to @everget --
float haClose = float(1) / 4 * (open[1] + high[1] + low[1] + close[1])
atr = mult * ta.atr(length)[1]

longStop = (useClose ? ta.highest(haClose, length) : ta.highest(haClose, length)) - atr
longStopPrev = nz(longStop[1], longStop)
longStop := haClose > longStopPrev ? math.max(longStop, longStopPrev) : longStop

shortStop = (useClose ? ta.lowest(haClose, length) : ta.lowest(haClose, length)) + atr
shortStopPrev = nz(shortStop[1], shortStop)
shortStop := haClose < shortStopPrev ? math.min(shortStop, shortStopPrev) : shortStop

var int dir = 1
dir := haClose > shortStopPrev ? 1 : haClose < longStopPrev ? -1 : dir

buySignal = dir == 1 and dir[1] == -1
plotshape(buySignal and showLabels ? longStop : na, title='Buy Label', text='Buy', location=location.absolute, style=shape.labelup, size=size.tiny, color=mediumAquamarine, textcolor=color.white)
sellSignal = dir == -1 and dir[1] == 1
plotshape(sellSignal and showLabels ? shortStop : na, title='Sell Label', text='Sell', location=location.absolute, style=shape.labeldown, size=size.tiny, color=carrotOrange, textcolor=color.white)

changeCond = dir != dir[1]

// -- ZLSMA - Credits to @netweaver2011 --
lsma = ta.linreg(haClose, zlsmaLength, offset)
lsma2 = ta.linreg(lsma, zlsmaLength, offset)
eq = lsma - lsma2
zlsma = lsma + eq

zColor = zcolorchange ? zlsma > zlsma[1] ? magicMint : rajah : languidLavender
plot(zlsma, title='ZLSMA', linewidth=2, color=zColor)

// -- Signals --
var string isTradeOpen = ''
var string signalCache = ''

bool enterLong = buySignal and ta.crossover(haClose, zlsma) 
bool exitLong = ta.crossunder(haClose, zlsma) 
bool enterShort = sellSignal and ta.crossunder(haClose, zlsma)
bool exitShort = ta.crossover(haClose, zlsma)

if (signalCache == 'long entry')
    signalCache := ''
    enterLong := true
else if (signalCache == 'short entry')
    signalCache := ''
    enterShort := true

if (isTradeOpen == '')
    if (exitShort and (not enterLong))
        exitShort := false
    if (exitLong and (not enterShort))
        exitLong := false   
    if (enterLong and exitShort)
        isTradeOpen := 'long'
        exitShort := false
    else if (enterShort and exitLong)
        isTradeOpen := 'short'
        exitLong := false
    else if (enterLong)
        isTradeOpen := 'long'
    else if (enterShort)
        isTradeOpen := 'short'
else if (isTradeOpen == 'long')
    if (exitShort)
        exitShort := false
    if (enterLong)
        enterLong := false
    if (enterShort and exitLong)
        enterShort := false
        signalCache := 'short entry'
    if (exitLong)
        isTradeOpen := ''
else if (isTradeOpen == 'short')
    if (exitLong)
        exitLong := false
    if (enterShort)
        enterShort := false
    if (enterLong and exitShort)
        enterLong := false
        signalCache := 'long entry'
    if (exitShort)
        isTradeOpen := ''

plotshape((isSignalLabelEnabled and enterLong) ? zlsma : na, title='LONG', text='L', style=shape.labelup, color=mediumAquamarine, textcolor=color.white, size=size.tiny, location=location.absolute)
plotshape((isSignalLabelEnabled and enterShort) ? zlsma : na, title='SHORT', text='S', style=shape.labeldown, color=carrotOrange, textcolor=color.white, size=size.tiny, location=location.absolute)
plotshape((isSignalLabelEnabled and exitLong) ? zlsma : na, title='LONG EXIT', style=shape.circle, color=magicMint, size=size.tiny, location=location.absolute)
plotshape((isSignalLabelEnabled and exitShort) ? zlsma : na, title='SHORT EXIT', style=shape.circle, color=rajah, size=size.tiny, location=location.absolute)

barcolor(color=isTradeOpen == 'long' ? mediumAquamarine : isTradeOpen == 'short' ? carrotOrange : na)

// -- Long Exits --
if (exitLong and strategy.position_size > 0)
    strategy.close('long', comment='EXIT_LONG')

// -- Short Exits --
if (exitShort and strategy.position_size < 0)
    strategy.close('short', comment='EXIT_SHORT')

// -- Long Entries --
if (enterLong)
    strategy.entry('long', strategy.long, comment='ENTER_LONG')

// -- Short Entries --
if (enterShort)
    strategy.entry('short', strategy.short, comment='ENTER_SHORT')

더 많은

2019 FMZ - 모든 권리 보호