O recurso está a ser carregado... Carregamento...

Estratégia de inversão do sinal P

Autora:ChaoZhang, Data: 2024-01-29 14:44:56
Tags:

Resumo

A estratégia de reversão do sinal P é uma estratégia quantitativa de negociação construída com base em parâmetros estatísticos e funções de erro para construir um espaço de sinal probabilístico.

Princípios de estratégia

O indicador central desta estratégia é o sinal P, que combina os parâmetros estatísticos das médias móveis e desvios padrão e os mapeia para a faixa de -1 a 1 através da função de erro de Gauss para formar um indicador de julgamento quantificado.

Os parâmetros da estratégia incluem Cardinalidade, ΔErf e Tempo de Observação. Cardinalidade controla o tamanho da amostra, ΔErf controla a banda morta da função de erro para reduzir a frequência de negociação.

Análise das vantagens

A maior vantagem da estratégia de reversão do sinal P é que se baseia nas distribuições de probabilidade dos parâmetros estatísticos, que podem julgar efetivamente os pontos característicos do mercado e capturar oportunidades de reversão.

Além disso, o projeto parametrizado da estratégia é bem regulado, permitindo que os utilizadores ajustem o espaço de parâmetros de acordo com as suas próprias necessidades para encontrar a combinação ideal.

Análise de riscos

O principal risco da estratégia de reversão de sinal P é que depende demais dos parâmetros da distribuição de probabilidade, que é facilmente afetada por dados anormais resultando em julgamentos errôneos.

Aumentar o parâmetro de cardinalidade para aumentar o tamanho da amostra pode reduzir o impacto das anomalias de dados.

Orientações de otimização

A estratégia de inversão do sinal P pode ser otimizada nos seguintes aspectos:

Incorporar outros indicadores para filtrar sinais anormais, tais como aumentos acentuados no volume.
Validar sinais em vários prazos para melhorar a estabilidade do julgamento.
Aumentar as estratégias de stop loss para reduzir as perdas individuais.
Otimizar os parâmetros para encontrar a melhor combinação e melhorar a rentabilidade.
Incorporar aprendizagem de máquina para ajuste dinâmico de parâmetros.

Resumo

A estratégia de reversão de sinal P estabelece uma estrutura quantitativa de negociação baseada em distribuições de probabilidade com designs de parâmetros flexíveis e facilidade de uso. Ele efetivamente julga as características estatísticas dos mercados e capta oportunidades de reversão. A estratégia pode ser ainda melhorada em estabilidade e lucratividade através de validação de múltiplos indicadores, otimização de stop loss e outros meios.

/*backtest
start: 2023-12-01 00:00:00
end: 2023-12-31 23:59:59
period: 1h
basePeriod: 15m
exchanges: [{"eid":"Futures_Binance","currency":"BTC_USDT"}]
*/

//@version=5
// **********************************************************************************************************
// This source code is subject to the terms of the Mozilla Public License 2.0 at https://mozilla.org/MPL/2.0/
// P-Signal Strategy RVS © Kharevsky
// **********************************************************************************************************
strategy('P-Signal Strategy RVS.', precision=3, process_orders_on_close=true, pyramiding=0, 
     commission_type=strategy.commission.percent,
     commission_value=0.2)
// Parameters and const of P-Signal.
nPoints = input.int(title='Cardinality:', defval=4, minval=4, maxval=200, group='Parameters of strategy.')
ndErf = input.float(title='|ΔErf|:', defval=0, minval=0, maxval=1, step=0.01, group='Parameters of strategy.')
tStartDate = input(title='Start date:', defval=timestamp('30 Dec 1957 00:00 +0300'), group='Observation time.')
int nIntr = nPoints - 1
// Horner's method for the error (Gauss) & P-Signal functions.
fErf(x) =>
    nT = 1.0 / (1.0 + 0.5 * math.abs(x))
    nAns = 1.0 - nT * math.exp(-x * x - 1.26551223 + 
     nT * (1.00002368 + nT * (0.37409196 + nT * (0.09678418 + 
     nT * (-0.18628806 + nT * (0.27886807 + nT * (-1.13520398 + 
     nT * (1.48851587 + nT * (-0.82215223 + nT * 0.17087277)))))))))
    x >= 0 ? nAns : -nAns
fPSignal(ser, int) =>
    nStDev = ta.stdev(ser, int)
    nSma = ta.sma(ser, int)
    nStDev > 0 ? fErf(nSma / nStDev / math.sqrt(2)) : math.sign(nSma)
// Data.
float nPSignal = ta.sma(fPSignal(ta.change(ohlc4), nIntr), nIntr)
float ndPSignal = math.sign(nPSignal[0] - nPSignal[1])
bool isStartDate = true
// Reversal Strategy.
strategy.entry('short', strategy.short, when=isStartDate and nPSignal > ndErf and ndPSignal < 0)
strategy.entry('long', strategy.long, when=isStartDate and nPSignal < -ndErf and ndPSignal > 0)
// Plotting. 
hline(+1.0, color=color.new(color.orange, 70), linestyle=hline.style_dotted, editable=false)
hline(-1.0, color=color.new(color.orange, 70), linestyle=hline.style_dotted, editable=false)
hline(-ndErf, color=color.new(color.orange, 70), linestyle=hline.style_dotted, editable=false)
hline(ndErf, color=color.new(color.orange, 70), linestyle=hline.style_dotted, editable=false)
plot(nPSignal, color=color.new(color.blue, 0), style=plot.style_line)
// Table of state.
if barstate.isconfirmed
    var Table = table.new(position=position.bottom_right, columns=3, rows=1, 
     frame_color=color.new(color.orange, 70), frame_width=1, 
     border_color=color.new(color.orange, 70), border_width=1)
    table.cell(table_id=Table, column=0, row=0, 
     text=strategy.position_size > 0 ? 'Long: ' + str.tostring(strategy.position_size) : 'Short: ' + str.tostring(strategy.position_size), 
     text_color=strategy.position_size > 0 ? color.green : color.red)
    table.cell(table_id=Table, column=1, row=0, 
     text='Net P/L: ' + str.tostring(strategy.netprofit, '#.#'), 
     text_color=strategy.netprofit > 0 ? color.green : color.red)
    table.cell(table_id=Table, column=2, row=0, 
     text='Open P/L: ' + str.tostring(strategy.openprofit, '#.#'), 
     text_color=strategy.openprofit > 0 ? color.green : color.red)
// The end.

Mais.