O recurso está a ser carregado... Carregamento...

Estratégia de ruptura em percentagem de barras positivas

Autora:ChaoZhang, Data: 2024-01-08 10:32:25
Tags:

Resumo

A estratégia de breakout de porcentagem de barras positivas é uma estratégia quantitativa de negociação baseada em julgamentos de ação de preços. Ela calcula a porcentagem de velas de tendência de alta em um período especificado para determinar se o mercado está atualmente em um estado de tendência de alta. Quando a porcentagem de velas de tendência de alta é maior que o limite superior definido pelo usuário, a estratégia julga que o mercado está atualmente em uma tendência de alta e vai longo. Quando a porcentagem é menor que o limite inferior definido pelo usuário, a estratégia julga que o mercado está atualmente em uma tendência de baixa e vai curto.

Estratégia lógica

O indicador central desta estratégia é a porcentagem de velas de tendência de alta. Uma vela de tendência de alta abre abaixo da baixa anterior e fecha acima da aberta, indicando que o preço subiu durante esse período. A estratégia conta o número de velas de tendência de alta no período de retrospectiva definido pelo usuário e calcula a porcentagem de velas de tendência de alta entre todas as velas. Quando a porcentagem é maior que o limite superior, a estratégia julga que o mercado está em uma tendência de alta persistente e vai longo. Quando a porcentagem é menor que o limite inferior, a estratégia julga que o mercado está em uma tendência de baixa e vai curto. As ordens de stop loss e take profit são definidas de acordo com o método de stop loss definido pelo usuário.

Por exemplo, se o usuário definir o período de lookback para 20, limite superior para 70, limite inferior para 30, a estratégia rastreia as últimas 20 velas. Se 16 delas forem velas de tendência ascendente, a porcentagem seria de 16/20=80%. Como 80% é superior ao limite superior de 70%, a estratégia executará uma ordem longa. Se entre as últimas 20 velas, apenas 5 forem velas de tendência ascendente, então a porcentagem seria 5/20=25%. Isso é menor que o limite inferior de 30%, a estratégia executará uma ordem curta.

Análise das vantagens

As principais vantagens desta estratégia são:

A lógica da estratégia é simples e intuitiva, fácil de entender;
Baseia-se num único indicador, reduzindo o risco de sobreajuste;
Os utilizadores podem personalizar parâmetros para diferentes produtos;
Tem funções de stop loss/take profit integradas para evitar perdas enormes;
Permitir o reverso do comércio sem sair das posições primeiro, rastreamento mais rápido das tendências.

Análise de riscos

Os principais riscos desta estratégia são:

A utilização de um único indicador pode gerar falsos sinais;
Os parâmetros são propensos a sobreajustes, o desempenho em tempo real pode variar muito;
A posição de paragem pode ser afectada por flutuações voláteis dos preços, levando a perdas;
O reverse trade pode amplificar as perdas;
O desempenho depende fortemente do símbolo, exigindo testes separados.

Os riscos podem ser reduzidos:

Adição de filtros para evitar falsos sinais;
Otimizar a lógica de stop loss para limitar as perdas;
Avaliação e controlo do tamanho máximo das perdas;
Teste em diferentes símbolos separadamente.

Orientações de otimização

As principais direcções para otimizar esta estratégia incluem:

Adicionar indicadores auxiliares como volume para evitar falsos sinais;
Otimizar os métodos de stop loss, tais como trailing stop loss;
Adicionando filtros de entrada como breakout de Bollinger Bands;
Ensaios de parâmetros ideais das velas de tendência ascendente para diferentes símbolos;
Avaliação do aproveitamento máximo e controlo do tamanho das perdas.

Conclusão

A estratégia de ruptura de porcentagem de barras positivas possui uma lógica simples e direta para capturar tendências julgando estatisticamente a persistência de tendências de alta/baixa. É fácil de entender e fácil de usar, adequado para iniciantes.

/*backtest
start: 2023-12-31 00:00:00
end: 2024-01-04 00:00:00
period: 1m
basePeriod: 1m
exchanges: [{"eid":"Futures_Binance","currency":"BTC_USDT"}]
*/


// This source code is subject to the terms of the Mozilla Public License 2.0 at https://mozilla.org/MPL/2.0/
// © ZenAndTheArtOfTrading 
// © TweakerID

// Based on the calculations by ZenAndTheArtOfTrading, I added stop loss, take profit and reverse line codes.
// The Positive Bars % calculates the number of green (positive) bars, relative to a lookback period, defined 
// by the user. If the percentage is low, it means that there was a bigger number of red candles in the 
// lookback period. The strategy goes long when the percentage is high and short when it's low, although
// this logic can be reversed with positive results on different time frames.

//@version=4
strategy("Positive Bars % Strat", 
     overlay=true, 
     default_qty_type=strategy.percent_of_equity, 
     default_qty_value=100, 
     initial_capital=10000, 
     commission_value=0.04, 
     calc_on_every_tick=false, 
     slippage=0)

direction = input(0, title = "Strategy Direction", type=input.integer, minval=-1, maxval=1)
strategy.risk.allow_entry_in(direction == 0 ? strategy.direction.all : (direction < 0 ? strategy.direction.short : strategy.direction.long))

/////////////////////// STRATEGY INPUTS ////////////////////////////////////////
title1=input(true, "-----------------Strategy Inputs-------------------")  

