O recurso está a ser carregado... Carregamento...

Estratégia de dupla MA com limite de tempo

Autora:ChaoZhang, Data: 2023-11-14 16:45:03
Tags:

Resumo

Esta estratégia implementa um módulo de limite de tempo baseado na estratégia de média móvel dupla original para controlar a hora de início da estratégia.

Princípio

A estratégia gera sinais de negociação usando MAs rápidos e lentos. O MA rápido tem um período de 14 dias e o MA lento tem um período de 21 dias. Um sinal de compra é gerado quando o MA rápido cruza acima do MA lento. Um sinal de venda é gerado quando o MA rápido cruza abaixo do MA lento.

A estratégia inclui igualmente uma opção de inversão comercial para reverter a direcção comercial original.

O módulo limite de tempo compara o tempo atual com o tempo de início configurado usando carimbos de tempo, retornando verdadeiro ou falso para controlar se a estratégia é iniciada ou não. O ano de início, mês, dia, hora e minuto precisam ser definidos. A estratégia só será iniciada quando o tempo atual exceder a hora de início configurada.

Vantagens

Os MAs duplos captam eficazmente as tendências de médio a curto prazo
O módulo de limite de tempo controla com precisão o tempo de execução da estratégia, evitando negociações desnecessárias em condições desfavoráveis de mercado
A opção de reversão das trocas acrescenta flexibilidade

Riscos e soluções

Os MAs duplos podem gerar sinais de negociação excessivos, aumentando a frequência e os custos de negociação
Configuração incorreta do prazo pode causar oportunidades perdidas
A inversão comercial incorreta pode levar a sinais comerciais errados

Otimizar os períodos de MA pode reduzir a frequência de negociação. O horário de início também deve ser definido racionalmente para evitar oportunidades perdidas. Finalmente, escolha cuidadosamente se inverterá os sinais com base nas condições do mercado.

Orientações de otimização

A adição de um módulo de stop loss controla melhor o risco das operações individuais
A implementação de um stop loss que move gradualmente o ponto de stop loss pode ajudar a bloquear os lucros
Combinar sinais em vários símbolos pode melhorar a qualidade do sinal e reduzir os falsos sinais
Desenvolvimento de um módulo de otimização de parâmetros que encontre automaticamente as combinações ótimas de parâmetros

Resumo

Esta estratégia gera sinais de negociação usando MAs duplos e controla o tempo de execução com o módulo de limite de tempo, capturando efetivamente as tendências, evitando condições desfavoráveis de mercado.

/*backtest
start: 2023-11-06 00:00:00
end: 2023-11-13 00:00:00
period: 45m
basePeriod: 5m
exchanges: [{"eid":"Futures_Binance","currency":"BTC_USDT"}]
*/

//@version=2

strategy(title = "Strategy Code Example", shorttitle = "Strategy Code Example", overlay = true)

// Revision:        1
// Author:          @JayRogers
//
// *** THIS IS JUST AN EXAMPLE OF STRATEGY TIME LIMITING ***
//
//  This is a follow up to my previous strategy example for risk management, extended to include a time limiting factor.

// === GENERAL INPUTS ===
// short ma
maFastSource   = input(defval = open, title = "Fast MA Source")
maFastLength   = input(defval = 14, title = "Fast MA Period", minval = 1)
// long ma
maSlowSource   = input(defval = open, title = "Slow MA Source")
maSlowLength   = input(defval = 21, title = "Slow MA Period", minval = 1)

// === STRATEGY RELATED INPUTS ===
tradeInvert     = input(defval = false, title = "Invert Trade Direction?")
// Risk management
inpTakeProfit   = input(defval = 1000, title = "Take Profit", minval = 0)
inpStopLoss     = input(defval = 200, title = "Stop Loss", minval = 0)
inpTrailStop    = input(defval = 200, title = "Trailing Stop Loss", minval = 0)
inpTrailOffset  = input(defval = 0, title = "Trailing Stop Loss Offset", minval = 0)
// *** FOCUS OF EXAMPLE ***
// Time limiting
// a toggle for enabling/disabling
useTimeLimit    = input(defval = true, title = "Use Start Time Limiter?")
// set up where we want to run from
startYear       = input(defval = 2016, title = "Start From Year",  minval = 0, step = 1)
startMonth      = input(defval = 05, title = "Start From Month",  minval = 0,step = 1)
startDay        = input(defval = 01, title = "Start From Day",  minval = 0,step = 1)
startHour       = input(defval = 00, title = "Start From Hour",  minval = 0,step = 1)
startMinute     = input(defval = 00, title = "Start From Minute",  minval = 0,step = 1)

// === RISK MANAGEMENT VALUE PREP ===
// if an input is less than 1, assuming not wanted so we assign 'na' value to disable it.
useTakeProfit   = inpTakeProfit  >= 1 ? inpTakeProfit  : na
useStopLoss     = inpStopLoss    >= 1 ? inpStopLoss    : na
useTrailStop    = inpTrailStop   >= 1 ? inpTrailStop   : na
useTrailOffset  = inpTrailOffset >= 1 ? inpTrailOffset : na

// *** FOCUS OF EXAMPLE ***
// === TIME LIMITER CHECKING FUNCTION ===
// using a multi line function to return true or false depending on our input selection
// multi line function logic must be indented.
startTimeOk() =>
    // get our input time together
    inputTime   = timestamp(syminfo.timezone, startYear, startMonth, startDay, startHour, startMinute)
    // check the current time is greater than the input time and assign true or false
    timeOk      = time > inputTime ? true : false
    // last line is the return value, we want the strategy to execute if..
    // ..we are using the limiter, and the time is ok -OR- we are not using the limiter
    r = (useTimeLimit and timeOk) or not useTimeLimit

// === SERIES SETUP ===
/// a couple of ma's..
maFast = ema(maFastSource, maFastLength)
maSlow = ema(maSlowSource, maSlowLength)

// === PLOTTING ===
fast = plot(maFast, title = "Fast MA", color = green, linewidth = 2, style = line, transp = 50)
slow = plot(maSlow, title = "Slow MA", color = red, linewidth = 2, style = line, transp = 50)

// === LOGIC ===
// is fast ma above slow ma?
aboveBelow = maFast >= maSlow ? true : false
// are we inverting our trade direction?
tradeDirection = tradeInvert ? aboveBelow ? false : true : aboveBelow ? true : false

// *** FOCUS OF EXAMPLE ***
// wrap our strategy execution in an if statement which calls the time checking function to validate entry
// like the function logic, content to be included in the if statement must be indented.
if( startTimeOk() )
    // === STRATEGY - LONG POSITION EXECUTION ===
    enterLong = not tradeDirection[1] and tradeDirection
    exitLong = tradeDirection[1] and not tradeDirection
    strategy.entry( id = "Long", long = true, when = enterLong )
    strategy.close( id = "Long", when = exitLong )
    
    // === STRATEGY - SHORT POSITION EXECUTION ===
    enterShort = tradeDirection[1] and not tradeDirection
    exitShort = not tradeDirection[1] and tradeDirection
    strategy.entry( id = "Short", long = false, when = enterShort )
    strategy.close( id = "Short", when = exitShort )
    
    // === STRATEGY RISK MANAGEMENT EXECUTION ===
    strategy.exit("Exit Long", from_entry = "Long", profit = useTakeProfit, loss = useStopLoss, trail_points = useTrailStop, trail_offset = useTrailOffset)
    strategy.exit("Exit Short", from_entry = "Short", profit = useTakeProfit, loss = useStopLoss, trail_points = useTrailStop, trail_offset = useTrailOffset)

Mais.