O recurso está a ser carregado... Carregamento...

Estratégia de negociação de reversão RSI rápida

Autora:ChaoZhang, Data: 2024-03-01 11:55:56
Tags:

Resumo

A Estratégia de Reversão do RSI Rápido gera sinais de negociação combinando o indicador RSI Rápido, o filtro do corpo do candelabro, o filtro de preço min/max e o filtro SMA para determinar pontos de reversão da tendência para negociação de reversão de baixo risco.

Estratégia lógica

A estratégia baseia-se principalmente nos seguintes indicadores de avaliação:

Indicador RSI rápido: Calcula o RSI utilizando a função RMA para torná-lo mais sensível, a fim de captar mais rapidamente os sinais de sobrecompra/supervenda.
Filtro do corpo do candelabro: Requer que o tamanho do corpo do candelabro exceda 1/5 da média do corpo da EMA para filtrar situações de baixa volatilidade.
Filtro de preço mínimo/máximo: Julga se o preço atinge um novo máximo ou um novo mínimo para confirmar a reversão da tendência.
Filtro SMA: Requer preço para quebrar a linha SMA para confirmação adicional.

Os sinais de negociação são gerados quando múltiplas condições acima são acionadas simultaneamente.

Entrada longa: RSI rápido abaixo do nível de sobrevenda E corpo da vela > 1/5 do corpo da EMA E quebra de preço mínima E cruzamento do preço acima da SMA

Entrada curta: RSI rápido acima do nível de sobrecompra E corpo da vela > 1/5 do corpo da EMA E quebra máxima do preço E cruzamento do preço abaixo da SMA

Saída: RSI rápido volta ao intervalo normal

Vantagens

A estratégia apresenta as seguintes vantagens:

Captura a volatilidade das reversões de curto prazo
Indicador RSI rápido é sensível
Vários filtros reduzem os falsos sinais
Risco controlado, pequeno aproveitamento

Riscos e otimização

A estratégia apresenta também alguns riscos:

Risco de reversão fracassada
Espaço de otimização limitado

Pode optimizar ainda mais:

Adicionar filtro de volume de negociação
Implementar o stop loss
Otimize a combinação de parâmetros

Conclusão

No geral, esta é uma estratégia de negociação de reversão média de baixo risco de curto prazo. Identifica sinais de negociação com RSI rápido e usa vários filtros para reduzir sinais falsos, alcançando negociação de reversão de risco controlável. A estratégia pode ser otimizada e tem grande potencial.

/*backtest
start: 2024-02-01 00:00:00
end: 2024-02-26 23:59:59
period: 1h
basePeriod: 15m
exchanges: [{"eid":"Futures_Binance","currency":"BTC_USDT"}]
*/

//Noro
//2018

//@version=3
strategy(title = "Noro's Fast RSI Strategy v1.4", shorttitle = "Fast RSI str 1.4", overlay = true, default_qty_type = strategy.percent_of_equity, default_qty_value = 100, pyramiding = 5)

//Settings
needlong = input(true, defval = true, title = "Long")
needshort = input(true, defval = true, title = "Short")
usersi = input(true, defval = true, title = "Use Fast RSI Strategy")
usemm = input(true, defval = true, title = "Use Min/Max Strategy")
usesma = input(true, defval = true, title = "Use SMA Filter")
smaperiod = input(20, defval = 20, minval = 2, maxval = 1000, title = "SMA Filter Period")
rsiperiod = input(7, defval = 7, minval = 2, maxval = 50, title = "RSI Period")
limit = input(30, defval = 30, minval = 1, maxval = 100, title = "RSI limit")
rsisrc = input(close, defval = close, title = "RSI Price")
rsibars = input(1, defval = 1, minval = 1, maxval = 20, title = "RSI Bars")
mmbars = input(1, defval = 1, minval = 1, maxval = 5, title = "Min/Max Bars")
showsma = input(false, defval = false, title = "Show SMA Filter")
showarr = input(false, defval = false, title = "Show Arrows")
fromyear = input(2018, defval = 2018, minval = 1900, maxval = 2100, title = "From Year")
toyear = input(2100, defval = 2100, minval = 1900, maxval = 2100, title = "To Year")
frommonth = input(01, defval = 01, minval = 01, maxval = 12, title = "From Month")
tomonth = input(12, defval = 12, minval = 01, maxval = 12, title = "To Month")
fromday = input(01, defval = 01, minval = 01, maxval = 31, title = "From day")
today = input(31, defval = 31, minval = 01, maxval = 31, title = "To day")

//Fast RSI
fastup = rma(max(change(rsisrc), 0), rsiperiod)
fastdown = rma(-min(change(rsisrc), 0), rsiperiod)
fastrsi = fastdown == 0 ? 100 : fastup == 0 ? 0 : 100 - (100 / (1 + fastup / fastdown))

//Limits
bar = close > open ? 1 : close < open ? -1 : 0
uplimit = 100 - limit
dnlimit = limit

//RSI Bars
upsignal = fastrsi > uplimit ? 1 : 0
dnsignal = fastrsi < dnlimit ? 1 : 0
uprsi = sma(upsignal, rsibars) == 1
dnrsi = sma(dnsignal, rsibars) == 1

//Body
body = abs(close - open)
emabody = ema(body, 30)

//MinMax Bars
min = min(close, open)
max = max(close, open)
minsignal = min < min[1] and bar == -1 and bar[1] == -1 ? 1 : 0
maxsignal = max > max[1] and bar == 1 and bar[1] == 1 ? 1 : 0
mins = sma(minsignal, mmbars) == 1
maxs = sma(maxsignal, mmbars) == 1

//SMA Filter
sma = sma(close, smaperiod)
colorsma = showsma ? blue : na
plot(sma, color = colorsma, linewidth = 3)

//Signals
up1 = bar == -1 and (strategy.position_size == 0 or close < strategy.position_avg_price) and dnrsi and body > emabody / 5 and usersi
dn1 = bar == 1 and (strategy.position_size == 0 or close > strategy.position_avg_price) and uprsi and body > emabody / 5 and usersi
up2 = mins and (close > sma or usesma == false) and usemm
dn2 = maxs and (close < sma or usesma == false) and usemm 
exit = ((strategy.position_size > 0 and fastrsi > dnlimit and bar == 1) or (strategy.position_size < 0 and fastrsi < uplimit and bar == -1)) and body > emabody / 2

//Arrows
col = exit ? black : up1 or dn1 ? blue : up2 or dn2 ? red : na
needup = up1 or up2
needdn = dn1 or dn2
needexitup = exit and strategy.position_size < 0
needexitdn = exit and strategy.position_size > 0
plotarrow(showarr and needup ? 1 : na, colorup = blue, colordown = blue, transp = 0)
plotarrow(showarr and needdn ? -1 : na, colorup = blue, colordown = blue, transp = 0)
plotarrow(showarr and needexitup ? 1 : na, colorup = black, colordown = black, transp = 0)
plotarrow(showarr and needexitdn ? -1 : na, colorup = black, colordown = black, transp = 0)

//Trading
if up1 or up2
    strategy.entry("Long", strategy.long, needlong == false ? 0 : na)

if dn1 or dn2
    strategy.entry("Short", strategy.short, needshort == false ? 0 : na)
    
if time > timestamp(toyear, tomonth, today, 00, 00) or exit
    strategy.close_all()

Mais.