O recurso está a ser carregado... Carregamento...

Scalping rápido RSI Switching Strategy v1.7

Autora:ChaoZhang, Data: 2023-12-22 15:10:40
Tags:

Resumo

A estratégia de comutação do RSI do Noro é uma estratégia quantitativa de negociação que identifica oportunidades de sobrecompra e sobrevenda usando o indicador RSI. A estratégia também incorpora padrões de velas, filtros de média móvel e métodos de stop loss para controlar o risco.

Os principais componentes desta estratégia incluem:

Indicador RSI rápido: Identificar os níveis de sobrecompra e sobrevenda
Padrões de velas: Ajudar a determinar a direção da tendência
Filtro de média móvel: Use SMA para evitar sinais falsos
Mecanismo de stop loss: implementar stop loss com base nos limites do RSI

Estratégia lógica

A estratégia de comutação do RSI Fast Scalping da Noro identifica principalmente os seguintes sinais de negociação:

Signais de sobrecompra/supervenda do RSI rápido: Os sinais de comércio são gerados quando o RSI rápido cruza o seu limite superior ou abaixo do seu limite inferior.
Sinais de candelabro: Parâmetros de candelabro como tamanho do corpo e direção são usados para determinar a tendência e complementar os sinais rápidos do RSI.
Sinais de filtragem SMA: a direção SMA filtra sinais de fuga falsos.
Sinais de Stop Loss: as posições são fechadas quando o RSI rápido cruza de volta acima do seu limite superior ou abaixo do seu limite inferior.

Especificamente, esta estratégia identifica oportunidades de negociação com base nas zonas de sobrecompra e sobrevenda do RSI rápido.

Para evitar o ruído, são acrescentadas as seguintes condições suplementares:

Tamanho do corpo da vela: corpos de vela maiores representam uma tendência mais forte
Direção da vela: Determina tendência de alta ou baixa
Filtro SMA: Filtra sinais falsos de ruptura
Stop Loss: sai das negociações quando o RSI rápido ultrapassa os seus limites

Portanto, esta estratégia combina RSI rápido, candelabros, média móvel e stop loss juntos para gerar sinais de negociação.

Vantagens

As vantagens desta estratégia incluem:

RSI rápido é sensível: captura rapidamente oportunidades de sobrecompra/supervenda
Candlestick & MA Filter: Evita sinais falsos
Stop Loss automático: Controla eficazmente os riscos
Adequado para Scalping: Funciona bem com prazos mais curtos, por exemplo 1H, 30M
Fácil de otimizar: os parâmetros podem ser ajustados para diferentes mercados

Riscos

Há também alguns riscos a considerar:

Stop Loss consecutivo: podem ocorrer mais sinais de stop loss em mercados variados
Optimização de parâmetros necessária: os parâmetros precisam ser ajustados para diferentes pares e prazos
Incapaz de evitar todas as perdas: A parada oportuna das perdas ainda resulta em algumas perdas

Os seguintes métodos de otimização podem ajudar a mitigar os riscos:

Otimizar os parâmetros do RSI rápido: reduzir os falsos sinais
Otimizar a colocação de stop loss: controlar o tamanho da perda de uma única negociação
Adicionar o tamanho da posição: distribuir os riscos entre vários negócios

Orientações de otimização

Algumas formas de otimizar ainda mais esta estratégia incluem:

Adicionar lucro tomando saídas: tomar lucros parciais ao atingir metas de lucro
Melhorar a gestão dos riscos: incorporar regras de dimensionamento das posições para diversificar os riscos
Ajuste de parâmetros: Efeito do ensaio de ajustes de parâmetros em intervalos de tempo
Machine Learning: usar algoritmos para otimizar automaticamente parâmetros ao longo do tempo
Teste de robustez: Avaliação do desempenho da estratégia em mais pares de símbolos

Ao incorporar a obtenção de lucros, a gestão de riscos, a otimização de parâmetros, o aprendizado de máquina e os testes de robustez, a estratégia pode ser significativamente melhorada em termos de estabilidade.

Conclusão

Em resumo, a Estratégia de Troca de RSI de Scalping Rápido da Noro combina o indicador RSI rápido com análise de velas suplementares para identificar oportunidades de negociação sobrecompradas e sobrevendidas. Com tempos de resposta de sinal rápidos, facilidade de otimização e módulos de stop loss incorporados, esta estratégia de negociação de curto prazo tem forte potencial para gerar resultados positivos após mais aprendizado de máquina e ajuste de parâmetros.

/*backtest
start: 2023-12-14 00:00:00
end: 2023-12-18 00:00:00
period: 15m
basePeriod: 5m
exchanges: [{"eid":"Futures_Binance","currency":"BTC_USDT"}]
*/

//Noro
//2018

//@version=2
strategy(title = "Noro's Fast RSI Strategy v1.7", shorttitle = "Fast RSI str 1.7", overlay = true)

