O recurso está a ser carregado... Carregamento...

Estratégia de negociação de média móvel dupla de rastreamento inteligente

Autora:ChaoZhang, Data: 2024-02-18 15:58:08
Tags:

Resumo

A estratégia de negociação de rastreamento inteligente de média móvel dupla é uma estratégia de seguimento de tendências baseada em médias móveis e indicadores específicos. A estratégia usa duas médias móveis com configurações de parâmetros diferentes para construir um canal e combina o indicador OTT para definir os limites superior e inferior do canal para rastrear de forma inteligente as tendências de preços.

Princípio da estratégia

A metodologia central desta estratégia consiste em construir um canal adaptativo utilizando duas médias móveis e o indicador OTT, nomeadamente:

Calcular a linha rápida MAvg utilizando como entrada a média móvel CLOSE e a média móvel personalizada, com uma duração de 5 períodos;
Calcular a posição de linha longa LongStop e a posição de linha curta ShortStop para o canal com base no MAvg e na percentagem pré-estabelecida;
Calcular o MT de stop loss do canal no indicador OTT e o preço do canal OTT com base na direção longa/curta;
Gerenciar sinais de negociação quando o preço atravessa o OTT.

O processo acima permite o acompanhamento em tempo real das alterações da tendência de preços, gerando sinais de negociação.

Vantagens da estratégia

As vantagens desta estratégia incluem:

A estrutura de canal de média móvel dupla capta eficazmente as tendências dos preços;
O indicador OTT define a perda de parada do canal para controlar os riscos;
Estrutura adaptável do canal que responde rapidamente às alterações de preços;
Ajuste flexível dos parâmetros para diferentes produtos e prazos.

Riscos estratégicos

Há também alguns riscos:

As médias móveis duplas podem formar divergências que resultam em falsos sinais;
As configurações incorretas dos parâmetros da OTT podem ser demasiado agressivas ou conservadoras;
A estratégia baseia-se exclusivamente em indicadores técnicos sem considerar os elementos fundamentais.

Os riscos podem ser abordados através da otimização de parâmetros, da integração de outros indicadores e filtros de fundamentais.

Orientações de otimização

A estratégia pode ser otimizada em vários aspectos:

Otimizar os parâmetros da média móvel para os produtos e prazos adequados;
Otimizar os parâmetros da largura do canal, equilibrando a sensibilidade e a estabilidade;
Adicionar filtros baseados no volume de negociação;
Definir filtros de direcção baseados em fundamentos.

Resumo

Em resumo, esta é uma estratégia de tendência baseada em um canal de média móvel dupla e indicador OTT. A ideia central é construir um canal adaptável e gerar sinais quando os preços quebram. A estratégia tem méritos, mas também espaço para melhorias. Com ajuste de parâmetros e otimização lógica, tem o potencial de se tornar uma estratégia de negociação de quantidade eficiente que vale a pena implantar.

/*backtest
start: 2023-02-11 00:00:00
end: 2024-02-17 00:00:00
period: 1d
basePeriod: 1h
exchanges: [{"eid":"Futures_Binance","currency":"BTC_USDT"}]
*/

//@version=4
strategy(title="BugRA_Trade_Strategy", shorttitle="BugRA_Trade_Strategy", overlay=true)

// Kullanıcı Girdileri
length = input(5, title="Period", minval=1)
percent = input(1, title="Sihirli Yüzde", type=input.float, step=0.1, minval=0)
mav = input(title="Hareketli Ortalama Türü", defval="VAR", options=["SMA", "EMA", "WMA", "TMA", "VAR", "WWMA", "ZLEMA", "TSF"])
wt_n1 = input(10, title="Kanal Periyodu")
wt_n2 = input(21, title="Averaj Uzunluğu")
src = close

// Tarih Aralığı Girdileri
startDate = input(20200101, title="Başlangıç Tarihi (YYYYMMDD)")
endDate = input(20201231, title="Bitiş Tarihi (YYYYMMDD)")

// Tarih Filtresi Fonksiyonu
isDateInRange() => true

// Özel Fonksiyonlar
Var_Func(src, length) =>
    valpha = 2 / (length + 1)
    vud1 = src > src[1] ? src - src[1] : 0
    vdd1 = src < src[1] ? src[1] - src : 0
    vUD = sum(vud1, length)
    vDD = sum(vdd1, length)
    vCMO = (vUD - vDD) / (vUD + vDD)
    varResult = 0.0
    varResult := nz(valpha * abs(vCMO) * src + (1 - valpha * abs(vCMO)) * nz(varResult[1]))
    varResult

Wwma_Func(src, length) =>
    wwalpha = 1 / length
    wwma = 0.0
    wwma := wwalpha * src + (1 - wwalpha) * nz(wwma[1])
    wwma

Zlema_Func(src, length) =>
    zxLag = floor(length / 2)
    zxEMAData = src + (src - src[zxLag])
    zlema = ema(zxEMAData, length)
    zlema

Tsf_Func(src, length) =>
    lrc = linreg(src, length, 0)
    lrs = lrc - linreg(src, length, 1)
    tsf = lrc + lrs
    tsf

getMA(src, length) =>
    ma = mav == "SMA" ? sma(src, length) :
         mav == "EMA" ? ema(src, length) :
         mav == "WMA" ? wma(src, length) :
         mav == "TMA" ? sma(sma(src, ceil(length / 2)), floor(length / 2) + 1) :
         mav == "VAR" ? Var_Func(src, length) :
         mav == "WWMA" ? Wwma_Func(src, length) :
         mav == "ZLEMA" ? Zlema_Func(src, length) :
         mav == "TSF" ? Tsf_Func(src, length) : na

// Strateji Hesaplamaları
MAvg = getMA(src, length)
fark = MAvg * percent * 0.01
longStop = MAvg - fark
longStopPrev = nz(longStop[1], longStop)
longStop := MAvg > longStopPrev ? max(longStop, longStopPrev) : longStop
shortStop = MAvg + fark
shortStopPrev = nz(shortStop[1], shortStop)
shortStop := MAvg < shortStopPrev ? min(shortStop, shortStopPrev) : shortStop

dir = 1
dir := nz(dir[1], dir)
dir := dir == -1 and MAvg > shortStopPrev ? 1 : dir == 1 and MAvg < longStopPrev ? -1 : dir
MT = dir==1 ? longStop: shortStop
OTT = MAvg > MT ? MT*(200+percent)/200 : MT*(200-percent)/200

plot(OTT, title="BugRA", color=color.rgb(251, 126, 9))

// Alım ve Satım Koşulları
longCondition = crossover(src, OTT) and isDateInRange()
shortCondition = crossunder(src, OTT) and isDateInRange()

// Strateji Giriş ve Çıkış Emirleri
if (longCondition)
    strategy.entry("Long", strategy.long)

if (shortCondition)
    strategy.close("Long")

Mais.