lookback = input(title="Lookback", type=input.integer, defval=13)
upperLimit = input(title="Upper Limit", type=input.integer, defval=70)
lowerLimit = input(title="Lower Limit", type=input.integer, defval=30)

/////////////////////// BACKTESTER /////////////////////////////////////////////
title2=input(true, "-----------------General Inputs-------------------")  

// Backtester General Inputs
i_SL=input(true, title="Use Stop Loss and Take Profit")
i_SLType=input(defval="ATR Stop", title="Type Of Stop", options=["Strategy Stop", "Swing Lo/Hi", "ATR Stop"])
i_SPL=input(defval=10, title="Swing Point Lookback")
i_PercIncrement=input(defval=2, step=.1, title="Swing Point SL Perc Increment")*0.01
i_ATR = input(14, title="ATR Length")
i_ATRMult = input(10, step=.1, title="ATR Multiple")
i_TPRRR = input(1.6, step=.1, title="Take Profit Risk Reward Ratio")

// Bought and Sold Boolean Signal
bought = strategy.position_size > strategy.position_size[1] 
 or strategy.position_size < strategy.position_size[1]

// Price Action Stop and Take Profit
LL=(lowest(i_SPL))*(1-i_PercIncrement)
HH=(highest(i_SPL))*(1+i_PercIncrement)
LL_price = valuewhen(bought, LL, 0)
HH_price = valuewhen(bought, HH, 0)
entry_LL_price = strategy.position_size > 0 ? LL_price : na 
entry_HH_price = strategy.position_size < 0 ? HH_price : na 
tp=strategy.position_avg_price + (strategy.position_avg_price - entry_LL_price)*i_TPRRR
stp=strategy.position_avg_price - (entry_HH_price - strategy.position_avg_price)*i_TPRRR

// ATR Stop
ATR=atr(i_ATR)*i_ATRMult
ATRLong = ohlc4 - ATR
ATRShort = ohlc4 + ATR
ATRLongStop = valuewhen(bought, ATRLong, 0)
ATRShortStop = valuewhen(bought, ATRShort, 0)
LongSL_ATR_price = strategy.position_size > 0 ? ATRLongStop : na 
ShortSL_ATR_price = strategy.position_size < 0 ? ATRShortStop : na 
ATRtp=strategy.position_avg_price + (strategy.position_avg_price - LongSL_ATR_price)*i_TPRRR
ATRstp=strategy.position_avg_price - (ShortSL_ATR_price - strategy.position_avg_price)*i_TPRRR

// Strategy Stop
float LongStop = na
float ShortStop = na
float StratTP = na
float StratSTP = na

/////////////////////// STRATEGY LOGIC /////////////////////////////////////////

//Calculations
positiveBars = 0
for i = (lookback - 1) to 0
    if close[i] > open[i]
        positiveBars := positiveBars + 1
positiveBarsPercent = (positiveBars / lookback) * 100

BUY=positiveBarsPercent >= upperLimit
SELL=positiveBarsPercent <= lowerLimit

//Trading Inputs
DPR=input(true, "Allow Direct Position Reverse")
reverse=input(false, "Reverse Trades")

// Entries
if reverse
    if not DPR
        strategy.entry("long", strategy.long, when=SELL and strategy.position_size == 0)
        strategy.entry("short", strategy.short, when=BUY and strategy.position_size == 0)
    else     
        strategy.entry("long", strategy.long, when=SELL)
        strategy.entry("short", strategy.short, when=BUY)
else
    if not DPR 
        strategy.entry("long", strategy.long, when=BUY and strategy.position_size == 0)
        strategy.entry("short", strategy.short, when=SELL and strategy.position_size == 0)
    else
        strategy.entry("long", strategy.long, when=BUY)
        strategy.entry("short", strategy.short, when=SELL)


SL= i_SLType == "Swing Lo/Hi" ? entry_LL_price : i_SLType == "ATR Stop" ? LongSL_ATR_price : LongStop
SSL= i_SLType == "Swing Lo/Hi" ? entry_HH_price : i_SLType == "ATR Stop" ? ShortSL_ATR_price : ShortStop
TP= i_SLType == "Swing Lo/Hi" ? tp : i_SLType == "ATR Stop" ? ATRtp : StratTP
STP= i_SLType == "Swing Lo/Hi" ? stp : i_SLType == "ATR Stop" ? ATRstp : StratSTP

strategy.exit("TP & SL", "long", limit=TP, stop=SL, when=i_SL)
strategy.exit("TP & SL", "short", limit=STP, stop=SSL, when=i_SL)

/////////////////////// PLOTS //////////////////////////////////////////////////

plot(i_SL and strategy.position_size > 0 ? SL : na , title='SL', style=plot.style_cross, color=color.red)
plot(i_SL and strategy.position_size < 0 ? SSL : na , title='SSL', style=plot.style_cross, color=color.red)
plot(i_SL and strategy.position_size > 0 ? TP : na, title='TP', style=plot.style_cross, color=color.green)
plot(i_SL and strategy.position_size < 0 ? STP : na, title='STP', style=plot.style_cross, color=color.green)
// Draw price action setup arrows
plotshape(BUY ? 1 : na, style=shape.triangleup, location=location.belowbar, 
 color=color.green, title="Bullish Setup", size=size.auto)
plotshape(SELL ? 1 : na, style=shape.triangledown, location=location.abovebar, 
 color=color.red, title="Bearish Setup", size=size.auto)

Mais.