O recurso está a ser carregado... Carregamento...

Estratégia de negociação de rede quântica auto-adaptável

Autora:ChaoZhang, Data: 2024-02-02 18:08:22
Tags:

Resumo

Esta estratégia estabelece uma grade de negociação dinâmica para alcançar lucros constantes em meio a mercados voláteis. Ele calcula automaticamente o espaçamento da grade e o limite superior/inferior com base no número pré-definido de linhas de grade. Quando o preço atravessa cada linha de grade, as posições longas/cortas serão construídas em lotes. Os lucros serão obtidos quando o preço atingir as linhas de grade originais novamente. A estratégia suporta ajuste manual e automático dos parâmetros da grade para se adaptar às condições de mercado em mudança.

Estratégia lógica

Calcular os limites da rede e a matriz de preços das linhas da rede com base nos parâmetros de entrada.
Quando o preço cai abaixo de uma linha de grade sem ordens correspondentes, as ordens longas serão colocadas no preço da linha de grade.
Se o ajuste automático estiver habilitado, os limites superior/inferior da grade, o espaçamento da grade e as matrizes da grade serão recalculados periodicamente com base nos dados recentes do candelabro.

Análise das vantagens

Realizar lucros constantes em meio a um mercado volátil.
Suporte ao ajuste manual e automático de parâmetros. O ajuste manual oferece um melhor controle, mas requer intervenção. O ajuste automático reduz a carga de trabalho e se adapta à mudança da dinâmica do mercado.
Quando o preço quebra todas as linhas da rede, os riscos são contidos.
Ajuste o espaçamento da grade para ajustar o lucro/perda por negociação.

Análise de riscos

Oscilações frequentes de preços dentro do intervalo da rede podem levar a perdas.
Requer um capital inicial adequado, pois o financiamento insuficiente não pode suportar linhas de rede suficientes.
Numeros extremos de grades prejudicam os lucros. Poucas grades não aproveitam plenamente a volatilidade, enquanto muitas grades levam a lucros mínimos por negociação. Extenso teste necessário para determinar configurações ideais.
O ajustamento automático corre o risco de manipulação de preços, baseando-se em velas recentes que podem ser afetadas por operações de preços a curto prazo.

Optimização

Introduzir uma lógica de stop loss, tal como trailing stop loss, para restringir ainda mais o risco de queda por direcção.
Otimizar parâmetros de rede através de aprendizagem de máquina. Testar diferentes parâmetros em condições de mercado e treinar modelos de ML para obter parâmetros ideais e adaptáveis.
Incorporar indicadores técnicos adicionais. Avalie a força da tendência atual com indicadores como MACD e RSI para orientar a quantidade da grade e o ajuste dos parâmetros.
Melhorar o controlo do risco através da fixação da percentagem máxima de retirada permitida. Desativar a estratégia quando o limiar for ultrapassado para evitar perdas adicionais.

Conclusão

Esta estratégia utiliza plenamente as características dos mercados voláteis e alcança lucros estáveis através de uma estrutura de negociação de rede dinâmica que oferece flexibilidade de parâmetros e facilidade de operação.

/*backtest
start: 2024-01-02 00:00:00
end: 2024-02-01 00:00:00
period: 1h
basePeriod: 15m
exchanges: [{"eid":"Futures_Binance","currency":"BTC_USDT"}]
*/

//@version=4
strategy("(IK) Grid Script", overlay=true, pyramiding=14, close_entries_rule="ANY", default_qty_type=strategy.cash, initial_capital=100.0, currency="USD", commission_type=strategy.commission.percent, commission_value=0.1)
i_autoBounds    = input(group="Grid Bounds", title="Use Auto Bounds?", defval=true, type=input.bool)                             // calculate upper and lower bound of the grid automatically? This will theorhetically be less profitable, but will certainly require less attention
i_boundSrc      = input(group="Grid Bounds", title="(Auto) Bound Source", defval="Hi & Low", options=["Hi & Low", "Average"])     // should bounds of the auto grid be calculated from recent High & Low, or from a Simple Moving Average
i_boundLookback = input(group="Grid Bounds", title="(Auto) Bound Lookback", defval=250, type=input.integer, maxval=500, minval=0) // when calculating auto grid bounds, how far back should we look for a High & Low, or what should the length be of our sma
i_boundDev      = input(group="Grid Bounds", title="(Auto) Bound Deviation", defval=0.10, type=input.float, maxval=1, minval=-1)  // if sourcing auto bounds from High & Low, this percentage will (positive) widen or (negative) narrow the bound limits. If sourcing from Average, this is the deviation (up and down) from the sma, and CANNOT be negative.
i_upperBound    = input(group="Grid Bounds", title="(Manual) Upper Boundry", defval=0.285, type=input.float)                      // for manual grid bounds only. The upperbound price of your grid
i_lowerBound    = input(group="Grid Bounds", title="(Manual) Lower Boundry", defval=0.225, type=input.float)                      // for manual grid bounds only. The lowerbound price of your grid.
i_gridQty       = input(group="Grid Lines",  title="Grid Line Quantity", defval=8, maxval=15, minval=3, type=input.integer)       // how many grid lines are in your grid