//Settings
needlong = input(true, defval = true, title = "Long")
needshort = input(true, defval = true, title = "Short")
usemar = input(false, defval = false, title = "Use Martingale")
capital = input(100, defval = 100, minval = 1, maxval = 10000, title = "Capital, %")
usersi = input(true, defval = true, title = "Use Fast RSI Strategy")
usemm = input(true, defval = true, title = "Use Min/Max Strategy")
usebc = input(true, defval = true, title = "Use BarColor Strategy")
usesma = input(false, defval = false, title = "Use SMA Filter")
smaperiod = input(20, defval = 20, minval = 2, maxval = 1000, title = "SMA Filter Period")
fast = input(7, defval = 7, minval = 2, maxval = 50, title = "Fast RSI Period")
limit = input(30, defval = 30, minval = 1, maxval = 100, title = "RSI limit")
rsisrc = input(close, defval = close, title = "RSI Price")
rsibars = input(1, defval = 1, minval = 1, maxval = 20, title = "RSI Bars")
mmbars = input(1, defval = 1, minval = 1, maxval = 5, title = "Min/Max Bars")
showsma = input(false, defval = false, title = "Show SMA Filter")
showarr = input(false, defval = false, title = "Show Arrows")
fromyear = input(2018, defval = 2018, minval = 1900, maxval = 2100, title = "From Year")
toyear = input(2100, defval = 2100, minval = 1900, maxval = 2100, title = "To Year")
frommonth = input(01, defval = 01, minval = 01, maxval = 12, title = "From Month")
tomonth = input(12, defval = 12, minval = 01, maxval = 12, title = "To Month")
fromday = input(01, defval = 01, minval = 01, maxval = 31, title = "From day")
today = input(31, defval = 31, minval = 01, maxval = 31, title = "To day")

//Fast RSI
fastup = rma(max(change(rsisrc), 0), fast)
fastdown = rma(-min(change(rsisrc), 0), fast)
fastrsi = fastdown == 0 ? 100 : fastup == 0 ? 0 : 100 - (100 / (1 + fastup / fastdown))

//Limits
bar = close > open ? 1 : close < open ? -1 : 0
uplimit = 100 - limit
dnlimit = limit

//RSI Bars
upsignal = fastrsi > uplimit ? 1 : 0
dnsignal = fastrsi < dnlimit ? 1 : 0
uprsi = sma(upsignal, rsibars) == 1
dnrsi = sma(dnsignal, rsibars) == 1

//Body
body = abs(close - open)
abody = sma(body, 10)

//MinMax Bars
min = min(close, open)
max = max(close, open)
minsignal = min < min[1] and bar == -1 and bar[1] == -1 ? 1 : 0
maxsignal = max > max[1] and bar == 1 and bar[1] == 1 ? 1 : 0
mins = sma(minsignal, mmbars) == 1
maxs = sma(maxsignal, mmbars) == 1

//SMA Filter
sma = sma(close, smaperiod)
colorsma = showsma ? blue : na
plot(sma, color = colorsma, linewidth = 3)

//Signals
up1 = bar == -1 and (strategy.position_size == 0 or close < strategy.position_avg_price) and dnrsi and body > abody / 5 and usersi
dn1 = bar == 1 and (strategy.position_size == 0 or close > strategy.position_avg_price) and uprsi and body > abody / 5 and usersi
up2 = mins and (close > sma or usesma == false) and fastrsi < 70 and usemm
dn2 = maxs and (close < sma or usesma == false) and fastrsi > 30 and usemm 
up3 = sma(bar, 2) == -1 and usebc
dn3 = sma(bar, 2) == 1 and usebc
exit = (((strategy.position_size > 0 and fastrsi > dnlimit and bar == 1) or (strategy.position_size < 0 and fastrsi < uplimit and bar == -1)) and body > abody / 2)

//Arrows
col = exit ? black : up1 or dn1 ? blue : up2 or dn2 ? red : na
needup = up1 or up2
needdn = dn1 or dn2
needexitup = exit and strategy.position_size < 0
needexitdn = exit and strategy.position_size > 0
plotarrow(showarr and needup ? 1 : na, colorup = blue, colordown = blue, transp = 0)
plotarrow(showarr and needdn ? -1 : na, colorup = blue, colordown = blue, transp = 0)
plotarrow(showarr and needexitup ? 1 : na, colorup = black, colordown = black, transp = 0)
plotarrow(showarr and needexitdn ? -1 : na, colorup = black, colordown = black, transp = 0)

//Trading
profit = exit ? ((strategy.position_size > 0 and close > strategy.position_avg_price) or (strategy.position_size < 0 and close < strategy.position_avg_price)) ? 1 : -1 : profit[1]
mult = usemar ? exit ? profit == -1 ? mult[1] * 2 : 1 : mult[1] : 1
lot = strategy.position_size == 0 ? strategy.equity / close * capital / 100 * mult : lot[1]

if up1 or up2 or up3
    if strategy.position_size < 0
        strategy.close_all()
        
    strategy.entry("Long", strategy.long, needlong == false ? 0 : lot)

if dn1 or dn2 or dn3
    if strategy.position_size > 0
        strategy.close_all()
        
    strategy.entry("Short", strategy.short, needshort == false ? 0 : lot)
    
if time > timestamp(toyear, tomonth, today, 23, 59) or exit
    strategy.close_all()

Mais.