f_getGridBounds(_bs, _bl, _bd, _up) =>
    if _bs == "Hi & Low"
        _up ? highest(close, _bl) * (1 + _bd) : lowest(close, _bl)  * (1 - _bd)
    else
        avg = sma(close, _bl)
        _up ? avg * (1 + _bd) : avg * (1 - _bd)

f_buildGrid(_lb, _gw, _gq) =>
    gridArr = array.new_float(0)
    for i=0 to _gq-1
        array.push(gridArr, _lb+(_gw*i))
    gridArr

f_getNearGridLines(_gridArr, _price) =>
    arr = array.new_int(3)
    for i = 0 to array.size(_gridArr)-1
        if array.get(_gridArr, i) > _price
            array.set(arr, 0, i == array.size(_gridArr)-1 ? i : i+1)
            array.set(arr, 1, i == 0 ? i : i-1)
            break
    arr

var upperBound      = i_autoBounds ? f_getGridBounds(i_boundSrc, i_boundLookback, i_boundDev, true) : i_upperBound  // upperbound of our grid
var lowerBound      = i_autoBounds ? f_getGridBounds(i_boundSrc, i_boundLookback, i_boundDev, false) : i_lowerBound // lowerbound of our grid
var gridWidth       = (upperBound - lowerBound)/(i_gridQty-1)                                                       // space between lines in our grid
var gridLineArr     = f_buildGrid(lowerBound, gridWidth, i_gridQty)                                                 // an array of prices that correspond to our grid lines
var orderArr        = array.new_bool(i_gridQty, false)                                                              // a boolean array that indicates if there is an open order corresponding to each grid line

var closeLineArr    = f_getNearGridLines(gridLineArr, close)                                                        // for plotting purposes - an array of 2 indices that correspond to grid lines near price
var nearTopGridLine = array.get(closeLineArr, 0)                                                                    // for plotting purposes - the index (in our grid line array) of the closest grid line above current price
var nearBotGridLine = array.get(closeLineArr, 1)                                                                    // for plotting purposes - the index (in our grid line array) of the closest grid line below current price
strategy.initial_capital = 50000
for i = 0 to (array.size(gridLineArr) - 1)
    if close < array.get(gridLineArr, i) and not array.get(orderArr, i) and i < (array.size(gridLineArr) - 1)
        buyId = i
        array.set(orderArr, buyId, true)
        strategy.entry(id=tostring(buyId), long=true, qty=(strategy.initial_capital/(i_gridQty-1))/close, comment="#"+tostring(buyId))
    if close > array.get(gridLineArr, i) and i != 0
        if array.get(orderArr, i-1)
            sellId = i-1
            array.set(orderArr, sellId, false)
            strategy.close(id=tostring(sellId), comment="#"+tostring(sellId))

if i_autoBounds
    upperBound  := f_getGridBounds(i_boundSrc, i_boundLookback, i_boundDev, true)
    lowerBound  := f_getGridBounds(i_boundSrc, i_boundLookback, i_boundDev, false)
    gridWidth   := (upperBound - lowerBound)/(i_gridQty-1)
    gridLineArr := f_buildGrid(lowerBound, gridWidth, i_gridQty)

closeLineArr    := f_getNearGridLines(gridLineArr, close)
nearTopGridLine := array.get(closeLineArr, 0)
nearBotGridLine := array.get(closeLineArr, 1)

Mais.